FTP LIstToArray, nur mp3 Files Listen

Rene_RNI

Hallo, ich habe hier ein kleines Script zum Downloaden von MP3 Datein vin meinem Server

Nun sind in dem Verzeichniss auch andere Dateien, es sollen aber nur "*.mp3" Dateien in der FileListe auftauchen.

Hier mal des Script:

C

#include <Misc.au3>
#include <FTPEx.au3>
#include <array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListView.au3>
#include <GuiButton.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>


Opt('MustDeclareVars', 1)
Global $ListView1, $Dirlist1, $Label3, $Label4, $hot, $datum, $npfad, $Button1, $item1, $item2, $item3, $input1, $msg, $Server, $Username, $Passwort, $Path, $Ziel, $Open, $Conn, $SetDir, $DirList, $Item, $file, $file1, $Form1, $Label1, $Label2, $Button2


$Server = IniRead("config.ini", "Server", "IP", "")
$Username = IniRead("config.ini", "Server", "User", "")
$Passwort = IniRead("config.ini", "Server", "Passwort", "")


$Path = IniRead("config.ini", "Server", "Ordner", "")
$Ziel = IniRead("config.ini", "Server", "Ziel", "")


$Open = _FTP_Open('FTP-OTR')
$Conn = _FTP_Connect($Open, $Server, $Username, $Passwort, true)
$SetDir = _FTP_DirSetCurrent($Conn, $Path)
$DirList = _Ftp_ListToArray($Conn,2)
$Dirlist1 = _ArraySearch($DirList, "*.mp3")
If $Dirlist1 = 0 Then
	MsgBox(0, "", "Keine Dateien auf dem Server vorhanden", 5)
	Exit
Else
Example()	
EndIf


