Funktionreferenz

_GUICtrlListView_GetViewRect

Beschreibung anzeigen in

Ermittelt das begrenzende Rechteck aller Items in dem Control

#include <GuiListView.au3>
_GUICtrlListView_GetViewRect ( $hWnd )

Parameter

$hWnd Control-ID / Handle des Controls

Rückgabewert


Array mit dem folgenden Format:
    [0] - X-Koordinate der oberen linken Ecke des Rechtecks
    [1] - Y-Koordinate der oberen linken Ecke des Rechtecks
    [2] - X-Koordinate der unteren rechten Ecke des Rechtecks
    [3] - Y-Koordinate der unteren rechten Ecke des Rechtecks

Bemerkungen

Das Control muss sich in der Ansicht "große Icons" oder "kleine Icons" befinden

- - - - - - - - Erklärung der Controls - - - - - - - -

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("ListView: Ermittelt das begrenzende Rechteck aller Items (v" & @AutoItVersion & ")", 600, 300)
    Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

    ; Fügt die Spalten hinzu
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Fügt die Items hinzu
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Setzt die Ansicht
    _GUICtrlListView_SetView($idListview, 3)

    ; Ermittelt das begrenzende Rechteck aller Items
    Local $aRect = _GUICtrlListView_GetViewRect($idListview)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Begrenzendes Rechteck: [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example