_GUICtrlRichEdit_GetTextLength
Beschreibung anzeigen in
Ermittelt die Länge des gesamten Textes in einem Control
#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextLength ( $hWnd [, $bExact = True [, $bChars = False [, $iUseCrLf = 1]]] )
Parameter
| $hWnd | Handle des Controls |
| $bExact | [optional] True - Ermittelt die exakte Länge False - Ermittelt zumindest die Anzahl der Zeichen im Control (schneller) Standard: exakte Länge |
| $bChars | [optional] True - Ermittelt die Länge/Anzahl der Zeichen False - Ermittelt die Länge/Anzahl der Bytes Standard: Bytes |
| $iUseCrLf | [optional] 1 - Zählung am Ende der Zeile = 2 (Standard) 0 - Zählung am Ende der Zeile = 1 |
Rückgabewert
| Erfolg: | Die Anzahl der Bytes oder Zeichen |
| Fehler: | 0 und setzt das @error Flag auf ungleich null |
| @error: | 101 - $hWnd ist kein Handle 102 - $bExact ist nicht True oder False 103 - $bChars ist nicht True oder False |
Bemerkungen
- - - - - - - - Erklärung der Controls - - - - - - - -
Siehe auch
Suche nach EM_GETTEXTLENGTHEX in der MSDN Bibliothek.
Beispiel
#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>
Global $g_idLblMsg
Example()
Func Example()
Local $hGui, $iMsg, $hRichEdit
$hGui = GUICreate("Beispiel (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
$hRichEdit = _GUICtrlRichEdit_Create($hGui, "Dies ist ein Test.", 10, 10, 300, 220, _
BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
$g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
GUISetState(@SW_SHOW)
_GUICtrlRichEdit_AppendText($hRichEdit, @CR & "Dies ist angehängter Text.")
Report("Es gibt " & _GUICtrlRichEdit_GetTextLength($hRichEdit, True, True) & _
" Zeichen im Control")
While True
$iMsg = GUIGetMsg()
Select
Case $iMsg = $GUI_EVENT_CLOSE
_GUICtrlRichEdit_Destroy($hRichEdit) ; wird benötigt, da sonst das Skript abstürzt
;~ GUIDelete() ; ist auch in Ordnung
Exit
EndSelect
WEnd
EndFunc ;==>Example
Func Report($sMsg)
GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc ;==>Report