Hallo!
Schon wieder eine Frage 
:
Ich habe ein Skript mit mehreren GUIs.
Jetzt möchte ich, dass wenn man auf "Maximieren" im Hauptfenster drückt, dass es sich oben am Rand ablegt und sich auf Maximalbreite verbreitert, Höhe soll aber 90 bleiben. Wie ist sowas möglich? Der Button Maximieren soll ja auf Kleiner machen bleiben...
Hallo MatthiasG,
ich denke Du suchst sowas:
#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#region - GUI Create
$fenster = GUICreate('',200 ,90 ,-1,-1,$WS_MAXIMIZEBOX)
GUISetState()
#endregion
#region - GUI SelectLoop
While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
Exit
Case $msg = -6
WinMove($fenster,"",0,0,@DesktopWidth,90,1)
EndSelect
WEnd
#endregion
Danke! Das ist es! Wie registriere ich denn, das der Nutzer wieder klein macht? Maximieren geht ja über $GUI_MAXIMIZE o.s.ä.
Hat sich geklärt, Danke 
Aus der Hilfe:
If the option GUIEventOptions is set to 1 the minimize, restore and maximize button will not do any action on the window just a simple notification.
Damit kannst Du dann selbst (Funktion) auf einen Klick reagieren.
MatthiasG für dich könnte auch folgendes Script interessant sein.
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('GUIOnEventMode', 1)
If Not IsDeclared('WS_EX_COMPOSITED') Then Global Const $WS_EX_COMPOSITED = 0x02000000
Global $hGUI = GUICreate('Test', 640, 90, -1, 0, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX, $WS_SIZEBOX), $WS_EX_COMPOSITED)
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
GUISetState()
GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
While True
Sleep(100)
WEnd
Func _End()
Exit
EndFunc ;==>_End
Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
If $hWnd = $hGUI Then
Local $minmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
DllStructSetData($minmaxinfo, 7, 200) ; min X
DllStructSetData($minmaxinfo, 8, 90) ; min Y
DllStructSetData($minmaxinfo, 9, 1024) ; max X
DllStructSetData($minmaxinfo, 10, 90) ; max Y
EndIf
EndFunc ;==>MY_WM_GETMINMAXINFO
Wenn du auf die MaximizeBox klicks wird die Gui aus die Maximalmaße (max X und max Y ) vergrößert und beim verkleinern auf die Normalgröße zurückgesetzt. Das Script hab ich mal von Oscar bekommen 
Ich dachte, er meint das eher so:
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt('GUIOnEventMode', 1)
Opt('GUIEventOptions', 1)
$bSwitch = True
Global $hGUI = GUICreate('Test', 640, 480, -1, 0, BitOR($WS_MAXIMIZEBOX,$WS_MINIMIZEBOX))
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
GUISetOnEvent($GUI_EVENT_MAXIMIZE, '_Maximize')
GUISetState()
While True
Sleep(100)
WEnd
Func _End()
Exit
EndFunc
Func _Maximize()
Switch $bSwitch
Case True
WinMove($hGUI, '', 0, 0, @DesktopWidth, 480)
Case False
WinMove($hGUI, '', @DesktopWidth/2-320, 0, 640, 480)
EndSwitch
$bSwitch = Not $bSwitch
EndFunc
Die sind beide sehr interessant! Habs mir abgespeichert! Wer ich auf jedem Fall noch brauchen! Danke 
