_GUICtrlListView_SetItemPosition32
Beschreibung anzeigen in
Bewegt ein Item zu der festgelegten Position im Control
#include <GuiListView.au3>
_GUICtrlListView_SetItemPosition32 ( $hWnd, $iIndex, $iCX, $iCY )
Parameter
| $hWnd | Control-ID / Handle des Controls |
| $iIndex | 0-basierender Index des Items |
| $iCX | Neue X-Koordinate der oberen linken Ecke des Items (in "ListView"-Koordinaten) |
| $iCY | Neue Y-Koordinate der oberen linken Ecke des Items (in "ListView"-Koordinaten) |
Rückgabewert
| Erfolg: | True |
| Fehler: | False |
Bemerkungen
Falls das Control den Stil $LVS_AUTOARRANGE aufweist, rasten die Items in dem Control nach dem verschieben im Gitter ein. das Control muss sich in der "Icon" oder "kleine Icons" Ansicht befinden.
Diese Funktion unterscheidet sich von der _GUICtrlListView_SetItemPosition() Funktion in der Form, dass diese 32-bit Koordinaten benutzt.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
_GUICtrlListView_SetItemPosition
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>
Example()
Func Example()
GUICreate("ListView: Setzt die Itemposition (v" & @AutoItVersion & ")", 400, 300)
Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
GUISetState(@SW_SHOW)
; Setzt das ANSI Format
;~ _GUICtrlListView_SetUnicodeFormat($idListview, False)
; Fügt die Spalten hinzu
_GUICtrlListView_AddColumn($idListview, "Items", 100)
; Fügt die Items hinzu
_GUICtrlListView_BeginUpdate($idListview)
For $iI = 1 To 10
_GUICtrlListView_AddItem($idListview, "Item " & $iI)
Next
_GUICtrlListView_EndUpdate($idListview)
; Setzt die Ansicht "Kleine Icons"
_GUICtrlListView_SetView($idListview, 3)
MsgBox($MB_SYSTEMMODAL, "Information", "Verschiebt Item 2")
_GUICtrlListView_SetItemPosition32($idListview, 1, 100, 100)
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
GUIDelete()
EndFunc ;==>Example