_GUICtrlListView_GetItemText

Beschreibung anzeigen in

Ermittelt den Text des Item oder Subitem

#include <GuiListView.au3>
_GUICtrlListView_GetItemText ( $hWnd, $iIndex [, $iSubItem = 0] )

Parameter

$hWnd	Control-ID / Handle des Controls
$iIndex	0-basierender Index des Items
$iSubItem	[optional] 1-basierender Index des Subitems

Rückgabewert

Gibt den Text des Items oder Subitems zurück

Bemerkungen

Um den Text des Items zu ermitteln, ist $iSubItem auf 0 zu setzen.
Um den Text des Subitems zu ermitteln, ist $iSubItem auf den 1-basierenden Index zu setzen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

Beispiel 1

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Setzt und ermittelt den Itemtext (v" & @AutoItVersion & ")", 500, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_AddItem($idListview, "Item 0")
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")

    ; Setzt den Itemtext des ersten Items
    _GUICtrlListView_SetItemText($idListview, 1, "Neues Item 1")
    MsgBox($MB_SYSTEMMODAL, "Information", "Item 1 Text: " & _GUICtrlListView_GetItemText($idListview, 1))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Beispiel 2: _GUICtrlListView_SetItemText() mit $iSubItem = - 1

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview
    GUICreate("ListView Elementtext setzen", 400, 300)
    $idListview = GUICtrlCreateListView("Item        |subitem        |subitem        ", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Fügt Zeile 0 hinzu
    GUICtrlCreateListViewItem("Item 0|SubItem1|SubItem2", $idListview)
    MsgBox($MB_TOPMOST, "", "Bevor der gesamte Text auf einmal geändert wird")

    ; Ändert den ganzen Text auf einmal in Zeile 0
    _GUICtrlListView_SetItemText($idListview, 0, "Item 0_alt|SubItem1_alt|SubItem2_alt", -1)
    MsgBox($MB_TOPMOST, "Parameter $iSubItem = - 1", "Der gesamte Text wurde auf einmal geändert.")

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

Funktionreferenz