Fragen zur Syntax oder Hilfe zur Selbsthilfe

msdotz

Hallo an alle,
ich habe hier mal einige Frage die Syntax betreffend. Ich stelle sie hier, weil mir die Hilfe nicht immer eine war.

Die Grundstruktur eines Befehles/ einer Funktion ist fast immer: Funktionsname( "Title", "Text", ControlID, [ weitere Parameter])
Die Hilfe-Beispiele laufen zu 90% so ab: Funktionsname("[CLASS:Notepad]", "") gibt etwas zurück oder meist 0 im Fehlerfall.

a) Kann man immer den Handle des Fensters statt der CLASS-Syntax verwenden? (Klare Ausnahme bei WinGetHandle)
b) Welcher Aufruf ist korrekt? Beispiel:

In der Hilfe steht: ControlFocus("[CLASS:Notepad]", "", "Edit1")

$strClassName = " Edit"
$ClassNN= 1
$OK = ControlFocus($HWndFenster, "", $strClassName & $ClassNN) ; Funktioniert
$OK = ControlFocus($HWndControl, "", "") ; Funktioniert nicht immer
$OK = ControlFocus($HWndFenster, "", $HWndControl) ; Funktioniert anscheinend nicht

Wo und wie finde ich heraus, außer durch rumprobieren, wann man welche Schreibweise bzw. Ersetzung der Parameter vornehmen kann.
Diese 0815-Beispiele mit dem Notepad sind da eher weniger hilfreich. Also wenn mir da jemand die richtigen Antworten geben könnte, das wäre schon super.

Noch eine Frage zum Forum selbst: Wie kann ich Programmcode posten, ohne dass die Formatierung verloren geht? (Export als Html und dann Quelltext und einfügen ? Bisher war nach dem Einfügen immer alles schön linksbündig.

Danke vorab für Eure Hilfe
MsDotz

name22

Zitat

a) Kann man immer den Handle des Fensters statt der CLASS-Syntax verwenden? (Klare Ausnahme bei WinGetHandle)

Klar ;).

Zitat

b) Welcher Aufruf ist korrekt? Beispiel:

Naja... Das kommt darauf an was du machen willst. Allerdings solltest du beachten, das ein Handle sich beim neustart eines Programms ändert (du müsstest es also immer wieder aufs Neue herrausfinden).

misterspeed

Zitat von msdotz

Noch eine Frage zum Forum selbst: Wie kann ich Programmcode posten, ohne dass die Formatierung verloren geht? (Export als Html und dann Quelltext und einfügen ? Bisher war nach dem Einfügen immer alles schön linksbündig.

Indem du den Autoit Quellcode Button verwendest -->
Bei umfangreicherem Quellcode empfhielt sich zusätzlich noch ein Spoiler -->

Code

[spoiler][autoit]; dein Quellcode[/autoit][/spoiler]

schaut dann so aus:

Spoiler anzeigen

[autoit]

; dein Quellcode

[/autoit]

Sollte die Formatierung dennoch verloren gehen liegt das an deinem Browser, in diesem Falle den IE oder FF verwenden und ggf JavaScript für autoit.de erlauben.

msdotz

Danke für die schnelle Antwort. Das mit der Lebenserwartung eines Handles ist mir schon bewußt.
Habe schließlich seit Anfang an Windowssoftware erstellt.
Deshalb eiere ich ja auch so rum mit Autoit. Ich dachte, der Name sei hier der Zweck (Automate It).
Bin da etwas ernüchtert mittlerweile. Ich versuche eine fremde Anwendung zu automatisieren.
Für "statische Fenster", die keine, während der Laufzeit erzeugten Controls beinhalten, funktioniert alles prächtig.
Aber wehe wenn, dann geht das Probieren los.
Ich benutze z.B. eine aufgebohrte Version von _WinGetcontrols hier aus dem Forum, die mir sehr hilfreich ist (danke an die Autoren).
Ich habe nur das Rückgabe-Array aufgebohrt, d.h es liefert mir jetzt auch den Text und die Position (x,y,Width,Height) zurück.
Dachte halt, wenn ich Classname, ID, NN, Handle, Position und Text habe, dann sollte ja ein SetFocus und ein ControlClick nicht mehr vom Zufall
abhängig sein. Dachte ich. Bin noch nicht vom Gegenteil überzeugt.
Kann ich gerne posten, sobald mir einer das mit der Formatierung erklärt hat .

msdotz

misterspeed: ich benutze den Google-Chrome, kann allerdings auch für diese Zwecke den Firefox nehmen.
Danke
MsDotz

name22

Zitat

Dachte halt, wenn ich Classname, ID, NN, Handle, Position und Text habe, dann sollte ja ein SetFocus und ein ControlClick nicht mehr vom Zufall
abhängig sein. Dachte ich. Bin noch nicht vom Gegenteil überzeugt.

Das ist dann auch nicht vom Zufall abhängig. Ohne ein Stück Code oder die entsprechenden Informationen kann ich allerdings nur raten, wieso es nur manchmal funktioniert...

**Greenhorn**

Hallo msdotz,

Zitat von msdotz

a) Kann man immer den Handle des Fensters statt der CLASS-Syntax verwenden? (Klare Ausnahme bei WinGetHandle)
b) Welcher Aufruf ist korrekt? Beispiel:

In der Hilfe steht: ControlFocus("[CLASS:Notepad]", "", "Edit1")

In der Hilfe steht auch:

Zitat von ControlFocus

Code

Parameter


title        |    Der Titel des Fensters, auf das zugegriffen werden soll.
...
ControlID    |    Die ID des Controls, das beeinflusst werden soll. ...

"title" ist also immer das Parentfenster. Für diesen Parameter kannst Du ein Handle übergeben.

[autoit]

$strClassName = "Edit"
$ClassNN= 1
$ID_EDIT = 15

[/autoit][autoit][/autoit][autoit]

$OK = ControlFocus($HWndParent, "", $strClassName & $ClassNN) ; Funktioniert
$OK = ControlFocus ($HWndParent, "", $ID_EDIT) ; Funktioniert
$OK = ControlFocus($HWndParent, "", $HWndControl) ; Funktioniert nicht !
$OK = WinActivate ($HWndControl, "", "") ; Könnte schon eher funktionieren ...

[/autoit]

Zitat von msdotz

Wo und wie finde ich heraus, außer durch rumprobieren, wann man welche Schreibweise bzw. Ersetzung der Parameter vornehmen kann.
Diese 0815-Beispiele mit dem Notepad sind da eher weniger hilfreich. Also wenn mir da jemand die richtigen Antworten geben könnte, das wäre schon super.

Herumprobieren muss man immer, leider bringt AutoIt keinen brauchbaren Debugger mit.

Beispiele findest Du genug im Forum, Stichwort "Installationsskripte".
Oder hier ...

EDIT:
Dieser Beitrag hilft Dir vllt auch weiter ...

Gruß und viel Spaß mit AutoIt
Greenhorn

msdotz

name22:

ich stelle hier mal den code ein, den ich zum Control finden verwende. Die _WinGetControls - Funktion stammt hier aus dem Forum (Grossvater?).
Ich habe nur etwas erweitert. Die Funktion PositionsDatenErmitteln ist von mir. Ich suche damit das EditControl, das den Text $strText enthält ($iModus=1).
Im $iModus=2 suche ich das EditControl in der selben Zeile, von dem ich nur weis, wo die X-Pos liegt.

Spoiler anzeigen

C

#include <GUIEdit.au3>
#include <WinAPI.au3>
#include-once


Func _WinGetControls($hWnd)
 Local Const $GWL_STYLE = 0xFFFFFFF0
 Local Const $BS_AUTOCHECKBOX = 0x0003
 Local Const $BS_CHECKBOX = 0x0002
 Local Const $BS_GROUPBOX = 0x0007
 Local Const $BS_RADIOBUTTON = 0x0004
 Local Const $BS_AUTORADIOBUTTON = 0x0009
 Local Const $ES_MULTILINE = 4
 Local Const $ES_WANTRETURN = 4096
 Local Const $SS_ICON = 0x3
 Local Const $SS_BITMAP = 0xE
 Local Const $WS_VSCROLL = 0x00200000
 Local Const $ES_EDIT = BitOR($ES_WANTRETURN, $WS_VSCROLL)
 Local $UControls = 100
 Local $UClasses = 50
 Local $aControls[$UControls + 1][11]   ; Erweitert für die neuen Einträge
 Local $aClasses[$UClasses + 1][2]
 Local $aResult, $AU3, $C, $Class, $ClassExist, $Handle, $ID, $NN, $Styles
 Local $CtlText, $CtlPos  ; Neu für Text und Position


