Funktionreferenz


_GUICtrlRichEdit_GetLineLength

Beschreibung anzeigen in

Gibt die Länge der Zeile zurück

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineLength ( $hWnd, $iLine )

Parameter

$hWnd Handle des Controls
$iLine Zeilennummer
    Besonderer Wert: -1 - Gibt die Anzahl nicht ausgewählter Zeichen der Zeilen zurück, in denen es eine Auswahl gibt

Rückgabewert

Erfolg: Mehrzeiliges Control - Länge der Zeile (in Zeichen)
Einzeiliges Control - Anzahl der Zeichen im Control
Fehler: 0 und setzt das @error Flag auf ungleich null
@error: 101 - $hWnd ist kein Handle
102 - $iLine ist weder positiv noch -1
1022 - $iLine ist größer als die Anzahl der Zeichen im Control

Bemerkungen

Ein Control, das keinen Text enthält, hat eine Zeile.
Die erste Zeichenposition in einem Control ist 0.

Das Ergebnis enthält keine Wagenrücklauf-Zeichen (@CR) am Ende der Zeile.

- - - - - - - - Erklärung der Controls - - - - - - - -

Siehe auch

Suche nach EM_GETLINELENGTH in der MSDN Bibliothek.

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $hRichEdit, $iMsg
    $hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    Report("Die jetzige Linie enthält " & _GUICtrlRichEdit_GetLineLength($hRichEdit, -1) & " Zeichen")

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~              GUIDelete()     ; ist auch in Ordnung
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report