Funktionreferenz

_GUICtrlListView_GetItemRectEx

Beschreibung anzeigen in

Ermittelt das begrenzende Rechteck für das gesamte oder einen Teil des Items

#include <GuiListView.au3>
_GUICtrlListView_GetItemRectEx ( $hWnd, $iIndex [, $iPart = 3] )

Parameter

$hWnd Control-ID / Handle des Controls
$iIndex 0-basierender Index des Items
$iPart [optional] Der gewünschte Abschnitt des Items:
    $LVIR_BOUNDS - Gibt das begrenzende Rechteck des gesamten Items, inklusive den Icons und Labels, zurück.
    $LVIR_ICON - Gibt das begrenzende Rechteck des Icons, oder kleinen Icons, zurück.
    $LVIR_LABEL - Gibt das begrenzende Rechteck des Itemtextes zurück
    $LVIR_SELECTBOUNDS - Gibt die Einheit von $LVIR_ICON und $LVIR_LABEL zurück, aber ohne die Spalten in der Reportansicht.

Rückgabewert

Gibt eine $tagRECT Struktur zurück

Bemerkungen

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

$tagRECT, _GUICtrlListView_GetItemRect

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Ermittelt das begrenzende Rechteck (v" & @AutoItVersion & ")", 500, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Ermittelt das begrenzende Rechteck für Item 2
    Local $tRECT = _GUICtrlListView_GetItemRectEx($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Rechteck für Item 2 : [%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
            DllStructGetData($tRECT, "Top"), DllStructGetData($tRECT, "Right"), DllStructGetData($tRECT, "Bottom")))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example