If Not IsHWnd($hWnd) Then Return SetError(1, 0, False)


Local $sClasses = WinGetClassList($hWnd)
 Local $aSplit = StringSplit(StringStripWS($sClasses, 2), @LF)


$aControls[0][0] = 0
 $aClasses[0][0] = 0


For $I = 1 To $aSplit[0]
     $Class = $aSplit[$I]
     $ClassExist = False
     $C = $aClasses[0][0]
     For $J = 1 To $C
         If $aClasses[$J][0] = $Class Then
             $NN = $aClasses[$J][1] + 1
             $aClasses[$J][1] = $NN
             $ClassExist = True
             ExitLoop
         EndIf
     Next
     If Not $ClassExist Then
         $NN = 1
         $C += 1
         If $C > $UClasses Then
             $UClasses += 50
             ReDim $aClasses[$UClasses + 1][2]
         EndIf
         $aClasses[0][0] = $C
         $aClasses[$C][0] = $Class
         $aClasses[$C][1] = $NN
     EndIf
     $Handle = ControlGetHandle($hWnd, "", $Class & $NN)
     $aResult = DllCall("User32.dll", "Int", "GetDlgCtrlID", "HWND", $Handle)
     If @error Or $aResult[0] = 0 Then
         $ID = ""
     Else
         $ID = $aResult[0]
     EndIf
     $C = $aControls[0][0] + 1
     If $C > $UControls Then
         $UControls += 100
         ReDim $aControls[$UControls + 1][11]
     EndIf
     ; Ausgeliehen aus der WinAPI.au3
     Local $sFuncName = "GetWindowLongW"
     If @AutoItX64 Then $sFuncName = "GetWindowLongPtrW"
     $aResult = DllCall("User32.dll", "LONG_PTR", $sFuncName, "HWND", $Handle, "INT", $GWL_STYLE)
     $Styles = $aResult[0]
     ; Erweiterung nach Vorschlag von UEZ
     Switch $Class
         Case "Button"
             If BitAND($Styles, $BS_GROUPBOX) = $BS_GROUPBOX Then
                 $AU3 = "Group"
             ElseIf BitAND($Styles, $BS_CHECKBOX) = $BS_CHECKBOX Then
                 $AU3 = "Checkbox"
             ElseIf BitAND($Styles, $BS_AUTOCHECKBOX) = $BS_AUTOCHECKBOX Then
                 $AU3 = "Checkbox"
             ElseIf BitAND($Styles, $BS_RADIOBUTTON) = $BS_RADIOBUTTON Then
                 $AU3 = "Radio"
             ElseIf BitAND($Styles, $BS_AUTORADIOBUTTON) = $BS_AUTORADIOBUTTON Then
                 $AU3 = "Radio"
             Else
                 $AU3 = "Button"
             EndIf
         Case "Static"
             If BitAND($Styles, $SS_ICON) = $SS_ICON Then
                 $AU3 = "Icon"
             ElseIf BitAND($Styles, $SS_BITMAP) = $SS_BITMAP Then
                 $AU3 = "Pic"
             Else
                 $AU3 = "Label"
             EndIf
         Case "Edit"
             If BitAND($Styles, $ES_EDIT) = $ES_EDIT Then
                 $AU3 = "Edit"
             Else
                 $AU3 = "Input"
             EndIf
         Case "SysAnimate32"
             $AU3 = "AVI"
         Case "ComboBox"
             $AU3 = "Combo"
         Case "SysDateTimePick32"
             $AU3 = "Date"
         Case "ListBox"
             $AU3 = "List"
         Case "SysListView32"
             $AU3 = "ListView"
         Case "SysMonthCal32"
             $AU3 = "MonthCal"
         Case "msctls_progress32"
             $AU3 = "Progress"
         Case "msctls_trackbar32"
             $AU3 = "Slider"
         Case "SysTabControl32"
             $AU3 = "Tab"
         Case "SysTreeView32"
             $AU3 = "TreeView"
         Case "msctls_updown32"
             $AU3 = "UpDown"
         Case Else
             $AU3 = ""
     EndSwitch
     ;##################################################################
     ;# Lese Text des Controls
     ;##################################################################
     $CtlText = _GUICtrlEdit_GetText($Handle) ;  GetControlText($Handle)




    ;##################################################################
     ;# Lese Position des Controls
     ;##################################################################
     ; $CtlPos = ControlGetPos($Handle,"","")
     ; Welcher Aufruf ist korrekt ?
     ; oder geht auch:  $CtlPos = ControlGetPos($hWnd, "", $Handle)


     $CtlPos = ControlGetPos($hWnd, "", $Class & $NN)


     $aControls[0][0] = $C
     $aControls[$C][0] = $Handle
     $aControls[$C][1] = $Class
     $aControls[$C][2] = $NN
     $aControls[$C][3] = $ID
     $aControls[$C][4] = $AU3
     $aControls[$C][5] = $CtlText
     $aControls[$C][6] = ControlCommand($hWnd, "", $ID, "IsVisible", "")
     ; Position auslesen
     if IsArray($CtlPos) Then
         $aControls[$C][7] = $CtlPos[0]
         $aControls[$C][8] = $CtlPos[1]
         $aControls[$C][9] = $CtlPos[2]
         $aControls[$C][10] = $CtlPos[3]
     Else
         $aControls[$C][7] = -1
         $aControls[$C][8] = -1
         $aControls[$C][9] = -1
         $aControls[$C][10] = -1
     EndIf


