Pipette

Cheater Dieter

Hi, ich habe ein kleines Script gemacht (110 Zeilen) welches es euch ermöglicht, Farben, die auf dem Bildschirm dargestellt werden zu identifizieren (als HEX, RBG und RBG %). Schaut es euch einfach mal an. Es ist wirklich nichts Großes, aber vielleicht findet ja der ein oder andere daran Gefallen. Ich werde in nächster Zeit wahrscheinlich noch ein paar Updates rausbringen.

Feedback ist erwünscht .

[Blockierte Grafik: http://cheaterd.cwsurf.de/Pipette.jpg]

Version 1.1:

Code jetzt ressourcenschonender (danke an Kizum)

Version 1.2

Bugfix beim Kopieren des RGB Farbwerts
Icon binär eingebunden
Code optimiert (danke an RR04)

Version 1.2.1

Code "verschönert" - keinerlei Änderrungen an Programmfunktionalität (danke an RR04)

Kizum

[autoit]

IniWrite (@TempDir & "\Pipette.txt"

[/autoit]

Habe mal die Dateiendung "ini" eingeführt.
Und eine Prüfung ob $farbe immer noch die selbe Farbe wie im vorherigen Schleifendurchgang ist, dann kann man sich den Rest der Schleife sparen.
Und noch ein kleiner Sleep(25), ..freut sich der Prozessor.

Spoiler anzeigen

[autoit]

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

[/autoit] [autoit][/autoit] [autoit]

Global $farbebackup
Global $farbe
Global $ini = @ScriptDir & "\Pipette.ini"

[/autoit] [autoit][/autoit] [autoit]

$farbehtml = "#000000"
$R = 0
$G = 0
$B = 0
$on = False
GUICreate("Pipette", 615, 219)
GUICtrlCreateGroup("", 8, 8, 161, 201)
$vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
GUICtrlSetBkColor(-1, 0x0)
$start = GUICtrlCreateButton("Pipette aufnehmen", 16, 176, 147, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
$hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
$copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, $BS_ICON)
GUICtrlSetImage(-1, "copy.ico", -1)
GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)
$RGB_R = GUICtrlCreateInput("0", 208, 104, 49, 21)
$RGB_G = GUICtrlCreateInput("0", 264, 104, 49, 21)
$RGB_B = GUICtrlCreateInput("0", 320, 104, 49, 21)
$copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, $BS_ICON)
GUICtrlSetImage(-1, "copy.ico", -1)
GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
$Proz_R = GUICtrlCreateInput("0", 208, 152, 49, 21)
$Proz_G = GUICtrlCreateInput("0", 264, 152, 49, 21)
$Proz_B = GUICtrlCreateInput("0", 320, 152, 49, 21)
$copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, $BS_ICON)
GUICtrlSetImage(-1, "copy.ico", -1)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
$verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
FileDelete ($ini)
Exit
Case $copy_hex
ClipPut ($farbehtml)
Case $copy_rbg
ClipPut (Round ($R/255*100,1) & ", " & Round ($B/255*100,1) & ", " & Round ($G/255*100,1))
Case $start
HotKeySet ("{Enter}","_Mark")
GUICtrlSetState ($start,$GUI_DISABLE)
GUICtrlSetData ($start,"Zum Ablegen Enter drücken")
$on = True
Case $verlauf
GUICtrlSetData ($hex_input,IniRead ($ini,GUICtrlRead ($verlauf),"HexHTML","Error"))
GUICtrlSetBkColor ($vorschau,IniRead ($ini,GUICtrlRead ($verlauf),"HexVorschau","Error"))
GUICtrlSetData ($RGB_R, IniRead ($ini,GUICtrlRead ($verlauf),"R","Error"))
GUICtrlSetData ($RGB_G, IniRead ($ini,GUICtrlRead ($verlauf),"G","Error"))
GUICtrlSetData ($RGB_B, IniRead ($ini,GUICtrlRead ($verlauf),"B","Error"))
GUICtrlSetData ($Proz_R,Round (IniRead ($ini,GUICtrlRead ($verlauf),"R","Error")/255*100,1))
GUICtrlSetData ($Proz_G,Round (IniRead ($ini,GUICtrlRead ($verlauf),"G","Error")/255*100,1))
GUICtrlSetData ($Proz_B,Round (IniRead ($ini,GUICtrlRead ($verlauf),"B","Error")/255*100,1))

[/autoit] [autoit][/autoit] [autoit]

