Hallo Leute.
Folgendes Problem:
ich möchte den aktuellen Bildschirmausdruck in einer GUI anzeigen lassen, als hätte man die "Druck"-Taste gedrückt und das Bild in Paint eingefügt.
Mit dem Unterschied, dass das Bild um die Hälfte verkleinert werden sollte.
Geht sowas überhaupt?
Gruß. 
So in der Art?
[autoit]
#include <ScreenCapture.au3>
GUICreate('',@DesktopWidth/2,@DesktopHeight/2)
$screen=_ScreenCapture_Capture()
_ScreenCapture_SaveImage(@tempdir&'\screen.jpg',$screen)
GUICtrlCreatePic(@tempdir&'\screen.jpg',0,0,@DesktopWidth/2,@DesktopHeight/2)
GUISetState()
While 1
$msg=GUIGetMsg()
if $msg=-3 then Exit
WEnd
Indem man die Dateiendung ändert. In meiner HIlfe steht:
[...] the valid extensions are BMP, GIF, JPEG, PNG and TIF.
In meiner Hilfe steht das gleiche. Unfassbar! 
Das Problem ist nur, dass wenn ich die Dateiendung auf .PNG ändere, nichts angezeigt wird.
Fehlt mir vielleicht irgendein Plugin?
Gruß
Wie wäre es mal die Hilfe auch Richtig zu Lesen? , PNG's können nicht mit GUICtrlCreatePic angezeigt werden sondern mit GDI+ steht alles i der Hilfe
Zitat : "PNG can be used with GDI+. See example 3."
und dazu dass Example
;----- example 3 PNG work araund by Zedna
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#Include <WinAPI.au3>
Global $hGUI, $hImage, $hGraphic, $hImage1
[/autoit] [autoit][/autoit] [autoit]; Create GUI
$hGUI = GUICreate("Show PNG", 250, 250)
; Load PNG image
_GDIPlus_StartUp()
$hImage = _GDIPlus_ImageLoadFromFile("..\GUI\Torus.png")
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
GUIRegisterMsg($WM_PAINT, "MY_WM_PAINT")
GUISetState()
; Loop until user exits
do
until GUIGetMsg() = $GUI_EVENT_CLOSE
; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_ShutDown()
; Draw PNG image
Func MY_WM_PAINT($hWnd, $Msg, $wParam, $lParam)
_WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_UPDATENOW)
_GDIPlus_GraphicsDrawImage($hGraphic, $hImage, 0, 0)
_WinAPI_RedrawWindow($hGUI, 0, 0, $RDW_VALIDATE)
Return $GUI_RUNDEFMSG
EndFunc
Wozu als Datei speichern?
Es soll doch nur in der GUI angezeigt werden.
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
_Main()
[/autoit] [autoit][/autoit] [autoit]Func _Main()
Local $hGUI, $hBMP, $hBitmap, $hGraphic
$hBMP = _ScreenCapture_Capture("", 0, 0, @DesktopWidth, @DesktopHeight)
; Create GUI
$hGUI = GUICreate("Screenshot", @DesktopWidth / 2, @DesktopHeight / 2)
GUISetState()
; Initialize GDI+ library
_GDIPlus_Startup()
; Draw bitmap to GUI
$hBitmap = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
_GDIPlus_GraphicsDrawImageRect($hGraphic, $hBitmap, 0, 0, @DesktopWidth / 2, @DesktopHeight / 2)
; Clean up resources
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_BitmapDispose($hBitmap)
_WinAPI_DeleteObject($hBMP)
; Shut down GDI+ library
_GDIPlus_Shutdown()
; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc ;==>_Main
