WinSetTrans

**GtaSpider**

Hi!

nich viel.. aber etwas.. ein programm mit dem man genau bestimmen kann wie doll ein fenster transparent wird, wie bei dem zukünftigen windows longhorn...

edit: kleiner bug behoben

Code

#include <GUIConstants.au3>


$Form1 = GUICreate("Set Trans - By GtaSpider",157, 125, 192, 125)
$Slider1 = GUICtrlCreateSlider(8, 32, 142, 29)
GUICtrlSetLimit(-1,255)
$Combo1 = GUICtrlCreateCombo("Choose", 8, 8, 145, 21)
$wl = WinList()
$setcomb = ""
For $i = 1 To $wl[0][0]
	if $wl[$i][0] <> "" And $wl[$i][0] <> "Set Trans - By GtaSpider" AND IsVisible($wl[$i][1]) Then
		$setcomb &= $wl[$i][0]&"|"
	EndIf
Next
GUICtrlSetData($Combo1,$setcomb)
GUICtrlCreateLabel("0%", 16, 72, 18, 17)
GUICtrlCreateLabel("100%", 120, 72, 30, 17)
$Progress1 = GUICtrlCreateProgress(35, 72, 83, 17)
GUICtrlSetColor(-1, 0x335EA8)
$update = GUICtrlCreateButton("&Update",10,95,137)
GUISetState(@SW_SHOW)


$old = 0


While 1
	$new = GUICtrlRead($Slider1)
	$msg = GuiGetMsg()
	Select
	Case $msg = $GUI_EVENT_CLOSE
		ExitLoop
	Case $msg = $update
		GUICtrlSetData($Combo1,"")
		$wl = WinList()
		$setcomb = "Choose|"
		For $i = 1 To $wl[0][0]
			if $wl[$i][0] <> "" And $wl[$i][0] <> "Set Trans - By GtaSpider" AND IsVisible($wl[$i][1]) Then
				$setcomb &= $wl[$i][0]&"|"
			EndIf
		Next
		GUICtrlSetData($Combo1,$setcomb,"Choose")
	Case $old <> $new
		WinSetTrans(GUICtrlRead($Combo1),"",255-$new)
		GUICtrlSetData($Progress1,$new*100/255)
		If $new = 0 Then WinSetTrans(GUICtrlRead($Combo1),"",0)
		$old = $new
	EndSelect
WEnd
Exit






Func IsVisible($handle)
  If BitAnd( WinGetState($handle), 2 ) Then 
    Return 1
  Else
    Return 0
  EndIf


EndFunc

Alles anzeigen

mfg Spielkind^^

Unicom

Ich hab das mal für meine Zwecke umgestaltet.
Hab eine stay-on-top funktion dazugefügt, was praktisch ist wenn man mit mehreren Fenstern gleichzeitig arbeitet. Die Combobox läuft jetzt auch nicht über.

C

;Stay on Top - Transparency Manger


#include <GUIConstants.au3>


$main = GUICreate("SoTTM",157, 125, 192, 125)
$Slider1 = GUICtrlCreateSlider(8, 32, 142, 29)
GUICtrlSetLimit(-1,255)
$Combo1 = GUICtrlCreateCombo("Choose", 8, 8, 145, 160)
$wl = WinList()
$setcomb = ""
For $i = 1 To $wl[0][0]
	if $wl[$i][0] <> ""  And $wl[$i][0]  AND IsVisible($wl[$i][1])  Then
		$setcomb = $setcomb & StringLeft ( $wl[$i][0], 23 ) &"|"
	EndIf
Next
GUICtrlSetData($Combo1,$setcomb)


$ontopon = GUICtrlCreateButton("On top on",10,70,60)
$ontopoff = GUICtrlCreateButton("On top off",87,70,60)


$update = GUICtrlCreateButton("&Update",10,95,137)
GUISetState(@SW_SHOW)


$old = 0
While 1
	$new = GUICtrlRead($Slider1)
	$msg = GuiGetMsg()


	Select
	Case $msg = $GUI_EVENT_CLOSE
		ExitLoop


	Case $msg = $update
		GUICtrlSetData($Combo1,"")
		$wl = WinList()
		$setcomb = "Choose|"
		For $i = 1 To $wl[0][0]
			if $wl[$i][0] <> "" AND IsVisible($wl[$i][1]) Then
				$setcomb = $setcomb & StringLeft ( $wl[$i][0], 23 ) &"|"
			EndIf
		Next
		GUICtrlSetData($Combo1,$setcomb,"Choose")

	case $msg=$ontopon
	WinSetOnTop(GUICtrlRead($Combo1), "", 1)	


	case $msg=$ontopoff
	WinSetOnTop(GUICtrlRead($Combo1), "", 0)


	Case $old <> $new
		WinSetTrans(GUICtrlRead($Combo1),"",255-$new)
		If $new = 0 Then WinSetTrans(GUICtrlRead($Combo1),"",0)
		$old = $new
	EndSelect
Wend
Exit


