Funktionreferenz

_GUICtrlToolbar_SetRows

Beschreibung anzeigen in

Setzt die Anzahl von Zeilen mit Buttons

#include <GuiToolBar.au3>
_GUICtrlToolbar_SetRows ( $hWnd, $iRows [, $bLarger = True] )

Parameter

$hWnd Handle des Controls
$iRows Anzahl von erforderlichen Zeilen. Die minimale Anzahl von Zeilen ist eins und die maximale Anzahl von Zeilen ist gleich der gesamten Anzahl von Buttons.
$bLarger [optional] Flag welches anzeigt, ob mehr Zeilen erstellt werden sollen als erforderlich wenn das System die Anzahl von Zeilen, festgelegt durch $iRows nicht erstellen kann.
Falls dieser Parameter True ist, erstellt das System mehr Zeilen.
Falls er False ist, erstellt das System weniger Zeilen.

Rückgabewert

Gibt ein Array mit dem folgenden Format zurück:
    [0] - X Koordinate der oberen linken Ecke des Rechtecks
    [1] - Y Koordinate der oberen linken Ecke des Rechtecks
    [2] - X Koordinate der unteren rechten Ecke des Rechtecks
    [3] - Y Koordinate der unteren rechten Ecke des Rechtecks

Bemerkungen

Da das System beim setzen der Anzahl der Zeilen die Buttongruppen nicht unterbricht, könnte das Ergebnis der Anzahl der Zeilen von der erforderlichen Anzahl abweichen.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUICtrlToolbar_GetRows

Beispiel

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Erstellt eine GUI
    Local $hGUI = GUICreate("Toolbar: setzt und ermittelt die Anzahl von Zeilen von Buttons (v" & @AutoItVersion & ")", 600, 300)
    Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
    $g_idMemo = GUICtrlCreateEdit("", 36, 2, 396, 262, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 10, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Setzt das ANSI Format
;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

    ; Fügt die Standard Systembitmaps hinzu
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Fügt die Buttons hinzu
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Erstellt eine vertikale Toolbar
    _GUICtrlToolbar_SetStyle($hToolbar, BitOR($CCS_LEFT, $TBSTYLE_FLAT))
    _GUICtrlToolbar_SetRows($hToolbar, 4)

    ; Zeigt die Anzahl der Zeilen
    MemoWrite("Anzahl der Zeilen:" & _GUICtrlToolbar_GetRows($hToolbar))

    ; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Schreibt eine Nachricht in das Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite