WinGetClientPos

  • Hallo.

    WinGetPos kennt man, allerdings teilt es die Koordinaten mit, wo der Fensterrahmen anfängt. Ich möchte aber wissen, wo auf dem Bildschirm der Clientbereich, also das innere des Fensters, beginnt. Gibt ja leider nur eine Funktion die mir sagt, wie breit und hoch der Clientbereich ist. Aber nicht die Koordinaten...

    Jemand eine Idee?

    Einmal editiert, zuletzt von NoName (31. Januar 2011 um 19:43)

    • Offizieller Beitrag
    [autoit]

    #include <WinAPI.au3>
    Local $hwnd, $tRect
    $hwnd = GUICreate("test")
    guisetState()
    $tRect = _WinAPI_GetWindowRect($hWnd) ; Struct mit Koordinaten auslesen
    ; Siehe $tagRECT in der Schlüsselwort-Referenz.

    [/autoit][autoit][/autoit][autoit]

    MsgBox(0, "Beispiel", _
    WinGetTitle($hWnd) & ":" & @CRLF & _
    DllStructGetData($tRect, "Left") & @CRLF & _ ; Daten ausgeben
    DllStructGetData($tRect, "Top") & @CRLF & _
    DllStructGetData($tRect, "Right") & @CRLF & _
    DllStructGetData($tRect, "Bottom") & @CRLF _
    )

    [/autoit][autoit][/autoit][autoit][/autoit]

    Edit: Das Beispiel funtioniert nicht unter Aero. Also bei Win7 und Vista werden falsche Werte zurückgegeben.

  • Danke schonmal.

    Warum muss es immer so unterschiedliche Bezeichnungen dafür geben?!

    Finds aber extrem doof, dass man da nicht das Fenster angeben kann...
    Gibts dafür noch eine Lösung?

  • Zitat

    Gibts dafür noch eine Lösung?


    Naja... Das hier macht so ziemlich das selbe.

    [autoit]

    #include <WinAPI.au3>

    [/autoit][autoit][/autoit][autoit]

    $hWnd = GUICreate("Test", 400, 400)
    GUISetState()

    [/autoit][autoit][/autoit][autoit]

    $tPoint = DllStructCreate($tagPOINT)
    DllStructSetData($tPoint, "X", 0)
    DllStructSetData($tPoint, "Y", 0)
    _WinAPI_ClientToScreen($hWnd, $tPoint)

    [/autoit][autoit][/autoit][autoit]

    MouseMove(DllStructGetData($tPoint, "X"), DllStructGetData($tPoint, "Y"))

    [/autoit][autoit][/autoit][autoit]

    Sleep(1000)

    [/autoit]
    • Offizieller Beitrag

    Oscar , ich hab den Beitrag gelöscht, weil _WinAPI_GetWindowRect unter Win7 und Vista falsche Werte liefert.
    Aero verhindert eine richtige Berechnung.

    Diese Funktion läuft einwandfrei und ich setze sie im meinen Scipten ein:

    Spoiler anzeigen
    [autoit]

    #include <WinAPI.au3>
    #include <Array.au3>
    Local $hwnd
    $hwnd = GUICreate("test")
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    $aClint = _WinGetClientPos($hwnd)
    _ArrayDisplay($aClint)

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinGetClientPos($hwnd)
    Local $aClientSize = WinGetClientSize($hwnd)
    Local $aWinpos = WinGetPos($hwnd)
    Local $iBorderSize = ($aWinpos[2] - $aClientSize[0]) / 2
    Local $iBarSize = $aWinpos[3] - $aClientSize[1] - $iBorderSize
    Local $aClient[4]
    $aClient[0] = $aWinpos[0] + $iBorderSize
    $aClient[1] = $aWinpos[1] + $iBarSize
    $aClient[2] = $aWinpos[0] + $aWinpos[2] - $iBorderSize
    $aClient[3] = $aWinpos[1] + $aWinpos[3] - $iBorderSize
    Return $aClient
    EndFunc

    [/autoit]
  • Ja, _WinAPI_GetWindowRect liefert in der Tat falsche Werte (hab Aero an).
    Die Lösung von name22 funktioniert zwar, allerdings müsste ich da auf 'nen include zurückgreifen (was ich gern vermeide wenn ich kann ;) ).

    @Raupi: Die Funktion ist genial. Jetzt werfe ich mir selbst wieder vor, warum ich nicht darauf gekommen bin... Ich habe sie jetzt noch so für mich angepasst, dass sie dieselben Angaben wie WinGetPos zurückgibt, also
    $return[0] = ClientPosX
    $return[1] = ClientPosY
    $return[2] = ClientWidth
    $return[3] = ClientHeight

    Spoiler anzeigen
    [autoit]

    Func _WinGetClientPos($hwnd)
    Local $aClientSize = WinGetClientSize($hwnd)
    Local $aWinpos = WinGetPos($hwnd)
    Local $iBorderSize = ($aWinpos[2] - $aClientSize[0]) / 2
    Local $iBarSize = $aWinpos[3] - $aClientSize[1] - $iBorderSize
    Local $aClient[4]
    $aClient[0] = $aWinpos[0] + $iBorderSize
    $aClient[1] = $aWinpos[1] + $iBarSize
    $aClient[2] = $aClientSize[0]
    $aClient[3] = $aClientSize[1]
    Return $aClient
    EndFunc

    [/autoit]

    Vielen Dank an alle für die sehr schnelle Hilfe!

  • Die Lösung von name22 funktioniert zwar, allerdings müsste ich da auf 'nen include zurückgreifen (was ich gern vermeide wenn ich kann ).

    Wieso denn das?
    Welche Begründung liegt dem zu Grunde?

    Und selbst wenn man dieses obskure Prinzip unbedingt einhalten will dann kann man sich auch die benötigten Deklarationen aus der Include-Datei ziehen so dass man nicht in Gefahr gerät Bibliotheken zu includen:

    Spoiler anzeigen
    [autoit]

    Global Const $tagPOINT = "long X;long Y"

    [/autoit] [autoit][/autoit] [autoit]

    $hWnd = GUICreate("Test", 400, 400)
    GUISetState()

    [/autoit] [autoit][/autoit] [autoit]

    $tPoint = DllStructCreate($tagPOINT)
    DllStructSetData($tPoint, "X", 0)
    DllStructSetData($tPoint, "Y", 0)
    _WinAPI_ClientToScreen($hWnd, $tPoint)

    [/autoit] [autoit][/autoit] [autoit]

    MouseMove(DllStructGetData($tPoint, "X"), DllStructGetData($tPoint, "Y"))

    [/autoit] [autoit][/autoit] [autoit]

    Sleep(1000)

    [/autoit] [autoit][/autoit] [autoit]

    Func _WinAPI_ClientToScreen($hWnd, ByRef $tPoint)
    Local $pPoint = DllStructGetPtr($tPoint)
    DllCall("user32.dll", "bool", "ClientToScreen", "hwnd", $hWnd, "ptr", $pPoint)
    Return SetError(@error, @extended, $tPoint)
    EndFunc

    [/autoit]

  • Ich möchte ein Script einfach so übersichtlich und einfach halten wie es geht. Und wenn ich nichtmal auf UDF-Funktionen zurückgreifen muss, finde ich es sowieso meist besser^^

  • Zitat

    Auserdem ging es in diesem Thread nicht um die Mausposition


    Ich lese auch nicht einfach nur die Mausposition aus, sondern errechne die Mausposition relativ zum Desktop und ziehe die Koordinaten des Client Bereich des angegebenen Fensters davon ab. Und das ergibt die Koordinaten für den Client Bereich des Fensters... Ist ja jetzt auch egal, da das Problem gelöst zu sein scheint.

  • Habe deinen Post eben erst übersehen...
    Naja habe es getestet und es geht auch wunderbar.

    Schön zu wissen, dass es so viele Möglichkeiten gibt, und mir keine einfiel ... *schmoll*

  • Hallo,

    Mr. Gates hat natürlich auch eine API-Funktion schreiben lassen, die die gesuchten Werte und noch ein paar andere Informationen liefert:

    Spoiler anzeigen
    [autoit]

    #include <Array.au3>

    [/autoit] [autoit][/autoit] [autoit]

    $hGUI = GUICreate("Test GUI", 300, 300)
    GUISetState()
    $aPos = _WinGetClientPos($hGUI)
    _ArrayDisplay($aPos, "Clientbereich des GUI")

    [/autoit] [autoit][/autoit] [autoit]

    Exit

    [/autoit] [autoit][/autoit] [autoit]

    ; #FUNCTION# ====================================================================================================================
    ; Name...........: _WinGetClientPos
    ; Description ...: Liefert die Position und die Dimensionen des Clientbereichs eines Fensters
    ; Syntax.........: _WinGetClientPos($hWnd)
    ; Parameters ....: $hWnd - HWND des Fensters
    ; Return values .: Erfolg: - Array in folgendem Format:
    ; |[0] - X-Position des Clientbereichs
    ; |[1] - Y-Position des Clientbereichs
    ; |[2] - Breite des Clientbereichs
    ; |[3] - Höhe des Clientbereichs
    ; Fehler: - Array mit Inhalt [0, 0, 0, 0]
    ; @error:
    ; |0 = Kein Fehler
    ; |1 = Das übergebene HWND ist ungültig
    ; |2 = Fehler beim DllCall("GetWIndowInfo") - @extended enthält den Inhalt von @error
    ; Author ........: Großvater ( http://www.autoit.de)
    ; Modified.......:
    ; Remarks .......:
    ; Related .......:
    ; Link ..........: http://msdn.microsoft.com/en-us/library/…28VS.85%29.aspx
    ; Example .......:
    ; ===============================================================================================================================
    Func _WinGetClientPos($hWnd)
    Local $WINDOWINFO = DllStructCreate( _
    "DWORD cbSize;" & _
    "LONG rcWindow[4];" & _
    "LONG rcClient[4];" & _
    "DWORD dwStyle;" & _
    "DWORD dwExStyle;" & _
    "DWORD dwWindowStatus;" & _
    "UINT cxWindowBorders;" & _
    "UINT cyWindowBorders;" & _
    "WORD atomWindowType;" & _
    "WORD wCreatorVersion")
    DllStructSetData($WINDOWINFO, "cbSize", DllStructGetSize($WINDOWINFO))
    Local $PWINDOWINFO = DllStructGetPtr($WINDOWINFO)
    Local $aRECT[4] = [0, 0, 0, 0]
    If Not IsHWnd($hWnd) Then
    Return SetError(1, 0, $aRECT)
    EndIf
    Local $aResult = DllCall("User32.dll", "BOOL", "GetWindowInfo", "HWND", $hWnd, "Ptr", $PWINDOWINFO)
    If @error Or $aResult[0] = 0 Then
    Return SetError(2, @error, $aRECT)
    EndIf
    For $I = 1 To 4
    $aRECT[$I - 1] = DllStructGetData($WINDOWINFO, "rcClient", $I)
    Next
    $aRECT[2] -= $aRECT[0]
    $aRECT[3] -= $aRECT[1]
    Return $aRECT
    EndFunc ;==>_WinGetClientPos

    [/autoit]
    • Offizieller Beitrag

    Servus Großvater.

    Ich habe eben deine Funktion unter Vista Ultimate Sp2 getestet. Die Rückgabewerte sind 0.
    Werde es später noch mal unter Win7 und WinXp testen habe gerade keinen anderen Rechner zu verfügung.
    Der Inhalt kann nicht angezeigt werden, da er nicht mehr verfügbar ist.

    Edit: Unter Win7 ULtimate 64 und WinXP Sp3 klappt es einwandfrei :thumbup:
    Somit steht fest, Windows Vista war ein Scheißbetriebssystem.

  • Somit steht fest, Windows Vista war ein Scheißbetriebssystem.


    Ich kann Dir nicht unbedingt widersprechen, in diesem Fall ist Vista - zumindest in der Version Home Premium - allerdings unschuldig, dat läuft! ;)