Hallo,
ich habe folgendes Problem.
Es werden 2 Guis gestartet.
Eine Gui ist im Hintergrund und die andere im Vordergrund.
Die Gui die im Vordergrung ist wurde mit WinSetOnTop nach oben gesetzt!
[autoit]
#include "Suche.au3"
WinSetOnTop("Suche", "", 1); Mein Name in der Titelleiste (Gui Name)
Klicke ich aber auf das andere Fenster dahinter, dann verschwindet das Fenster Suche
das normal immer oben bleiben sollte!
Gibt es da vielleicht noch einen anderen Befehl?
Grüße
Ilse 
Hallo Ilse,
hier ein allgemein gehaltenes Beispiel zum arbeiten mit 2 GUIs im Msg-Loop Modus:
#include <GUIConstantsEx.au3>
#include<WindowsConstants.au3>
Global $idGui1, $idGui2=-99, $idMsgBox, $idZurueck, $idbtnExit2
_CreateGui2() ;entweder hier oder erst wenn benötigt ($idbtmToGui2 Klick)
$idGui1 = GUICreate('GUI 1', 400, 280, 140, 150, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
;erzeugt eine GUI die zurückgebebene ID wird in der Variablen $idGui1 gespeichert
;die GUI hat BOXen für Mininmieren, Maximieren und ist in der Größe frei änderbar
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
$idbtnToGui2 = GUICtrlCreateButton('&Aufruf GUI 2', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnICQ = GUICtrlCreateButton('&ICQ', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "ICQ" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnExit1 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUISetState(@SW_SHOW, $idGui1)
[/autoit] [autoit][/autoit] [autoit]While 1
$nMsg = GUIGetMsg(1) ;extended Modus wichtig!!
Switch $nMsg[1] ;für welches Fenster ist die Message
Case $idGui1 ;ab hier ist Gui 1 dran
Switch $nMsg[0] ;welche Message wurde ausgelöst
Case $idbtnToGui2
GUISetState(@SW_DISABLE, $idGui1) ;Gui 1 disablen, damit nur Gui2 bearbeitet werden kann
;If $idGui2 = -99 Then _CreateGui2() ;nur wenn nicht am Anfang bereits erzeugt nötig, dann auf Vorbelegung der Variable in Global achten)
GUISetState(@SW_SHOW, $idGui2) ;Gui 2 anzeigen
Case $idbtnICQ
MsgBox(0,"","Jetzt würde ICQ gestartet")
;Run("C:\Program Files\ICQ7.0\ICQ.exe")
Case $idbtnExit1, $GUI_EVENT_CLOSE
_end()
EndSwitch
Case $idGui2 ;ab hier ist Gui 2 dran
Switch $nMsg[0] ;welche Message wurde ausgelöst
Case $idMsgBox
MsgBox(0, 'Test', 'Test', 0, $idGui2)
Case $idZurueck, $GUI_EVENT_CLOSE
GUISetState(@SW_ENABLE, $idGui1) ;Gui 1 für ensablen
GUISetState(@SW_HIDE, $idGui2) ;Gui 2 verstecken
Case $idbtnExit2
_end()
EndSwitch
EndSwitch
WEnd
Func _CreateGui2()
$idGui2 = GUICreate('GUI 2', 500, 300, 200, 50, -1, -1, $idGui1)
;erzeugt eine GUI als Child von Gui1, die zurückgebebene ID wird in der Variablen $idGui2 gespeichert
$idMsgBox = GUICtrlCreateButton('&MsgBox', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "MsgBox" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idZurueck = GUICtrlCreateButton('&Zurück zu GUI 1', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "zurück" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnExit2 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "beenden" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
EndFunc ;==>_CreateGui2
Func _end()
GUIDelete($idGui2)
GUIDelete($idGui1)
Exit
EndFunc ;==>_end
das ganze kommt ohne WinSetOnTop aus, das heist solange die Anwendung im Vordergrund ist wird auch das aktuelle Fenster im Vordergrund gehalten. Es gibt sicherlich noch andere Methoden, ich jedoch halte diese für die einfachste. Falls du es Im OnEvent-Modus benötigst, hier das gleiche:
#include <GUIConstantsEx.au3>
#include<WindowsConstants.au3>
Opt('GUIOnEventMode', 1)
[/autoit] [autoit][/autoit] [autoit]$cidGui1 = GUICreate('GUI 1', 400, 280, 140, 150, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
;erzeugt eine GUI die zurückgebebene ID wird in der Variablen $cidGui1 gespeichert
;die GUI hat BOXen für Mininmieren, Maximieren und ist in der Größe frei änderbar
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
$cidbtnToGui2 = GUICtrlCreateButton('&Aufruf GUI 2', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_CallGui2')
;Beim Klicken des Buttons wird die Funktion _CallGui2 aufgerufen
$cidbtnICQ = GUICtrlCreateButton('&ICQ', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "ICQ" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_RunICQ')
;Beim Klicken des Buttons wird die Funktion _RunICQ aufgerufen
$cidbtnExit1 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_End')
;Beim Klicken des Buttons wird die Funktion _END aufgerufen
$cidGui2 = GUICreate('GUI 2', 500, 300, 200, 50, -1, -1, $cidGui1)
;erzeugt eine GUI als Child von Gui1, die zurückgebebene ID wird in der Variablen $cidGui2 gespeichert
GUISetOnEvent($GUI_EVENT_CLOSE, '_BackToGui1')
$cidButton1 = GUICtrlCreateButton('&MsgBox', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "MsgBox" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_MsgBox')
;Beim Klicken des Buttons wird die Funktion _MsgBox aufgerufen
$cidButton2 = GUICtrlCreateButton('&Zurück zu GUI 1', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "zurück" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_BackToGui1')
;Beim Klicken des Buttons wird die Funktion _BackToGui1 aufgerufen
$cidbtnExit2 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKRIGHT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" rechts und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUICtrlSetOnEvent(-1, '_End')
;Beim Klicken des Buttons wird die Funktion _END aufgerufen
GUISetState(@SW_SHOW, $cidGui1)
While 1
Sleep(1000)
WEnd
Func _end()
GUIDelete($cidGui2)
GUIDelete($cidGui1)
Exit
EndFunc ;==>_end
Func _CallGui2()
GUISetState(@SW_DISABLE, $cidGui1)
GUISetState(@SW_SHOW, $cidGui2)
EndFunc ;==>_CallGui2
Func _RunICQ()
Run("C:\Program Files\ICQ7.0\ICQ.exe")
EndFunc ;==>_RunICQ
Func _BackToGui1()
GUISetState(@SW_ENABLE, $cidGui1)
GUISetState(@SW_HIDE, $cidGui2)
EndFunc ;==>_BackToGui1
Func _MsgBox()
MsgBox(0, 'Test', 'Test', 0, $cidGui2)
EndFunc ;==>_MsgBox
mfg autoBert
guten Morgen autoBert,
...konnte mich gestern Abend nicht mehr melden.
Danke für dein Beispiel.
Ich habe jedoch ein Problem.
Es soll alles mit include Dateien gelöst werden.
Ich meine, es gibt eine Hauptgui
und an irgendeiner Stelle kommt dann #include "FormX"
und diese Form soll dann nach vorne.
Gibt es nicht noch eine andere Variante?
Grüße
Ilse
Vielleicht so in dem das TopMost direkt in Suche.au3 definierst:
Main:
#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 625, 443, 192, 124)
$Button1 = GUICtrlCreateButton("Suche", 224, 144, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button1
#include "Suche.au3"
EndSwitch
WEnd
Suche:
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 163, 99, 192, 124, -1, BitOR($WS_EX_TOPMOST,$WS_EX_WINDOWEDGE))
$Input1 = GUICtrlCreateInput("Input1", 24, 8, 121, 21)
$Button1 = GUICtrlCreateButton("Button1", 40, 40, 75, 25, $WS_GROUP)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
EndSwitch
WEnd
einen schönen guten Morgen Chip,
folgendes Problem:
öffne bitte einmal zusätzlich Scite als "Hintergrundfenster",
Jetzt wird gestartet:
1. Main liegt auf Scite
2. Suche liegt ganz oben
Bis hierhin prima, wenn ich innerhalb von Main klicke, aber wenn ich dann auf Scite klicke
ist Main verschwunden. Auch wenn ich in Main ein WinSetOnTop einbaue
bleibt Main nicht vorne.
Grüße
Ilse
Hallo Ilse,
WinSetOnTop bringt es ja nur nach vorne, du müsstest aber beim erzegen der GUI den erweiterten Stil $WS_EX_TOPMOST verwenden.
Edit: Hatte deine Frage falsch verstanden, dachte du meitest Anwendungs-Modal und nicht Systemm-Modal. Davon halte ich nichts, dass jede(r) Programmierer(in) denkt ihr Programm ist das wichtigste, wenn nämlich alle Programme diesen Stil verwenden, kannst du bald nicht mehr vernünftig arbeiten. Er sollte also wirklich nur Systemprogrammen wie z.B.: dem Taskmanager zugestanden werden.
mfg autoBert
Hallo AutoBert,
WinSetOnTop bringt es ja nur nach vorne, du müsstest aber beim erzegen der GUI den erweiterten Stil $WS_EX_TOPMOST verwenden.
hab ich natürlich probiert, geht leider nicht.
Sobald ich auf ein anderes Fenster klicke
ist die MainGui weg. Die andere bleibt!
Und gerade noch ein Problem festgestellt:
Am Ende erscheint eine Msgbox, beendet!
Und die soll natürlch ganz oben stehen!
Sie erscheint im Hintergrund!
MsgBox(4,"Beendet","Ende")
WinSetOnTop("Beendet","Ende", $Gui)
Die Msgbox habe ich gerade gelöst:
MsgBox(4096,"Beendet","Ende")
...kann nicht mehr denken... 
Grüße
Ilse
Hallo Ilse,
doch das klappt, siehe mein abgewandeltes Beispiel:
#include <GUIConstantsEx.au3>
#include<WindowsConstants.au3>
Global $idGui1, $idGui2 = -99, $idMsgBox, $idZurueck, $idbtnExit2
_CreateGui2() ;entweder hier oder erst wenn benötigt ($idbtmToGui2 Klick)
$idGui1 = GUICreate('GUI 1', 400, 280, 140, 150, BitOR($WS_MINIMIZEBOX, $WS_MAXIMIZEBOX, $WS_SIZEBOX), $WS_EX_TOPMOST)
;wichtig ist der letzte Parameter
;$WS_EX_TOPMOST Hält diese Gui immer an vorderster Stelle
;erzeugt eine GUI die zurückgebebene ID wird in der Variablen $idGui1 gespeichert
;die GUI hat BOXen für Mininmieren, Maximieren und ist in der Größe frei änderbar
GUISetOnEvent($GUI_EVENT_CLOSE, '_End')
$idbtnToGui2 = GUICtrlCreateButton('&Aufruf GUI 2', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnICQ = GUICtrlCreateButton('&ICQ', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "ICQ" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnExit1 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "Afruf Gui 2" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
GUISetState(@SW_SHOW, $idGui1)
[/autoit] [autoit][/autoit] [autoit]While 1
$nMsg = GUIGetMsg(1) ;extended Modus wichtig!!
Switch $nMsg[1] ;für welches Fenster ist die Message
Case $idGui1 ;ab hier ist Gui 1 dran
Switch $nMsg[0] ;welche Message wurde ausgelöst
Case $idbtnToGui2
; GUISetState(@SW_DISABLE, $idGui1) ;Gui 1 für disablen
;If $idGui2 = -99 Then _CreateGui2() ;nur wenn nicht am Anfang bereits erzeugt nötig, dann auf Vorbelegung der Variable in Global achten)
GUISetState(@SW_SHOW, $idGui2) ;Gui 2 anzeigen
GUISetState(@SW_DISABLE,$idGui1);wichtig sonst kann dieses Fenster in den Vordergrund während GUI2 gezeigt wird
Case $idbtnICQ
MsgBox(0, "", "Jetzt würde ICQ gestartet", 0, $idGui1)
;wichtig ist der letzte Parameter
;$idGui ist das Parent-Fenster dieser MsgBox dadurch bleibt auch sie immer an vorderster Stelle
;Run("C:\Program Files\ICQ7.0\ICQ.exe")
Case $idbtnExit1, $GUI_EVENT_CLOSE
_end()
EndSwitch
Case $idGui2 ;ab hier ist Gui 2 dran
Switch $nMsg[0] ;welche Message wurde ausgelöst
Case $idMsgBox
MsgBox(0, 'Test', 'Test', 0, $idGui2)
;wichtig ist der letzte Parameter
;$idGui2 ist das Parent-Fenster dieser MsgBox dadurch bleibt auch sie immer an vorderster Stelle
Case $idZurueck, $GUI_EVENT_CLOSE
GUISetState(@SW_ENABLE, $idGui1) ;Gui 1 für ensablen
GUISetState(@SW_HIDE, $idGui2) ;Gui 2 verstecken
Case $idbtnExit2
_end()
EndSwitch
EndSwitch
WEnd
Func _CreateGui2()
$idGui2 = GUICreate('GUI 2', 500, 300, 200, 50, -1, $WS_EX_TOPMOST, $idGui1)
;wichtig sind die beiden letzten Parameter
;$WS_EX_TOPMOST Hält diese Gui immer an vorderster Stelle
;$idGui1 ist das Parent-Fenster
;erzeugt eine GUI als Child von Gui1, die zurückgebebene ID wird in der Variablen $idGui2 gespeichert
$idMsgBox = GUICtrlCreateButton('&MsgBox', 20, 20, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "MsgBox" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idZurueck = GUICtrlCreateButton('&Zurück zu GUI 1', 20, 50, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "zurück" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
$idbtnExit2 = GUICtrlCreateButton('be&enden', 20, 80, 100, 21)
GUICtrlSetResizing(-1, $GUI_DOCKSIZE + $GUI_DOCKLEFT + $GUI_DOCKTOP)
;verankert den Button "beenden" links und oben und fixiert die Größe
;beim Resizen bleibt es dadurch auf seiner Position am rechten Rand
EndFunc ;==>_CreateGui2
Func _end()
GUIDelete($idGui2)
GUIDelete($idGui1)
Exit
EndFunc ;==>_end
viel Spass damit,
Edit: Skript angepasst
autoBert
guten Morgen AutoBert,
hatte gestern leider keine Zeit mehr.
Vielen Dank für deine Lösung
Grüße
Ilse
