Funktionreferenz

_GUIToolTip_GetBubbleWidth

Beschreibung anzeigen in

Gibt die Breite des Controls zurück

#include <GuiToolTip.au3>
_GUIToolTip_GetBubbleWidth ( $hTool, $hWnd, $iID [, $iFlags = Default] )

Parameter

$hTool Handle des Controls (welches von _GUIToolTip_Create zurückgegeben wird.)
$hWnd Handle zum Fenster, welches das Tool enthält
$iID Handle des Fensters welches mit dem Tool assoziiert ist oder die ID des Tools
$iFlags [optional] Flags welche die ToolTip Anzeige steuern:
    $TTF_IDISHWND = Zeigt an, dass $iID ist das Fenster Handle des Tools anstatt der ID
    $TTF_CENTERTIP = Zentriert das Fenster, zugehörig zu dem durch $iID festgelegten Tool
    $TTF_RTLREADING = Zeigt an, dass der Text in umgekehrter Richtung angezeigt werden soll
    $TTF_SUBCLASS = Zeigt an, dass das Control das Fenster des Tool unterklassifizieren soll
    $TTF_TRACK = Positioniert das Control neben dem zugehörigen Tool
    $TTF_ABSOLUTE = Positioniert das Fenster bei den gleichen Koordinaten wie TTM_TRACKPOSITION
    $TTF_TRANSPARENT = Sorgt dafür, dass das Control die Nachrichten an das Elternfenster weiterleitet
    $TTF_PARSELINKS = Zeigt an, dass links im Control Text ausgegliedert sein sollte
Standard = BitOr($TTF_SUBCLASS, $TTF_IDISHWND)

Die Konstanten sind in ToolTipConstants.au3 definiert.

Rückgabewert

Erfolg: die Breite des ToolTip.
Fehler: @error wird gesetzt (siehe Bemerkungen).

Bemerkungen

Wenn sich das von $hWnd referenzierte Steuerelement nicht im selben Prozess befindet und beide Prozesse in unterschiedlichen AutoIt-Modi (@AutoItVersion) ausgeführt werden, wird @error auf 6 gesetzt.

Diese Funktion arbeitet nur korrekt auf einem ToolTip welches Tracking aktiviert hat.
Wenn das Tracking nicht aktiviert ist werden falsche Werte zurückgegeben.

- - - - - - - - Erklärung der Controls - - - - - - - -

Verwandte Funktionen

_GUIToolTip_GetBubbleHeight, _GUIToolTip_GetBubbleSize

Beispiel

#include "Extras\HelpFileInternals.au3"

#include <GUIConstantsEx.au3>
#include <GUIToolTip.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("ToolTip Get BubbleWidth - v(" & @AutoItVersion & ")", 450, 300, 100, 100)

    Local $idButton = GUICtrlCreateButton("This is a button", 30, 32, 130, 28)
    Local $hButton = GUICtrlGetHandle($idButton)
    ; create a tooltip control using default settings
    Local $hToolTip = _GUIToolTip_Create(0)

;~  $hGUI = 0 ; is OK
    ; add a tool to the tooltip control
    _GUIToolTip_AddTool($hToolTip, $hGUI, "This is a ToolTip", $hButton)

    GUISetState(@SW_SHOW)

    ; Show the tooltip associated with the button
    Opt("MouseCoordMode", 2)
    MouseMove(50, 42, 0)
    Sleep(250)

    ; Display the height of the tooltip bubble in pixels
    _MemoMsgBox($MB_SYSTEMMODAL, "Info", "Bubble Width = " & _GUIToolTip_GetBubbleWidth($hToolTip, $hGUI, $hButton) & " Pixels")

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd

    ; Destroy the tooltip control
    _GUIToolTip_Destroy($hToolTip)
    GUIDelete($hGUI)
EndFunc   ;==>Example