EndSwitch

[/autoit] [autoit][/autoit] [autoit]

If $on = True Then
$farbe = PixelGetColor (MouseGetPos (0),MouseGetPos (1))

[/autoit] [autoit][/autoit] [autoit]

if $farbebackup <> $farbe Then

[/autoit] [autoit][/autoit] [autoit]

$farbehex = Hex ($farbe)
$farbehex = StringTrimLeft ($farbehex,2)
$farbehtml = "#" & $farbehex
$farbedarstellung = "0x" & $farbehex
GUICtrlSetBkColor($vorschau, $farbedarstellung)
$HR = StringMid($farbehex, 1, 2)
$HG = StringMid($farbehex, 3, 2)
$HB = StringMid($farbehex, 5, 2)
$R = Dec($HR)
$G = Dec($HG)
$B = Dec($HB)
GUICtrlSetData ($hex_input,$farbehtml)
GUICtrlSetData ($RGB_R, $R)
GUICtrlSetData ($RGB_G, $G)
GUICtrlSetData ($RGB_B, $B)
GUICtrlSetData ($Proz_R,Round ($R/255*100,1))
GUICtrlSetData ($Proz_G,Round ($G/255*100,1))
GUICtrlSetData ($Proz_B,Round ($B/255*100,1))

[/autoit] [autoit][/autoit] [autoit]

EndIf
EndIf

[/autoit] [autoit][/autoit] [autoit]

$farbebackup = $farbe
Sleep(25)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _Mark ()
$on = False
HotKeySet ("{Enter}")
GUICtrlSetState ($start,$GUI_ENABLE)
GUICtrlSetData ($start,"Pipette aufnehmen")
GUICtrlSetData ($verlauf, $R & " " & $G & " " & $B)
IniWrite ($ini,$R & " " & $G & " " & $B,"HexHTML",$farbehtml)
IniWrite ($ini,$R & " " & $G & " " & $B,"HexVorschau",$farbedarstellung)
IniWrite ($ini,$R & " " & $G & " " & $B,"R",$R)
IniWrite ($ini,$R & " " & $G & " " & $B,"G",$G)
IniWrite ($ini,$R & " " & $G & " " & $B,"B",$B)
EndFunc

[/autoit] [autoit][/autoit] [autoit]

Func _binaer ()
$Icon = "0x000001000100101010000100040028010000160000002800000010000000200000000100040000000000000000000000000000000000000000000000000080808000FFFFFF0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000002222200000000222222220111111002222222011111101022200001111110000220110111111111022011011000111102201101111111110220110110000011022011011111111102201101100000110220110111111111022011011111111102201100000000000220111111111022222011111111102222200000000000222F8070000F8030000F8010000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0070000C0070000C0070000"
FileOpen("copy.ico", 18)
FileWrite(FileOpen("copy.ico", 18), Binary($Icon))
FileClose("copy.ico")
EndFunc

[/autoit]

Cheater Dieter

Danke Kizum, ich hab mir jetzt mal deinen Code angeschaut und 2 Sachen übernommen: Den Sleep und die Prüfung, ob sich die Farbe verändert hat.
Ob die Datei jetzt Pipette.txt oder Pipette.ini heißt, ist wohl grad egal (theoretisch sind TXTs ja sogar besser, denn INIs haben doch eine Größenbeschränkung oder irre ich mich?).

===> Version 1.1

**Xorianator**

@Cheater Deater - Haben sie ?
Wahrscheinlich hat die Ini-Read Funktion das, aber mir wäre das neu; somit müsste jede Datei auf deinem System eine Beschränkung auf 4096 KB haben ...
Aber es ist doch egal, ob die Datei WAYNE.Weihnachten, Farbe.txt oder farbe.schlagmichtot heißt ...
Der Dateiname ist ja letztendlich nur eine Erkennungsmarke, wie ein Hund sie hat -> An der Erkennungsmarke erkennt man den Besitzer. Stellen wir uns vor die Erkennungsmarke ist deine Datei und der Besitzer das Programm das sie ausführt
Etwas blöd aber so in etwa

Saguhilla