Func IsVisible($handle)
  If BitAnd( WinGetState($handle), 2 ) Then 
    Return 1
  Else
    Return 0
  EndIf
EndFunc

Alles anzeigen

Health

sehr genial, könnte man das irgendwie unten in die taskleiste basteln?

:party4:

kann man das nich irgendwie ins tray minimieren und dann immer wieder öffnen?

€: ich hab mir das mal von Unicom bisschen verschönert :tier:

so jetz kann man es "ins tray minimieren", doppelklick aufs symbol machts wieder sichtbar

so glaube letzte mal das ich meine veränderungen poste

PHP

#include <GUIConstants.au3>
#Include <Constants.au3>


$g_szVersion = "SetTrans"
If WinExists ($g_szVersion) Then Exit
AutoItWinSetTitle ($g_szVersion)
Break (0)
TraySetState ()
TraySetToolTip ("SetTrans")


$main = GUICreate ("SetTrans", 200, 150)
$Slider1 = GUICtrlCreateSlider (10, 40, 180, 30)
GUICtrlSetLimit (-1, 255, 0)
$Combo1 = GUICtrlCreateCombo ("---- wähle ----", 10, 10, 180, 200)
$wl = WinList ()
$setcomb = ""


For $i = 1 To $wl[0][0]
	if $wl[$i][0] <> "" And $wl[$i][0] AND IsVisible ($wl[$i][1]) Then
		$setcomb = $setcomb & StringLeft ($wl[$i][0], 30) & "|"
	EndIf
Next


GUICtrlSetData ($Combo1, $setcomb)


$ontopon = GUICtrlCreateButton ("TOP ON", 10, 82, 85)
$ontopoff = GUICtrlCreateButton ("TOP OFF", 105, 82, 85)


$update = GUICtrlCreateButton ("Aktualisieren", 10, 115, 85)
$min = GUICtrlCreateButton ("Minimieren", 105, 115, 85)
GUISetState (@SW_SHOW)


$old = 0
While 1
	$new = GUICtrlRead ($Slider1)
	$msg = GuiGetMsg ()
	$tmsg = TrayGetMsg ()


	Select
	Case $tmsg = $TRAY_EVENT_PRIMARYDOUBLE
		GUICtrlSetData ($Combo1, "")
		$wl = WinList ()
		$setcomb = "---- wähle ----|"
		For $i = 1 To $wl[0][0]
			if $wl[$i][0] <> "" AND IsVisible ($wl[$i][1]) Then
				$setcomb = $setcomb & StringLeft ($wl[$i][0], 30) & "|"
			EndIf
		Next
		GUICtrlSetData (3, 0)
		GUICtrlSetData ($Combo1, $setcomb, "---- wähle ----")
		WinSetState ("SetTrans", "", @SW_SHOW)


	Case $msg = $GUI_EVENT_CLOSE
		ExitLoop

	Case $msg = $GUI_EVENT_MINIMIZE
		WinSetState ("SetTrans", "", @SW_HIDE)


	Case $msg = $update
		GUICtrlSetData ($Combo1, "")
		$wl = WinList ()
		$setcomb = "---- wähle ----|"
		For $i = 1 To $wl[0][0]
			if $wl[$i][0] <> "" AND IsVisible ($wl[$i][1]) Then
				$setcomb = $setcomb & StringLeft ($wl[$i][0], 30) & "|"
			EndIf
		Next
		GUICtrlSetData (3, 0)
		GUICtrlSetData ($Combo1, $setcomb, "---- wähle ----")


	Case $msg = $min
		WinSetState ("SetTrans", "", @SW_HIDE)

	Case $msg = $ontopon
		WinSetOnTop (GUICtrlRead ($Combo1), "", 1)	


	Case $msg = $ontopoff
		WinSetOnTop (GUICtrlRead ($Combo1), "", 0)


	Case $old <> $new
		WinSetTrans (GUICtrlRead ($Combo1), "", 255-$new)
		GUICtrlSetTip (3, $new)
		$old = $new
	EndSelect
Wend
Exit


Func IsVisible ($handle)
  If BitAnd (WinGetState ($handle), 2) Then
    Return 1
  Else
    Return 0
  EndIf
EndFunc

Alles anzeigen

Health

wie kann ich da jetzt bestimmte fenster rausnehmen wie zb program manager?

Unicom

wenn es nur um den programm manger geht dann wohl so:

Zeile 19 & 45:
if $wl[$i][0] <> "" And $wl[$i][0] <>"Program Manager" AND IsVisible($wl[$i][1]) Then

wolkenloser

Hi, ein nettes Programm.

Ich habs mal ausprobiert, leider scheint es aber mit DOS Fenstern (CMD) nicht zu funktionieren.

Weißt Du warum ?

**peethebee**

Das geht nicht.
Ist halt kein Windows-Fenster, denke ich. Ist ja nur emluiertes DOS.

peethebee

wolkenloser

ja, aber es ist ein Fenster in Windows....

Unicom

also mit Fenster rausnehmen könnte es so aussehen:

