Icons glätten?

#include <GUIConstantsEx.au3>

GUICreate("Meine GUI Icons", 700, 300)

$icon = "C:\Windows\system32\mobsync.exe"

GUICtrlCreateIcon($icon, 1, 20, 20, 16, 16)
GUICtrlCreateIcon($icon, 1, 100, 20, 32, 32)
GUICtrlCreateIcon($icon, 1, 200, 20, 48, 48)
GUICtrlCreateIcon($icon, 1, 300, 20, 256, 256)
GUISetState()

While 1
Local $msg = GUIGetMsg()

If $msg = $GUI_EVENT_CLOSE Then ExitLoop
WEnd

#include <WindowsConstants.au3>
#include <GDIPlus.au3>
Opt("MustDeclareVars", 1)

_GDIPlus_Startup()
Global Const $STM_SETIMAGE = 0x0172

Global $hGUI, $Msg, $Button, $Icon, $hIcon, $iPic, $hPic, $hGraphics, $Index = 0, $iBGColor = 0xF0F0F0
Global $hIcon300x300 = _WinAPI_ShellExtractIcon("C:\Windows\system32\mobsync.exe", $Index, 300, 300)
Global $hHBitmap256x256 = _WinAPI_GetFileIcon("C:\Windows\system32\mobsync.exe", $Index, 256, 256, $iBGColor)
Global $hBitmapIcon256x256 = _GDIPlus_BitmapCreateFromHBITMAP($hHBitmap256x256)
Global $hBitmapIcon300x300 = _GDIPlus_BitmapCreateFromScan0(300, 300)
Global $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmapIcon300x300)
_GDIPlus_GraphicsSetInterpolationMode($hContext, 7)
_GDIPlus_GraphicsDrawImageRect($hContext, $hBitmapIcon256x256, 0, 0, 300, 300)
_GDIPlus_GraphicsDispose($hContext)

$hGUI = GUICreate("MyGUI", 610, 300)
GUISetBkColor($iBGColor)
$Icon = GUICtrlCreateIcon("", 0, 0, 0, 300, 300)
$hIcon = GUICtrlGetHandle(-1)
$iPic = GUICtrlCreatePic("", 310,0, 300, 300)
$hPic = GUICtrlGetHandle(-1)
GUISetState()
$hGraphics = _GDIPlus_GraphicsCreateFromHWND($hPic)
_GDIPlus_GraphicsDrawImageRect($hGraphics, $hBitmapIcon300x300, 0, 0, 300, 300)
_WinAPI_DestroyIcon(_SendMessage($hIcon, $STM_SETIMAGE, 1, $hIcon300x300))

While 1
$Msg = GUIGetMsg()
Switch $Msg
Case -3
_GDIPlus_BitmapDispose($hBitmapIcon256x256)
_GDIPlus_BitmapDispose($hBitmapIcon300x300)
_WinAPI_DestroyIcon($hIcon300x300)
_WinAPI_DeleteObject($hHBitmap256x256)
_GDIPlus_GraphicsDispose($hGraphics)
_GDIPlus_Shutdown()
ExitLoop
EndSwitch
WEnd

Func _WinAPI_GetFileIcon($sFile, $iIndex = 0, $iW = 18, $iH = 18, $iColor = -1)
Local $aRet, $hIcon, $hHBitmap
Local $hDC, $hBackDC, $hBackSv

$aRet = DllCall("shell32.dll", "int", "SHExtractIconsW", "wstr", $sFile, "int", $iIndex, "int", $iW, "int", $iH, "ptr*", 0, "ptr*", 0, "int", 1, "int", 0)
If @error Then Return SetError(6, @extended, 0)
$hIcon = $aRet[5]

$hDC = _WinAPI_GetDC(0)
$hBackDC = _WinAPI_CreateCompatibleDC($hDC)
If $iColor = -1 Then $iColor = _WinAPI_GetSysColor($COLOR_MENU)
$hHBitmap = _WinAPI_CreateSolidBitmap(0, $iColor, $iW, $iH)
$hBackSv = _WinAPI_SelectObject($hBackDC, $hHBitmap)
_WinAPI_DrawIconEx($hBackDC, 0, 0, $hIcon, $iW, $iH)
_WinAPI_DestroyIcon($hIcon)

_WinAPI_SelectObject($hBackDC, $hBackSv)
_WinAPI_ReleaseDC(0, $hDC)
_WinAPI_DeleteDC($hBackDC)
Return $hHBitmap
EndFunc ;==>_GUICtrlMenu_CreateBitmap