Kizum:
Ich finde dein Befehl äußerst interessant
______________________________________
IniWrite (@TempDir & "\Pipette.txt"
______________________________________
Wenn schon ,,IniWrite(@TempDir & "\Pipette.txt")
Mit einer Schließklammer :-O
mfg SAGUHILLA

RR04

Hi,
gute Arbeit, sehr schöner Stil.

Tipps:
Keine Includes nötig.
Den 14 mal "@TempDir & "\Pipette.txt"" eine Variable spendieren "Global $PipetteTXT = @TempDir & "\Pipette.txt"".
Das Icon in das Script einbauen.

Spoiler anzeigen

[autoit]

#region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=Pipette.exe
#AutoIt3Wrapper_Res_Icon_Add=copy.ico ;i icon wird in die EXE eingebaut !erst beim kompilieren!
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 ;i mehr Auskunft u. Sicherheit fürs Script
#AutoIt3Wrapper_Run_Tidy=y
#AutoIt3Wrapper_Run_Obfuscator=y
#Obfuscator_Parameters=/striponly
#endregion ;**** Directives created by AutoIt3Wrapper_GUI ****

[/autoit] [autoit][/autoit] [autoit]

$farbehtml = "#000000"
$R = 0
$G = 0
$B = 0
$on = False

[/autoit] [autoit][/autoit] [autoit]

Global $PipetteTXT = @TempDir & "\Pipette.txt" ;i eine Globale Var für alle 14 Pfade !
Global $farbebackup, $title = "Pipette"

[/autoit] [autoit][/autoit] [autoit]

GUICreate($title, 615, 219)
GUICtrlCreateGroup("", 8, 8, 161, 201)
$vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
GUICtrlSetBkColor(-1, 0x0)
$start = GUICtrlCreateButton($title, 16, 176, 147, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
$hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
$copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, 0x0040)
GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)
$RGB_R = GUICtrlCreateInput("0", 208, 104, 49, 21)
$RGB_G = GUICtrlCreateInput("0", 264, 104, 49, 21)
$RGB_B = GUICtrlCreateInput("0", 320, 104, 49, 21)
$copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, 0x0040)
GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
$Proz_R = GUICtrlCreateInput("0", 208, 152, 49, 21)
$Proz_G = GUICtrlCreateInput("0", 264, 152, 49, 21)
$Proz_B = GUICtrlCreateInput("0", 320, 152, 49, 21)
$copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, 0x0040)
GUICtrlSetImage(-1, @ScriptFullPath, -5) ;i Aufruf des eingebauten Icons !
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
$verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
FileDelete($PipetteTXT)
Exit
Case $copy_hex
ClipPut($farbehtml)
Case $copy_rbg
ClipPut(Round($R / 255 * 100, 1) & ", " & Round($B / 255 * 100, 1) & ", " & Round($G / 255 * 100, 1))
Case $start
HotKeySet("{Enter}", "_Mark")
GUICtrlSetState($start, 128)
GUICtrlSetData($start, "Enter drücken zum ablegen !")
$on = True
Case $verlauf
GUICtrlSetData($hex_input, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexHTML", "Error"))
GUICtrlSetBkColor($vorschau, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexVorschau", "Error"))
GUICtrlSetData($RGB_R, IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error"))
GUICtrlSetData($RGB_G, IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error"))
GUICtrlSetData($RGB_B, IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error"))
GUICtrlSetData($Proz_R, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz_G, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz_B, Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error") / 255 * 100, 1))
EndSwitch

[/autoit] [autoit][/autoit] [autoit]

If $on = True Then
$farbe = PixelGetColor(MouseGetPos(0), MouseGetPos(1))
If $farbebackup <> $farbe Then
$farbehex = Hex($farbe)
$farbehex = StringTrimLeft($farbehex, 2)
$farbehtml = "#" & $farbehex
$farbedarstellung = "0x" & $farbehex
GUICtrlSetBkColor($vorschau, $farbedarstellung)
$HR = StringMid($farbehex, 1, 2)
$HG = StringMid($farbehex, 3, 2)
$HB = StringMid($farbehex, 5, 2)
$R = Dec($HR)
$G = Dec($HG)
$B = Dec($HB)
GUICtrlSetData($hex_input, $farbehtml)
GUICtrlSetData($RGB_R, $R)
GUICtrlSetData($RGB_G, $G)
GUICtrlSetData($RGB_B, $B)
GUICtrlSetData($Proz_R, Round($R / 255 * 100, 1))
GUICtrlSetData($Proz_G, Round($G / 255 * 100, 1))
GUICtrlSetData($Proz_B, Round($B / 255 * 100, 1))
EndIf
$farbebackup = $farbe
EndIf
Sleep(25)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _Mark()
$on = False
HotKeySet("{Enter}")
GUICtrlSetState($start, 64)
GUICtrlSetData($start, $title)
GUICtrlSetData($verlauf, $R & " " & $G & " " & $B)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexHTML", $farbehtml)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexVorschau", $farbedarstellung)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "R", $R)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "G", $G)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "B", $B)
EndFunc ;==>_Mark

[/autoit] [autoit][/autoit] [autoit]

; Ende

[/autoit]

Schöne Feiertage !

Cheater Dieter

Zitat von RR04

Keine Includes nötig.

Danke für den Tipp, das kannte ich nicht.

Zitat von RR04

Das Icon in das Script einbauen.

Oder es einfach binär einbinden.

Zitat von RR04

Den 14 mal "@TempDir & "\Pipette.txt"" eine Variable spendieren "Global $PipetteTXT = @TempDir & "\Pipette.txt"".

Gut, habe ich gemacht.

==> Das und ein Bugfix in Version 1.2 eingebaut.

RR04

Hi, mit

[autoit]

GUISetCursor(3, 1, $Cursor)

[/autoit]

wird der Cursor zum Kreuz, natürlich erst nach dem drücken von Pipette !

James · AutoIt Version (Prod): 3.3.14.2

Nettes Skript, erinnert mich an frühere Versionen von Paint...

Spoiler anzeigen

[autoit]

$Show = False
HotKeySet('{F1}', '_Toggle')
HotKeySet('{ESC}', '_Exit')
Do
If $Show Then
ToolTip(Hex(PixelGetColor(MouseGetPos(0), MouseGetPos(1))))
EndIf
Until False
Func _Toggle()
$Show = Not $Show
If Not $Show Then
ToolTip('')
EndIf
EndFunc
Func _Exit()
Exit
EndFunc

[/autoit]

RR04

Pipette

[autoit]

#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

[/autoit] [autoit][/autoit] [autoit]

#cs
1. Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
2. 2x3 = 6 Inputs erstellt.
3. Das Bild "copy.jpg" gelöscht.
#ce

[/autoit] [autoit][/autoit] [autoit]

Global $icon = ""
$icon &= "0x000001000100101010000100040028010000160000002800000010000000200000000100040000000000000000000000000000000000000000000000000080808000FFFFFF0000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000002222200000000222222220111111002222222011111101022200001111110000220110111111111022011011000111102201101111111110220110110000011022011011111111102201101100000110220110111111111022011011111111102201100000000000220111111111022222011111111102222200000000000222F8070000F8030000F8010000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0000000C0070000C0070000C0070000"
Global $copyJPG = @TempDir & "\" & "copy.jpg" ;i Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
$handle = FileOpen($copyJPG, 18)
FileWrite($handle, Binary($icon))
FileClose($handle)
Global $PipetteTXT = @TempDir & "\Pipette.txt"
Global $farbehtml = "#000000"
$R = 0
$G = 0
$B = 0
$on = False
Global $farbebackup
GUICreate("Pipette", 615, 219)
GUICtrlCreateGroup("", 8, 8, 161, 201)
$vorschau = GUICtrlCreateLabel("", 13, 20, 148, 148)
GUICtrlSetBkColor(-1, 0x0)
$start = GUICtrlCreateButton("Pipette aufnehmen", 16, 176, 147, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Farbmodelle", 176, 16, 233, 193)
GUICtrlCreateLabel("Hexadezimal (HEX):", 192, 40, 98, 17)
$hex_input = GUICtrlCreateInput("#000000", 208, 57, 161, 21)
$copy_hex = GUICtrlCreateButton("", 376, 56, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateLabel("RGB-Farbraum (RGB):", 192, 88, 109, 17)

[/autoit] [autoit][/autoit] [autoit]

#region ### Start 2x3 = 6 Inputs erstellen ###
Global $RGB[3], $Proz[3] ;i 2x3 = 6 Inputs erstellen
For $i = 0 To 2
$RGB[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 104, 49, 21)
$Proz[$i] = GUICtrlCreateInput("0", 208 + $i * 56, 152, 49, 21)
Next
#endregion ### Start 2x3 = 6 Inputs erstellen ###

[/autoit] [autoit][/autoit] [autoit]

$copy_rbg = GUICtrlCreateButton("", 376, 104, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateLabel("Prozentualer RGB-Farbraum (RBG %):", 192, 136, 182, 17)
$copy_proz = GUICtrlCreateButton("", 376, 152, 21, 21, 0x0040)
GUICtrlSetImage(-1, $copyJPG, -1)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Verlauf", 416, 16, 153, 193)
$verlauf = GUICtrlCreateList("", 424, 32, 137, 162)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUISetState(@SW_SHOW)

[/autoit] [autoit][/autoit] [autoit]

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case -3
FileDelete($PipetteTXT)
FileDelete($copyJPG) ;i Das Bild auch löschen!
Exit
Case $copy_hex
ClipPut($farbehtml)
Case $copy_rbg
ClipPut($R & ", " & $B & ", " & $G)
Case $copy_proz
ClipPut(Round($R / 255 * 100, 1) & ", " & Round($B / 255 * 100, 1) & ", " & Round($G / 255 * 100, 1))
Case $start
HotKeySet("{Enter}", "_Mark")
GUICtrlSetState($start, 128)
GUICtrlSetData($start, "Zum Ablegen Enter drücken")
$on = True
Case $verlauf
GUICtrlSetData($hex_input, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexHTML", "Error"))
GUICtrlSetBkColor($vorschau, IniRead($PipetteTXT, GUICtrlRead($verlauf), "HexVorschau", "Error"))
GUICtrlSetData($RGB[0], IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error"))
GUICtrlSetData($RGB[1], IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error"))
GUICtrlSetData($RGB[2], IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error"))
GUICtrlSetData($Proz[0], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "R", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz[1], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "G", "Error") / 255 * 100, 1))
GUICtrlSetData($Proz[2], Round(IniRead($PipetteTXT, GUICtrlRead($verlauf), "B", "Error") / 255 * 100, 1))
EndSwitch

[/autoit] [autoit][/autoit] [autoit]

If $on = True Then
$farbe = PixelGetColor(MouseGetPos(0), MouseGetPos(1))
If $farbebackup <> $farbe Then
$farbehex = Hex($farbe)
$farbehex = StringTrimLeft($farbehex, 2)
$farbehtml = "#" & $farbehex
$farbedarstellung = "0x" & $farbehex
GUICtrlSetBkColor($vorschau, $farbedarstellung)
$HR = StringMid($farbehex, 1, 2)
$HG = StringMid($farbehex, 3, 2)
$HB = StringMid($farbehex, 5, 2)
$R = Dec($HR)
$G = Dec($HG)
$B = Dec($HB)
GUICtrlSetData($hex_input, $farbehtml)
GUICtrlSetData($RGB[0], $R)
GUICtrlSetData($RGB[1], $G)
GUICtrlSetData($RGB[2], $B)
GUICtrlSetData($Proz[0], Round($R / 255 * 100, 1))
GUICtrlSetData($Proz[1], Round($G / 255 * 100, 1))
GUICtrlSetData($Proz[2], Round($B / 255 * 100, 1))
EndIf
$farbebackup = $farbe
EndIf
Sleep(25)
WEnd

[/autoit] [autoit][/autoit] [autoit]

Func _Mark()
$on = False
HotKeySet("{Enter}")
GUICtrlSetState($start, 64)
GUICtrlSetData($start, "Pipette aufnehmen")
GUICtrlSetData($verlauf, $R & " " & $G & " " & $B)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexHTML", $farbehtml)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "HexVorschau", $farbedarstellung)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "R", $R)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "G", $G)
IniWrite($PipetteTXT, $R & " " & $G & " " & $B, "B", $B)
EndFunc ;==>_Mark

[/autoit]

**Xorianator**

RR04 wieso lädst du eine "v1.3" hoch wenn du nicht ersteller bist ?

RR04

@Mattthias,
ist nur zur besseren Kenntlichkeit, Pipette ist natürlich nicht von mir!

**Xorianator**

Hmm ...
Was ist an deinem Script anders als an CheaterDieters (grad zu faul zu testen :D)

RR04

@Mattthias,

[autoit]

#cs
1. Eine Var für 4 mal "@TempDir & "\" & "copy.jpg"".
2. 2x3 = 6 Inputs erstellt.
3. Das Bild "copy.jpg" gelöscht.
#ce

[/autoit]

**Xorianator**

Unglaublich XD

RR04

@Mattthias,
habe es entfernt !

Cheater Dieter

Also ich habe jetzt deine Vorschläge (mit kleinen Änderrungen) übernommen und habe nun eine Version 1.2.1 hochgeladen, da die Änderrungen ja nur eine Verschönerrung sind und die Funktionalität des Programms nicht verändern.