Funktionreferenz

_GUICtrlListView_GetItemRect

Beschreibung anzeigen in

Ermittelt das begrenzende Rechteck für das gesamte oder einen Teil des Items

#include <GuiListView.au3>
_GUICtrlListView_GetItemRect ( $hWnd, $iIndex [, $iPart = 3] )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex 0-basierender Index des Items
$iPart [optional] Der gewünschte Abschnitt des Items:
    $LVIR_BOUNDS - Gibt das begrenzende Rechteck des gesamten Items inklusive dem Icon und Label zurück
    $LVIR_ICON - Gibt das begrenzende Rechteck des Icons oder der kleinen Icons zurück
    $LVIR_LABEL - Gibt das begrenzende Rechteck von dem Itemtext zurück
    $LVIR_SELECTBOUNDS - Gibt die Einheit von $LVIR_ICON und $LVIR_LABEL, aber ohne die Spalten in der Reportansicht zurück

Rückgabewert


Array mit dem folgenden Format:
    [0] - X-Koordinate der oberen linken Ecke des Rechtecks
    [1] - Y-Koordinate der oberen linken Ecke des Rechtecks
    [2] - X-Koordinate der unteren rechten Ecke des Rechtecks
    [3] - Y-Koordinate der unteren rechten Ecke des Rechtecks

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlListView_GetItemRectEx

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aRect, $idListView

    GUICreate("ListView: Ermittelt das Rechteck des Items", 400, 300)
    $idListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListView, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListView, "Item 1")
    _GUICtrlListView_AddItem($idListView, "Item 2")
    _GUICtrlListView_AddItem($idListView, "Item 3")

    ; Ermittelt das Rechteck von Item 2
    $aRect = _GUICtrlListView_GetItemRect($idListView, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item 2 Rechteck : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example