Func Example()

	GUICreate("RNI - News und Wetter", 237, 474, 335, 147, -1, $WS_EX_ACCEPTFILES)
	GUISetBkColor(0x002142)  ; will change background color

	$ListView1 = GUICtrlCreateListView("Datei", 8, 48, 218, 302)
	_GUICtrlListView_SetColumnWidth($ListView1, 0, $LVSCW_AUTOSIZE_USEHEADER)
	GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
	GUICtrlSetCursor (-1, 0)
	$Button1 = GUICtrlCreateButton("Herunterladen", 8, 360, 100, 25)
	$Label1 = GUICtrlCreateLabel("RNI - News und Wetter", 24, 16, 188, 24)
	GUICtrlSetFont(-1, 12, 800, 0, "MS Sans Serif")
	GUICtrlSetColor(-1, 0xC0C0C0)
	$Input1 = GUICtrlCreateInput("Input1", 8, 416, 217, 21)
	GUICtrlSetData(-1, $Ziel)
	GUICtrlSetState(-1, $GUI_DISABLE)
	$Label2 = GUICtrlCreateLabel("Speicherort:", 8, 400, 61, 17)
	GUICtrlSetColor(-1, 0xC0C0C0)
	$Button2 = GUICtrlCreateButton("Ändern", 8, 440, 75, 25)
	$Label3 = GUICtrlCreateLabel("Datum:", 120, 360, 36, 17)
	GUICtrlSetColor(-1, 0xC0C0C0)
	$Label4 = GUICtrlCreateLabel(@MDAY&"."&@MON&"."&@YEAR, 160, 360, 66, 17)
	GUICtrlSetColor(-1, 0xC0C0C0)




	For $i = 1 To $DirList1[0]
	$item1= GUICtrlCreateListViewItem($Dirlist1[$i], $ListView1)
	Next
	GUICtrlSetState(-1, $GUI_DROPACCEPTED)   ; to allow drag and dropping
	GUISetState()


	Do
		$msg = GUIGetMsg()

		Select

		Case $msg = $Button1
			$file=GUICtrlRead(GUICtrlRead($ListView1))
			$file1=StringTrimRight($file, 1)
			_FTP_ProgressDownload($Conn, $Ziel&$file1, $file1)
			_GUICtrlListView_DeleteItemsSelected($ListView1)


		Case $msg = $ListView1
			MsgBox(0, "listview", "clicked=" & GUICtrlGetState($ListView1), 2)
		Case $msg = $Button2
			$npfad=FileSelectFolder("Verzeichniss zum Speichern auswählen.", "")
			IniWrite("config.ini", "Server", "Ziel", $npfad&"\")
			GUICtrlSetData($Input1, $npfad&"\")
			$Ziel=$npfad&"\"
		EndSelect
	Until $msg = $GUI_EVENT_CLOSE
	_FTP_Close($Conn)
	_FTP_Close($Open)
EndFunc   ;==>Example

Alles anzeigen

wäre schön wenn mir hier jemand weiter helfen könnte

Gruß Rene

**AspirinJunkie**

Statt _FTP_ListToArray() selbst aus _FTP_FindFileFirst() und _FTP_FindFileNext() was basteln.

misterspeed

Oder halt einfach das Array im Anschluss filtern.

[autoit]

_arrayFindall()

[/autoit]

progandy

Übrigens lässt sich das Filtern des Array besser mit dieser Funktion lösen:
_ArrayFilter
(Hab ich in meiner Ablage gefunden)

GerhardSchr

Was ist der unterschied zwischen _ArrayFindAll und _ArraySearch ?

**autoBert**

Hallo GerhardSchr,

Zitat

_ArraySearch

Findet einen Eintrag in einem 1-dimensionalen oder 2-dimensionalen Array

Zitat

_ArrayFindAll

Findet die Indizes mit allen Vorkommen einer Suchabfrage zwischen zwei Punkten in einem 1-dimensionalen oder 2-dimensionalen Array

Quelle: dt. Hilfe

mfg autoBert

GerhardSchr

ah ok genau lesen
danke

**AspirinJunkie**

Und ich bin immer noch der Meinung:
Warum erst Informationen im Speicher bunkern welche eh nie gebraucht werden und danach wieder rausgefiltert werden anstatt gleich beim Einlesen nur das zu nehmen was man wirklich braucht?
Warum nicht damit?:

Spoiler anzeigen

[autoit]

#include <ftpEx.au3>
#include <array.au3>

[/autoit] [autoit][/autoit] [autoit]

$server = 'ftp.csx.cam.ac.uk'
$username = ''
$pass = ''

[/autoit] [autoit][/autoit] [autoit]

$hFTP = _FTP_Open('FTP_open')
$hFTPCon = _FTP_Connect($hFTP, $server, $username, $pass)

[/autoit] [autoit][/autoit] [autoit]

$aFileList = _FTP_ListToArray2($hFTPCon, "pub/information/courses/perl/", "*.zip", 1)
_ArrayDisplay($aFileList)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

; #FUNCTION# ======================================================================================
; Name ..........: _FTP_FileList()
; Description ...: Listet alle Dateien und Ordner in allen Ebenen eines FTP-Pfades
; Syntax ........: _FTP_FileList(Const $hConn[, $sPath = ""])
; Parameters ....: Const $hConn - Handle zu einer offenen FTP-Verbindung. (z.B. mit FTP_Open)
; $sPath - [optional] Ordnerpfad auf dem Server welcher durchsucht werden soll (default:"")
; $sPattern - Dateinamensfilterung anhand von WildCards (* und ?)
; Const $iFlag - 1=nur Dateien, 2=nur Ordner, 3=Dateien+Ordner
; $iSplitFlag - Siehe Parameter "flag" bei StringSplit()
; Return values .: Success: Array mit Datei/Ordnernamen
; Failure: Setzt @error = 1 und Array[0] = -1
; Author ........: AspirinJunkie
; Related .......: #include <ftpEx.au3>
; =================================================================================================
Func _FTP_ListToArray2(Const $hConn, $sPath = "", $sPattern = "*", Const $iFlag = 3, Const $iSplitFlag = 0)
Local $sRet = ""
Local $hFFFF, $aNext, $i

[/autoit] [autoit][/autoit] [autoit]

If StringRight($sPath, 1) = "/" Then $sPath = StringTrimRight($sPath, 1)
Local Const $aReplace[3][2] = [[".", "\."],["*", ".*"],["?", "."]]
For $i = 0 To 2
$sPattern = StringReplace($sPattern, $aReplace[$i][0], $aReplace[$i][1])
Next

[/autoit] [autoit][/autoit] [autoit]

$aNext = _FTP_FindFileFirst($hConn, $sPath, $hFFFF)
If @error Then
Local $Ret[1] = [-1]
Return SetError(1, @error, $Ret)
EndIf

[/autoit] [autoit][/autoit] [autoit]

If (BitAND($aNext[1], 16) And BitAND($iFlag, 2)) Or ((Not BitAND($aNext[1], 16)) And BitAND($iFlag, 1)) Then
If StringRegExp($aNext[10], $sPattern) Then $sRet &= $aNext[10] & "|"
EndIf

[/autoit] [autoit][/autoit] [autoit]

Do
$aNext = _FTP_FindFileNext($hFFFF)
If @error Then ExitLoop
If (BitAND($aNext[1], 16) And BitAND($iFlag, 2)) Or ((Not BitAND($aNext[1], 16)) And BitAND($iFlag, 1)) Then
If StringRegExp($aNext[10], $sPattern) Then $sRet &= $aNext[10] & "|"
EndIf
Until 0

[/autoit] [autoit][/autoit] [autoit]

_FTP_FindFileClose($hFFFF)

[/autoit] [autoit][/autoit] [autoit]

If $sRet = "" Then
Local $Ret[1] = [-1]
Return SetError(2, @error, $Ret)
EndIf

[/autoit] [autoit][/autoit] [autoit]

Return StringSplit(StringTrimRight($sRet, 1), "|", $iSplitFlag)
EndFunc ;==>_FTP_ListToArray2

[/autoit]

progandy

AspirinJunkie: Die Wildcards kann man doch direkt in den $sPath-Parameter schreiben. Das muss man nicht extra per Regex machen.

**AspirinJunkie**

Danke dir - dann gehts natürlich noch einfacher:

Spoiler anzeigen

[autoit]

#include <ftpEx.au3>
#include <array.au3>

[/autoit] [autoit][/autoit] [autoit]

$server = 'ftp.csx.cam.ac.uk'
$username = ''
$pass = ''

[/autoit] [autoit][/autoit] [autoit]

$hFTP = _FTP_Open('FTP_open')
$hFTPCon = _FTP_Connect($hFTP, $server, $username, $pass)

[/autoit] [autoit][/autoit] [autoit]

$aFileList = _FTP_ListToArray2($hFTPCon, "pub/information/courses/perl/", "*.zip", 1)
_ArrayDisplay($aFileList)

[/autoit] [autoit][/autoit] [autoit][/autoit] [autoit]

; #FUNCTION# ======================================================================================
; Name ..........: _FTP_FileList()
; Description ...: Listet alle Dateien und Ordner in allen Ebenen eines FTP-Pfades
; Syntax ........: _FTP_FileList(Const $hConn[, $sPath = ""])
; Parameters ....: Const $hConn - Handle zu einer offenen FTP-Verbindung. (z.B. mit FTP_Open)
; $sPath - [optional] Ordnerpfad auf dem Server welcher durchsucht werden soll (default:"")
; $sPattern - Dateinamensfilterung anhand von WildCards (* und ?)
; Const $iFlag - 1=nur Dateien, 2=nur Ordner, 3=Dateien+Ordner
; $iSplitFlag - Siehe Parameter "flag" bei StringSplit()
; Return values .: Success: Array mit Datei/Ordnernamen
; Failure: Setzt @error = 1 und Array[0] = -1
; Author ........: AspirinJunkie
; Related .......: #include <ftpEx.au3>
; =================================================================================================
Func _FTP_ListToArray2(Const $hConn, $sPath = "", $sPattern = "*", Const $iFlag = 3, Const $iSplitFlag = 0)
Local $sRet = ""
Local $hFFFF, $aNext, $i

[/autoit] [autoit][/autoit] [autoit]

If StringRight($sPath, 1) = "/" Then $sPath = StringTrimRight($sPath, 1)

[/autoit] [autoit][/autoit] [autoit]

$aNext = _FTP_FindFileFirst($hConn, $sPath & "/" & $sPattern, $hFFFF)
If @error Then
Local $Ret[1] = [-1]
Return SetError(1, @error, $Ret)
EndIf
If (BitAND($aNext[1], 16) And BitAND($iFlag, 2)) Or ((Not BitAND($aNext[1], 16)) And BitAND($iFlag, 1)) Then $sRet &= $aNext[10] & "|"

[/autoit] [autoit][/autoit] [autoit]

Do
$aNext = _FTP_FindFileNext($hFFFF)
If @error Then ExitLoop
If (BitAND($aNext[1], 16) And BitAND($iFlag, 2)) Or ((Not BitAND($aNext[1], 16)) And BitAND($iFlag, 1)) Then $sRet &= $aNext[10] & "|"
Until 0

[/autoit] [autoit][/autoit] [autoit]

_FTP_FindFileClose($hFFFF)

[/autoit] [autoit][/autoit] [autoit]

If $sRet = "" Then
Local $Ret[1] = [-1]
Return SetError(2, @error, $Ret)
EndIf

[/autoit] [autoit][/autoit] [autoit]

Return StringSplit(StringTrimRight($sRet, 1), "|", $iSplitFlag)
EndFunc ;==>_FTP_ListToArray2

[/autoit]

Rene_RNI

Werde ich dann gleich mal ausprobieren!

danke schon mal