Funktionreferenz


_GUIToolTip_GetBubbleHeight

Beschreibung anzeigen in

Gibt die Höhe des Controls zurück

#include <GuiToolTip.au3>
_GUIToolTip_GetBubbleHeight ( $hWnd, $hTool, $iID [, $iFlags = 0x00000001 + 0x00000010] )

Parameter

$hWnd Handle des Controls (welches von _GUIToolTip_Create zurückgegeben wird.)
$hTool Handle zum Fenster welches das Tool enthält
$iID Handle des Controls welches mit dem Tool assoziiert ist oder die ID des Tools
$iFlags [optional] Flags welche die ToolTip Anzeige steuern:
    $TTF_IDISHWND = Zeigt an, dass $iID das Fensterhandle des Tools ist, anstatt der ID
    $TTF_CENTERTIP = Zentriert das Fenster, zugehörig zu dem durch $iID festgelegten Tool
    $TTF_RTLREADING = Zeigt an, dass der Text in umgekehrter Richtung angezeigt werden soll
    $TTF_SUBCLASS = Zeigt an, dass das Control das Fenster des Tool unterklassifizieren soll um Nachrichten abzufangen
    $TTF_TRACK = Positioniert das Control neben dem zugehörigen Tool
    $TTF_ABSOLUTE = Positioniert das Fenster bei den gleichen Koordinaten wie $TTM_TRACKPOSITION
    $TTF_TRANSPARENT = Sorgt dafür, dass das Control die Nachrichten an das Elternfenster weiterleitet
    $TTF_PARSELINKS = Zeigt an, dass links im Control Text ausgegliedert sein sollte

Die Konstanten sind in ToolTipConstants.au3 definiert.

Rückgabewert

Erfolg: die Höhe des ToolTips

Bemerkungen

Diese Funktion arbeitet nur korrekt auf einem ToolTip welches Tracking aktiviert hat.
Wenn das Tracking nicht aktiviert ist werden falsche Werte zurückgegeben.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUIToolTip_GetBubbleSize, _GUIToolTip_GetBubbleWidth

Beispiel

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate(StringTrimRight(@ScriptName, StringLen(".exe")), 350, 200)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; create a tooltip control using default settings
    Local $hToolTip = _GUIToolTip_Create(0)

    ; add a tool to the tooltip control
    _GUIToolTip_AddTool($hToolTip, 0, "This is a ToolTip", $hButton)
    _GUIToolTip_TrackActivate($hToolTip, True, 0, $hButton)
    GUISetState(@SW_SHOW)
    ; Display the height of the tooltip bubble in pixels
    MsgBox($MB_SYSTEMMODAL, "Info", "Bubble Height = " & _GUIToolTip_GetBubbleHeight($hToolTip, 0, $hButton) & " Pixels")

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    ; Destroy the tooltip control
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example