Hallo,
ich möchte für ein etwas komplexeres Script mehrere Daten in einer InputBox abfragen. Die InputBox fordert hierbei den User auf ein Datum im Format DD.MM.YYYY einzugeben. Gibt es eine Möglichkeit, den Tag, den Monat und das Jahr in jeweils 3 verschiedenen Variablen zu definieren? ($day, $month, $yeahr) Die Punkte(.) können ignoriert werden. Möchte, dass der User die Daten nicht einzeln in 3 verschiedenen InputBoxen eingegen muss.
Danke für Antworten 
sowas könnte dir helfen
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 200, 150)
$Input1 = GUICtrlCreateInput("", 32, 16)
GUISetState(@SW_SHOW)
Global $split
[/autoit] [autoit][/autoit] [autoit]While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Input1
$split = Stringsplit(GUICtrlRead($Input1), ".")
If IsArray($split) Then
msgbox(0,"Tag", $split[1])
msgbox(0,"Monat", $split[2])
msgbox(0,"Jahr", $split[3])
Endif
EndSwitch
WEnd
oh, an GUIs hab ich nun gar nicht gedacht bzw. noch gar nicht mit gearbeitet. Danke für den Tipp 
ups inputbox mit dem control input verwechselt 
geht natürlich so auch:
[autoit]$in = Inputbox("Gib ein Datum ein", "Im Format: " & @CRLF & "DD.MM.YYYY")
$split = Stringsplit($in, ".")
If IsArray($split) Then
msgbox(0,"Tag", $split[1])
msgbox(0,"Monat", $split[2])
msgbox(0,"Jahr", $split[3])
Endif
Oder schnell mal eine Datum-Eingabe-Box scripten.
Zum Beispiel so:
$sInput = _DateInputBox()
MsgBox(0, 'Eingegeben wurde dieses Datum:', $sInput)
Func _DateInputBox($sTitle = '')
Local $hGui, $hDate, $hOk, $aMsg
$hGui = GUICreate($sTitle, 200, 100)
GUICtrlCreateLabel('Bitte Datum eingeben:', 50, 10, 120, 20)
$hDate = GUICtrlCreateDate('', 45, 30, 120, 20, 0x00) ; 0x00 = $DTS_SHORTDATEFORMAT
GUICtrlSetFont(-1, 12)
$hOk = GUICtrlCreateButton('Ok', 70, 70, 60, 22)
GUISetState(@SW_SHOW, $hGui)
While True
$aMsg = GUIGetMsg(1)
If $aMsg[1] = $hGui Then
Switch $aMsg[0]
Case $hOk, -3 ; -3 = $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
EndIf
WEnd
$sDate = GUICtrlRead($hDate)
GUIDelete($hGui)
Return $sDate
EndFunc ;==>_DateInputBox
Vielen Dank Leute. Könntet ihr mir vllt. einmal erklären was das bedeutet:
$split = Stringsplit($in, ".")
If IsArray($split) Then
msgbox(0,"Tag", $split[1])
msgbox(0,"Monat", $split[2])
msgbox(0,"Jahr", $split[3])
Endif
Hab damit noch gar nicht gearbeitet.
Danke für Antworten
$split = Stringsplit($in, ".") ;Splittet den String nach jedem .
If IsArray($split) Then;Prüft ob es ein Array ist jenn ja dann zeigt er MsgBoxen mit dem Inhalt an
msgbox(0,"Tag", $split[1])
msgbox(0,"Monat", $split[2])
msgbox(0,"Jahr", $split[3])
Endif
oder eine InputBox-Funktion schreiben welche eine variable Anzahl an Feldern zulässt (ich weiß - bin bisschen spät):
#include <Array.au3>
Global $Felder[3] = ["Tag", "Monat", "Jahr"]
$aDaten = _InputBoxEx("Meine InputBox", "Bitte Datum eingeben:", $Felder)
If Not @error Then _ArrayDisplay($aDaten)
Func _InputBoxEx($sTitel, $sText, ByRef $aLabels)
Local $iOpt = Opt("GUIOnEventMode", 0)
Local $iN = UBound($aLabels)
Local $cLabel, $hGUI, $i, $iPos = 96
Local $aEdits[$iN], $hMsg
$hGUI = GUICreate($sTitel, 245, 135 + $iN * 40, Default, Default, 0x94CC0A4C, 0x00000204)
$cLabel = GUICtrlCreateLabel($sText, 10, 10, 223, 91, 0x50020000, 0x00000004)
$cOK = GUICtrlCreateButton("OK", 28, 105 + $iN * 40, 75, 23, 0x50010001, 0x00000004)
$cCancel = GUICtrlCreateButton("Cancel", 140, 105 + $iN * 40, 75, 23, 0x50010000, 0x00000004)
For $i = 0 To $iN - 1
GUICtrlCreateLabel($aLabels[$i], 10, $iPos, 223, 20)
$aEdits[$i] = GUICtrlCreateEdit("", 10, $iPos + 15 , 223, 20, 0x50010080, 0x00000204)
$iPos += 40
Next
While 1
[/autoit] [autoit][/autoit] [autoit]Switch GUIGetMsg()
Case -3
ExitLoop
Case $cOK
For $i = 0 To $iN -1
$aEdits[$i] = GUICtrlRead($aEdits[$i])
Next
GUIDelete($hGUI)
Opt("GUIOnEventMode", $iOpt)
Return $aEdits
Case $cCancel
ExitLoop
EndSwitch
WEnd
GUIDelete($hGUI)
Opt("GUIOnEventMode", $iOpt)
SetError(1)
Return 0
EndFunc
[autoit]Alles anzeigen[/autoit]
$split = Stringsplit($in, ".") ;Splittet den String nach jedem .
If IsArray($split) Then;Prüft ob es ein Array ist jenn ja dann zeigt er MsgBoxen mit dem Inhalt an
msgbox(0,"Tag", $split[1])
msgbox(0,"Monat", $split[2])
msgbox(0,"Jahr", $split[3])
Endif
alles klar, danke nochmal für die Hilfe.
bitte bitte 
