GUI mit Rand ohne Größen veränderbar

  • Hi, ich möchte ein GUI machen,was noch aussen diesen Rand hat, aber kein Balken oben mit dem Namen usw.. Das ist auch ganz leicht hinzubekommen, wenn man als Styles

    [autoit]

    BitOR($WS_BORDER,$WS_POPUP,$WS_SIZEBOX)

    [/autoit]

    verwendet. Jetzt kommtich zum Problem: Man kann an diesem Rand aber die Größe des Fensters verändern :(. Und das soll man bei meinem Script nicht können.
    Was muss ich verändern?

    owi

    Rechtschreibfehler sind Spezialeffekte meiner Tastatur.

    • Offizieller Beitrag
    [autoit]

    #include <WindowsConstants.au3>

    [/autoit][autoit][/autoit][autoit]

    GUICreate("Titel", 400, 400, -1, -1, BitOR($WS_BORDER,$WS_POPUP,$WS_SIZEBOX), 1)
    GUISetState()
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
    Do
    Until GUIGetMsg() = -3
    Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
    Local $AutoMonItnmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($AutoMonItnmaxinfo, 7, 416); min X Guisize +16 für Rand
    DllStructSetData($AutoMonItnmaxinfo, 8, 416); min Y
    DllStructSetData($AutoMonItnmaxinfo, 9, 416); max X
    DllStructSetData($AutoMonItnmaxinfo, 10, 416); max Y
    Return 0
    EndFunc ;==>MY_WM_GETMINMAXINFO

    [/autoit]
  • Also bei Autoberts-Version habe ich dann auch wieder die Zeile ganz oben. Zudem ist der Inhalt unsichtbar.
    Bei Raupis-Version ist danach alles wie wenn ich die Funktion und das GUIRegisterMsg weglasse. :(

    Rechtschreibfehler sind Spezialeffekte meiner Tastatur.

    • Offizieller Beitrag
    Zitat

    Bei Raupis-Version ist danach alles wie wenn ich die Funktion und das GUIRegisterMsg weglasse. :(

    Hast du schon mal versucht das Fenster zu resizen? Das geht nicht.
    Wenn deine GUI andere Ausmaße hat, must du natürlich MY_WM_GETMINMAXINFO dementsprechend anpaßen.
    Ich weiß sonst keine Lösung, weil der Rahmen von der SizeBox stammt.

    • Offizieller Beitrag

    autoBert

    Er will, das es so aussieht: Der Inhalt kann nicht angezeigt werden, da er nicht mehr verfügbar ist.

    Dein Ergebnis sieht so aus:

    Der Inhalt kann nicht angezeigt werden, da er nicht mehr verfügbar ist.

    @owi dowi spin, ich bastel dir was und füge es an diesen Beitrag an.


    Edit, so sollte es auf jedem BS klappen:

    Spoiler anzeigen
    [autoit]

    #include <WindowsConstants.au3>
    Global $hGui, $Pos
    $hGui = GUICreate("Titel", 400, 400, -1, -1, BitOR($WS_BORDER, $WS_POPUP, $WS_SIZEBOX), 1)
    $Pos = WinGetPos($hGui)
    GUISetState(@SW_SHOW)
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")

    [/autoit] [autoit][/autoit] [autoit]

    Do
    Until GUIGetMsg() = -3
    Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
    Local $AutoMonItnmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($AutoMonItnmaxinfo, 7, $Pos[2]); min X Guisize +16 für Rand
    DllStructSetData($AutoMonItnmaxinfo, 8, $Pos[3]); min Y
    DllStructSetData($AutoMonItnmaxinfo, 9, $Pos[2]); max X
    DllStructSetData($AutoMonItnmaxinfo, 10, $Pos[3]); max Y
    Return 0
    EndFunc ;==>MY_WM_GETMINMAXINFO

    [/autoit]
  • Raupi, ich habe an meinem Script jetzt mal weitergearbeitet. Es wird an einer Stelle die Größe des Fensters verändert. Wenn ich dann die alte Version mit natürlich geänderten Werten nochmal verwende, funktioniert die Größenänderung auch ganz normal. Aber wenn ich das mit WinGetPos (habe ich in die Funktion geschreiben), also der neuen Version, mache, ist die Fenstergröße anschließend genauso wie vorher. Ich habe das WinMove vor dem WinGetPos.

    Rechtschreibfehler sind Spezialeffekte meiner Tastatur.

  • Schon bei einem ganz normalen. Dem zum Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIResizeMode",802)

    [/autoit] [autoit][/autoit] [autoit]

    $Form1 = GUICreate("Form1", 468, 247, -1,-1,BitOR($WS_BORDER,$WS_POPUP,$WS_SIZEBOX))
    $Button1 = GUICtrlCreateButton("Größe ändern", 192, 152, 75, 25)
    GUISetState(@SW_SHOW)
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")

    [/autoit] [autoit][/autoit] [autoit]

    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $Button1
    WinMove("Form1","",Default,Default,Default,400)
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
    $WinSize=WinGetPos("Form1")
    Local $AutoMonItnmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($AutoMonItnmaxinfo, 7,$WinSize[2]) ; min X Guisize +16 für Rand
    DllStructSetData($AutoMonItnmaxinfo, 8,$WinSize[3]) ; min Y
    DllStructSetData($AutoMonItnmaxinfo, 9,$WinSize[2]) ; max X
    DllStructSetData($AutoMonItnmaxinfo, 10,$WinSize[3]) ; max Y
    Return 0
    EndFunc ;==>MY_WM_GETMINMAXINFO

    [/autoit]

    Rechtschreibfehler sind Spezialeffekte meiner Tastatur.

    • Offizieller Beitrag

    Mach es doch einfach so:

    Spoiler anzeigen
    [autoit]

    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIResizeMode",802)

    [/autoit] [autoit][/autoit] [autoit]

    $Form1 = GUICreate("Form1", 468, 247, -1,-1,BitOR($WS_BORDER,$WS_POPUP,$WS_SIZEBOX))
    $Button1 = GUICtrlCreateButton("Größe ändern", 192, 152, 75, 25)
    GUISetState(@SW_SHOW)
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
    Global $WinSize=WinGetPos("Form1")
    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $Button1
    $WinSize[3] = 416
    WinMove("Form1","",Default,Default,Default,400)
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
    Local $AutoMonItnmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($AutoMonItnmaxinfo, 7,$WinSize[2]) ; min X Guisize +16 für Rand
    DllStructSetData($AutoMonItnmaxinfo, 8,$WinSize[3]) ; min Y
    DllStructSetData($AutoMonItnmaxinfo, 9,$WinSize[2]) ; max X
    DllStructSetData($AutoMonItnmaxinfo, 10,$WinSize[3]) ; max Y
    Return 0
    EndFunc ;==>MY_WM_GETMINMAXINFO

    [/autoit]
    • Offizieller Beitrag

    Du hast vielleicht Ansprüche. Warum denkst du nicht mal selbst wie du die Rahmengröße berechnen kannst?
    Aber ich bin ja nicht so, deshalb hier mein Beispiel:

    Spoiler anzeigen
    [autoit]

    #include <ButtonConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsConstants.au3>

    [/autoit] [autoit][/autoit] [autoit]

    Opt("GUIResizeMode", 802)
    Global $GuiSizeX = 468
    Global $GuiSizeY = 247

    [/autoit] [autoit][/autoit] [autoit]

    $Form1 = GUICreate("Form1", 468, 247, -1, -1, BitOR($WS_BORDER, $WS_POPUP, $WS_SIZEBOX))
    $Button1 = GUICtrlCreateButton("Größe ändern", 192, 152, 75, 25)
    GUISetState(@SW_SHOW)
    Global $WinSize = WinGetPos("Form1")
    Global $BorderX = $WinSize[2] - $GuiSizeX
    Global $BorderY = $WinSize[3] - $GuiSizeY
    GUIRegisterMsg($WM_GETMINMAXINFO, "MY_WM_GETMINMAXINFO")
    While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE
    Exit
    Case $Button1
    $GuiSizeY = 400
    WinMove("Form1", "", Default, Default, Default, 400)
    EndSwitch
    WEnd

    [/autoit] [autoit][/autoit] [autoit]

    Func MY_WM_GETMINMAXINFO($hWnd, $msg, $wParam, $lParam)
    Local $AutoMonItnmaxinfo = DllStructCreate("int;int;int;int;int;int;int;int;int;int", $lParam)
    DllStructSetData($AutoMonItnmaxinfo, 7, $GuiSizeX + $BorderX) ; min X
    DllStructSetData($AutoMonItnmaxinfo, 8, $GuiSizeY + $BorderY) ; min Y
    DllStructSetData($AutoMonItnmaxinfo, 9, $GuiSizeX + $BorderX) ; max X
    DllStructSetData($AutoMonItnmaxinfo, 10, $GuiSizeY + $BorderY) ; max Y
    Return 0
    EndFunc ;==>MY_WM_GETMINMAXINFO

    [/autoit]

    Ups, 2 Zeilen zuviel, SC angepaßt.