; #FUNCTION# ====================================================================================================================
; Name...........: _WinAPI_ShellExtractIcon
; Description....: Extracts the icon with the specified dimension from the specified file.
; Syntax.........: _WinAPI_ShellExtractIcon ( $sIcon, $iIndex, $iWidth, $iHeight )
; Parameters.....: $sIcon - Path and name of the file from which the icon are to be extracted.
; $iIndex - The zero-based index of the icon to extract. If this value is a negative number, the function extracts
; the icon whose resource identifier is equal to the absolute value of $iIndex.
; $iWidth - Horizontal icon size wanted.
; $iHeight - Vertical icon size wanted.
; Return values..: Success - Handle to the extracted icon.
; Failure - 0 and sets the @error flag to non-zero.
; Author.........: Yashied
; Modified.......:
; Remarks........: If the icon with the specified dimension is not found in the file, it will choose the nearest appropriate icon
; and change to the specified dimension.
;
; When you are finished using the icon, destroy it using the _WinAPI_DestroyIcon() function.
; Related........:
; Link...........: @@MsdnLink@@ SHExtractIcons
; Example........: Yes
; ===============================================================================================================================
Func _WinAPI_ShellExtractIcon($sIcon, $iIndex, $iWidth, $iHeight)
Local $Ret = DllCall("shell32.dll", "int", "SHExtractIconsW", "wstr", $sIcon, "int", $iIndex, "int", $iWidth, "int", $iHeight, "ptr*", 0, "ptr*", 0, "int", 1, "int", 0)
If (@error) Or (Not $Ret[0]) Or (Not $Ret[5]) Then
Return SetError(1, 0, 0)
EndIf
Return $Ret[5]
EndFunc ;==>_WinAPI_ShellExtractIcon

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_BitmapCreateFromScan0
; Description ...: Creates a Bitmap object based on an array of bytes along with size and format information
; Syntax.........: _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight[, $iStride = 0[, $iPixelFormat = 0x0026200A[, $pScan0 = 0]]])
; Parameters ....: $iWidth - The bitmap width, in pixels
; $iHeight - The bitmap height, in pixels
; $iStride - Integer that specifies the byte offset between the beginning of one scan line and the next. This
; +is usually (but not necessarily) the number of bytes in the pixel format (for example, 2 for 16 bits per pixel)
; +multiplied by the width of the bitmap. The value passed to this parameter must be a multiple of four
; $iPixelFormat - Specifies the format of the pixel data. Can be one of the following:
; |$GDIP_PXF01INDEXED - 1 bpp, indexed
; |$GDIP_PXF04INDEXED - 4 bpp, indexed
; |$GDIP_PXF08INDEXED - 8 bpp, indexed
; |$GDIP_PXF16GRAYSCALE - 16 bpp, grayscale
; |$GDIP_PXF16RGB555 - 16 bpp; 5 bits for each RGB
; |$GDIP_PXF16RGB565 - 16 bpp; 5 bits red, 6 bits green, and 5 bits blue
; |$GDIP_PXF16ARGB1555 - 16 bpp; 1 bit for alpha and 5 bits for each RGB component
; |$GDIP_PXF24RGB - 24 bpp; 8 bits for each RGB
; |$GDIP_PXF32RGB - 32 bpp; 8 bits for each RGB. No alpha.
; |$GDIP_PXF32ARGB - 32 bpp; 8 bits for each RGB and alpha
; |$GDIP_PXF32PARGB - 32 bpp; 8 bits for each RGB and alpha, pre-mulitiplied
; $pScan0 - Pointer to an array of bytes that contains the pixel data. The caller is responsible for
; +allocating and freeing the block of memory pointed to by this parameter.
; Return values .: Success - Returns a handle to a new Bitmap object
; Failure - 0 and either:
; |@error and @extended are set if DllCall failed
; |$GDIP_STATUS contains a non zero value specifying the error code
; Remarks .......: After you are done with the object, call _GDIPlus_ImageDispose to release the object resources
; Related .......: _GDIPlus_ImageDispose
; Link ..........; @@MsdnLink@@ GdipCreateBitmapFromScan0
; Example .......; Yes
; ===============================================================================================================================
Func _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iStride = 0, $iPixelFormat = $GDIP_PXF32RGB, $pScan0 = 0)
Local $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $iWidth, "int", $iHeight, "int", $iStride, "int", $iPixelFormat, "ptr", $pScan0, "int*", 0)
If @error Then Return SetError(@error, @extended, 0)
Return $aResult[6]
EndFunc ;==>_GDIPlus_BitmapCreateFromScan0

; #FUNCTION# ====================================================================================================================
; Name...........: _GDIPlus_GraphicsSetInterpolationMode
; Description ...: Sets the interpolation mode of a Graphics object
; Syntax.........: _GDIPlus_GraphicsSetInterpolationMode($hGraphics, $iInterpolationMode)
; Parameters ....: $hGraphics - Pointer to a Graphics object
; $iInterpolationMode - Interpolation mode:
; |0 - Default interpolation mode
; |1 - Low-quality mode
; |2 - High-quality mode
; |3 - Bilinear interpolation. No prefiltering is done
; |4 - Bicubic interpolation. No prefiltering is done
; |5 - Nearest-neighbor interpolation
; |6 - High-quality, bilinear interpolation. Prefiltering is performed to ensure high-quality shrinking
; |7 - High-quality, bicubic interpolation. Prefiltering is performed to ensure high-quality shrinking
; Return values .: Success - True
; Failure - False and either:
; |@error and @extended are set if DllCall failed
; |$GDIP_STATUS contains a non zero value specifying the error code
; Remarks .......: The interpolation mode determines the algorithm that is used when images are scaled or rotated
; Related .......: _GDIPlus_GraphicsGetInterpolationMode
; Link ..........; @@MsdnLink@@ GdipSetInterpolationMode
; Example .......; No
; ===============================================================================================================================
Func _GDIPlus_GraphicsSetInterpolationMode($hGraphics, $iInterpolationMode)
Local $aResult = DllCall($ghGDIPDll, "uint", "GdipSetInterpolationMode", "handle", $hGraphics, "int", $iInterpolationMode)
If @error Then Return SetError(@error, @extended, False)
Return $aResult[0] = 0
EndFunc ;==>_GDIPlus_GraphicsSetInterpolationMode