Hallo @ all
Ich möchte eine INI-Datei mit einer Schleife auslesen:
$var = IniReadSection(@ScriptDir & "\settings.ini", "Settings")
For $i = 1 To $var[0][0]
GUICtrlCreateListViewItem($var[$i][0] & "|" & $var[$i][1], $listview3)
Next
Jetz habe ich das Problem, wenn ich einen "Onclick", also folgendes versuche:
Swicht $msg
Case ?..?
EndSwitch
Wie kann ich dann das Element ansprechen?(das ?..? im Case)
Wenn ich eine Var. davor setze wird sie ja immer "überspielt"...
Thx im vorraus 
deswegen solltest du die control-id's in einem array speichern.
[autoit]$var = IniReadSection(@ScriptDir & "\settings.ini", "Settings")
If isarray($var) Then
Dim $item[ubound($var)]
For $i = 1 To $var[0][0]
$item[$i] = GUICtrlCreateListViewItem($var[$i][0] & "|" & $var[$i][1], $listview3)
Next
endif
in etwa so.
mit dem richtigen index kannst du dann jedes element wieder abfragen
thx
das ist wirklich genial...!
vllt hilft dir ja ein einfaches beispiel weiter
#include <GUIConstants.au3>
Dim $Button[5]
$Form1 = GUICreate("", 270, 190)
For $i = 0 to 4
$Button[$i] = GUICtrlCreateButton("Button" & $i, 8, 9+35*$i, 250, 30, 0)
next
GUISetState(@SW_SHOW)
While 1
$nMsg = GUIGetMsg(1)
Switch $nMsg[0]
Case $GUI_EVENT_CLOSE
Exit
Case $Button[0] to $Button[4]
msgbox(0,"","Die button id ist " & $nMsg[0] & @crlf & "das button handle ist: " & $nMsg[2])
EndSwitch
WEnd
thx nochmal
wusste nicht das es ein 'to' im Case gibt...
Vorsicht!!!
Bei Schnitzels Beispiel müssen alle Controls direkt hintereinander erstellt werden (oder du musst viel mit Enum arbeiten.)
Klick mal auf eine Checkbox, dann weißt du was ich meine.
Dim $aButton[50]
_GUI_Create()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
Case $aButton[0] to $aButton[49]
ConsoleWrite("Button geklickt" & @CRLF)
EndSwitch
WEnd
Func _GUI_Create()
Local $i = 0, $x = 0, $y = 0
GUICreate("Beispiel", 165, 290)
For $y = 0 To 9
For $x = 0 To 4
$aButton[$i] = GUICtrlCreateButton($i, 30 + ($x * 25), 20 + ($y * 25), 20, 20)
$i += 1
Next
GUICtrlCreateCheckbox($y, 5, 20 + ($y * 25))
Next
GUISetState()
EndFunc ;==>_GUI_Create
Um das richtig zu verarbeiten musst du auch eine For-Next schleife verwenden:
Dim $aButton[50]
_GUI_Create()
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
Exit
EndSwitch
For $i = 0 to UBound($aButton)-1
If $nMsg = $aButton[$i] Then ConsoleWrite("Button geklickt" & @CRLF)
Next
WEnd
Func _GUI_Create()
Local $i = 0, $x = 0, $y = 0
GUICreate("Beispiel", 165, 290)
For $y = 0 To 9
For $x = 0 To 4
$aButton[$i] = GUICtrlCreateButton($i, 30 + ($x * 25), 20 + ($y * 25), 20, 20)
$i += 1
Next
GUICtrlCreateCheckbox($y, 5, 20 + ($y * 25))
Next
GUISetState()
EndFunc ;==>_GUI_Create
Im OnEvent Mode geht das alles aber noch wesentlich einfacher!
Bei Schnitzels Beispiel müssen alle Controls direkt hintereinander erstellt werden
und? er will sie ja auch in ner schleife erstellen, da ist es dann ja ziemlich egal.
abwechseld controls erstellen die nicht selbe funktionen enthalten is meines erachtens sehr unsauber. da macht man lieber nochmal ne schleife
Im OnEvent Mode geht das alles aber noch wesentlich einfacher!
ja leider ist der sehr unbeliebt...
obwohls egtl sehr viel leichter geht
abwechseld controls erstellen die nicht selbe funktionen enthalten is meines erachtens sehr unsauber.
Du würdest also statt
[autoit]For $i = 0 To 9
$aLable[$i] = GUICtrlCreateLabel("Lable " & $i, 20, 20 + ($i * 25))
$aInput[$i] = GUICtrlCreateInput("Input " & $i, 100, 20 + ($i * 25),100)
Next
Lieber
For $i = 0 To 9
$aLable[$i] = GUICtrlCreateLabel("Lable " & $i, 20, 20 + ($i * 25))
Next
For $i = 0 To 9
$aInput[$i] = GUICtrlCreateInput("Input " & $i, 100, 20 + ($i * 25),100)
Next
schreiben? Sicher?
Ich denke der ist so unbeliebt, weil er erst aktiviert werden muss, und man im normalfall immer mit GUIGetMsg() arbeitet. Obwohl der OnEvent Mode sogar schneller ist. Natürlich hat aber beides seine Vor und Nachteile. Aber die brauchen wir ja hier nich aufzurattern. Wen's interessiert: http://www.autoit.de/dokumentation/guiref/GUIRef.htm
Im Prinzip hast du aber Recht: Man kann ruhig Case ... to machen. Ich geh aber immer lieber auf nummer sicher und nehme die For Schleife.
Ich geh aber immer lieber auf nummer sicher und nehme die For Schleife.
jup im prinzip hast du ja auch recht 
man sollte halt immer wissen was man tut. alles andere sind vorlieben