Next
 $C = $aControls[0][0] + 1
 ReDim $aControls[$C][11]
 Return $aControls
 EndFunc   ;==>_WinGetControls


Func PositionsDatenErmitteln ($iModus, $WndHandle,  $strText,  ByRef $strClassName, ByRef $HWndControl, ByRef $ClassID, ByRef $ClassNN, ByRef $iControlX, ByRef $iControlY, ByRef $iControlWidth, ByRef $iControlHeight)
Local $x = 0
Local $aControls = _WinGetcontrols($WndHandle)
local $Returnwert = -1


	For $x = 1 To $aControls[0][0]
		if $iModus = 1 Then
			;If $aControls[$x][5] <> "" then MsgBox(0,"Text gefunden", $aControls[$x][5], 1)
			If $aControls[$x][5] = $strText Then
				$Returnwert = $x
				ExitLoop
			EndIf
		ElseIf $iModus = 2 Then ; Suchen nach ControlX-Koordinate des Controls
			If ($aControls[$x][7] = $iControlX) And  ($aControls[$x][8] = $iControlY)  Then
				$Returnwert = $x
				ExitLoop
			EndIf
		EndIf
	Next


	If $Returnwert > 0 Then
		$HWndControl =  $aControls[$x][0]
		$strClassName = $aControls[$x][1]
		$ClassNN = $aControls[$x][2]
		$ClassID = $aControls[$x][3]
		$iControlX = $aControls[$x][7]
		$iControlY = $aControls[$x][8]
		$iControlWidth = $aControls[$x][9]
		$iControlHeight = $aControls[$x][10]
	Else
		$HWndControl = ""
		$strClassName = ""
		$ClassNN = -1
		$ClassID = -1
		$iControlX = -1
		$iControlY = -1
		$iControlWidth = -1
		$iControlHeight = -1
	EndIf


	MsgBox (0, "DEBUG", $strClassName & $ClassNN & " : Text gefunden in: " & $Returnwert, 1)
	Return $Returnwert
EndFunc

Alles anzeigen

Mit den Rückgabewerten dieser Funktion versuche ich eine neue Zeile in einer dynamisch erzeugten Eingabezeile korrekt zu befüllen. Das Ganze ist eine Positionserfassung in einem Warenwirschaftssystem. Fertig erfasste Zeile bewirkt automatisch die Erzeugung einer neuen leeren Eingabezeile.
Mit den Rückgabewerten meiner Funktion versuche ich einen MouseClick, aber da stimmen die Koordinaten nicht ganz. Aber ein ControlFocus sollte funktionieren. Ein ControlSend klappt auch nicht immer, obwohl ich lange Sleeps eingebaut habe.

Grüsse
MsDotz