Hab eine dynamische Liste mit den Ignornamen, zu der man via der Auswahl noch welche dazufügen kann.

Ich mußte noch Fenster mit "|" im Namen rausfiltern - die verhunzen die Comboboxauswahl.

C

#include <GUIConstants.au3>
#Include <Constants.au3>
#include <Array.au3>


$g_szVersion = "SetTrans"
If WinExists ($g_szVersion) Then Exit
AutoItWinSetTitle ($g_szVersion)
Break (0)
TraySetState ()
TraySetToolTip ("SetTrans")


$main = GUICreate ("SetTrans", 200, 180)
$Slider1 = GUICtrlCreateSlider (10, 40, 180, 30)
GUICtrlSetLimit (-1, 255, 0)
$Combo1 = GUICtrlCreateCombo ("---- wähle ----", 10, 10, 180, 200)


Dim $ignorelist[1]
$ignorelist[0] ="Program Manager"
updatecombo()
$ontopon = GUICtrlCreateButton ("TOP ON", 10, 82, 85)
$ontopoff = GUICtrlCreateButton ("TOP OFF", 105, 82, 85)
$update = GUICtrlCreateButton ("Aktualisieren", 10, 115, 85)
$min = GUICtrlCreateButton ("Minimieren", 105, 115, 85)
$ignore = GUICtrlCreateButton ("ignorieren", 10, 150, 85)
$ignorereset = GUICtrlCreateButton ("Ignor aufheben", 105, 150, 85)
GUISetState (@SW_SHOW)


$old = 0
While 1
    $new = GUICtrlRead ($Slider1)
    $msg = GuiGetMsg ()
	$tmsg = TrayGetMsg ()


    Select
		Case $tmsg = $TRAY_EVENT_PRIMARYDOUBLE
    	updatecombo ()
	    WinSetState ("SetTrans", "", @SW_SHOW)	
	case $msg = $ignore
			$info= StringLeft(GUICtrlRead ($Combo1),30)
			_ArrayAdd ( $ignorelist, $info )		
			updatecombo()
	Case $msg =$ignorereset
			dim $ignorelist[1]
			$ignorelist[0] ="Program Manager"
			updatecombo()
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop

    Case $msg = $GUI_EVENT_MINIMIZE
        WinSetState ("SetTrans", "", @SW_HIDE)


    Case $msg = $update
        updatecombo()


    Case $msg = $min
        WinSetState ("SetTrans", "", @SW_HIDE)

    Case $msg = $ontopon
        WinSetOnTop (GUICtrlRead ($Combo1), "", 1)    


    Case $msg = $ontopoff
        WinSetOnTop (GUICtrlRead ($Combo1), "", 0)


    Case $old <> $new
        WinSetTrans (GUICtrlRead ($Combo1), "", 255-$new)
        GUICtrlSetTip (3, $new)
        $old = $new
    EndSelect
Wend
Exit


Func IsVisible ($handle)
  If BitAnd (WinGetState ($handle), 2) Then
    Return 1
  Else
    Return 0
  EndIf
EndFunc


Func updatecombo ()       ;aktualisiert die Combolist
	GUICtrlSetData ($Combo1, "")
	    $wl = WinList ()
        $setcomb = "---- wähle ----|"
        For $i = 1 To $wl[0][0]
			if $wl[$i][0] <> ""  And  IsVisible($wl[$i][1]) AND myArraySearch($ignorelist, $wl[$i][0])=0 Then
				$split = StringSplit($wl[$i][0],"|")
				$setcomb = $setcomb & StringLeft ($split[1], 30) & "|"
			EndIf
        Next
        GUICtrlSetData (3, 0)
        GUICtrlSetData ($Combo1, $setcomb, "---- wähle ----")
EndFunc

Func myArraySearch($feld, $value)
		$result = 0
		$split = StringSplit($value,"|")
		$value = $split[1]
			for $i = 0 to UBound($feld)-1
			If StringLeft ($value,30) = StringLeft($feld[$i],30) Then
						$result=1
					ExitLoop
			EndIf
			Next

	Return $result
EndFunc

Alles anzeigen

**bernd670**

Hallo,

wenn du mit _GUICtrlComboAddString(), aus GUICombo.au3 (beta), die Fensternamen hinzufügst kann du auch Namen hinzufügen die "|" enthalten.

Code

#include <GUICombo.au3>


...


Func updatecombo ()       ;aktualisiert die Combolist
    GUICtrlSetData ($Combo1, "")
    $wl = WinList ()
    _GUICtrlComboAddString($Combo1,"---- wähle ----")
    For $i = 1 To $wl[0][0]
        if $wl[$i][0] <> ""  And  IsVisible($wl[$i][1]) AND myArraySearch($ignorelist, $wl[$i][0])=0 Then
            _GUICtrlComboAddString($Combo1,$wl[$i][0])
        EndIf
    Next
    GUICtrlSetData (3, 0)
    _GUICtrlComboSetCurSel($Combo1,0)
EndFunc


...

Alles anzeigen