Commander

**GtaSpider**

Hallo Doppelass

Ok danke für die antwort ich hab das skript einfach ein wenig umgeschrieben, sollte so genauso gut gehen:

Spoiler anzeigen

C

;~ ###################################################
;~ # Funktion: Stellt Dateiinhalt als TreeView dar
;~ #
;~ # Autor: bernd670 & GtaSpider
;~ ##################################################
#include <File.au3>
#include <Array.au3>
#include <GUIConstants.au3>


;TreeView
Global Const $TVGN_NEXT				= 0x0001
Global Const $TVGN_CHILD			= 0x0004
Global Const $TVI_ROOT				= 0xFFFF0000
Global Const $TV_FIRST				= 0x1100
Global Const $TVM_GETCOUNT			= $TV_FIRST + 5
Global Const $TVM_GETNEXTITEM		= $TV_FIRST + 10
Global Const $TVM_SORTCHILDREN		= $TV_FIRST + 19


Global $Tree[1], $FileTable[1][2]


$datei = "MAX-01(192.168.0.2).txt"
SplashTextOn("dada","initalizing",130,20,-1,-1,1)
;~ Opt("GUIOnEventMode", 1)  ; Wechsle in den OnEvent Modus
Opt("TrayIconDebug",1)


$mainwindow = GUICreate("BG Commander - "&$datei, 359, 439, 193, 126)
$TreeView = GUICtrlCreateTreeView(10, 10, 261, 397, BitOR($WS_BORDER, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS))
GUICtrlSetImage(-1, "shell32.dll", 4, 2)
$Search = GUICtrlCreateInput("", 60, 410, 121, 20)
GUICtrlCreateLabel("Suche:", 20, 410, 38, 15)
$SearchBut = GUICtrlCreateButton("Suchen", 190, 410, 82, 25, 0)
$start = GUICtrlCreateButton("Datei &Starten", 280, 10, 75, 25, 0)
$exit = GUICtrlCreateButton("E&xit", 280, 410, 75, 25, 0)
GUICtrlCreateEdit("", 280, 40, 75, 359,  BitOR($ES_AUTOVSCROLL,$ES_AUTOHSCROLL,$ES_READONLY,$ES_WANTRETURN))
GUICtrlSetData(-1, "Copyright by"&@CRLF&"Bernd 670"&@CRLF&"& GtaSpider"&@CRLF&""&@CRLF&"Was macht"&@CRLF&"dieser"&@CRLF&"Commander?"&@CRLF&""&@CRLF&"Er listet von"&@CRLF&"einer Datei,"&@CRLF&"Dateien,"&@CRLF&"Ordner"&@CRLF&"und"&@CRLF&"Laufwerke"&@CRLF&"auf die er"&@CRLF&"dann in der"&@CRLF&"Box"&@CRLF&"Kompfortabel"&@CRLF&"anzeigt"&@CRLF&"werden"&@CRLF&""&@CRLF&"Was mach"&@CRLF&"ich bei Problemen?"&@CRLF&""&@CRLF&"Entweder eine"&@CRLF&"Im Forum"&@CRLF&"fragen!")
MakeFileTree($datei)


SplashOff()
;~ GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSEClicked")


GUISetState()


While 1
	$msg = GUIGetMsg()
	Select
		Case $msg = $GUI_EVENT_CLOSE Or $msg = $exit
			Exit
		Case $msg = $start
			SelectFile(GUICtrlRead($TreeView))
		Case $msg = $SearchBut
			$SearchFile = GUICtrlRead($Search)
			Search($SearchFile)
	EndSelect
WEnd


Func Search($Search)
	;Hier kommt dann die Suchfunktion rein!
	MsgBox(0,"",$Search)
EndFunc
Func SelectFile($lastclick)
	;Beachte: an diesem Punkt wäre @GUI_CTRLID gleich $Tree[$Ebene]
	For $index = 0 To UBound($FileTable, 1) - 1
		If $FileTable[$index][0] = $lastclick Then
			RunWait(@ComSpec & ' /c start '&$FileTable[$index][1], '', @SW_HIDE)
			ExitLoop
		EndIf
	Next
EndFunc   ;==>SelectFile




Func MakeFileTree($strFileName)

	Local $arFile, $arTemp, $iFile, $iInsert, $iPos, $iPos2

	If Not FileExists($strFileName) Then
		MsgBox(16, "Fehler", "Datei " & $strFileName & " wurde nicht gefunden!")
		Exit
	EndIf
	_FileReadToArray($strFileName, $arFile)
;~ 	_ArraySort($arFile,0,0,1)
	; Leerzeilen entfernen
	    $iPos = 1
	    While 1
	        If Not stringlen(StringStripWS($arFile[1],15)) Then 
		   _ArrayDelete($arFile,1)
		   $arFile[0] = $arFile[0] - 1
	        Else
		   ExitLoop
	        EndIf
	        $iPos = $iPos + 1
	    Wend
	$Ebene = 0
	$arTemp = StringSplit(StringStripCR($arFile[1]), "\")
	For $iInsert = 1 To $arTemp[0]

		If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

		Select
			Case $iInsert = 1
				; Laufwerksbezeichnung
				ControlSetText("dada","","Static1", $arTemp[$iInsert])
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $TreeView)
				$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
				$icon2 = "-1"
				$sis = StringInStr($icon, ",", 0, -1)
				If Not @error Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
				GUICtrlSetImage(-1, $icon, $icon2)
				$Ebene = $Ebene + 1

			Case $iInsert = $arTemp[0]
				; Dateiname
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $Tree[$Ebene - 1])
				$ext = StringTrimLeft($arTemp[$iInsert], StringInStr($arTemp[$iInsert], ".", 0, -1) - 1)
				$icon = RegRead("HKCR\" & $ext, "")
				$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
				$icon2 = "-1"
				$sis = StringInStr($icon, ",", 0, -1)
				If Not @error Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
;~ 			 MsgBox(0,$icon2,$icon)
				GUICtrlSetImage($Tree[$Ebene], $icon, $icon2)
				$FileTable[UBound($FileTable, 1) - 1][0] = $Tree[$Ebene]
				$FileTable[UBound($FileTable, 1) - 1][1] = $arFile[1]
;~ 				GUICtrlSetOnEvent($Tree[$Ebene], "SelectFile")
				ReDim $FileTable[UBound($FileTable, 1) + 1][2]

			Case Else
				; Verzeichnisname
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $Tree[$Ebene - 1])
				$Ebene = $Ebene + 1

		EndSelect
	Next

	For $iFile = 2 To $arFile[0]
		$arTemp = StringSplit(StringStripCR($arFile[$iFile]), "\")
		$iPos = StringInStr($arFile[$iFile], "\", 0, -1)
		$strLeft = StringLeft($arFile[$iFile], $iPos)

		; Ebenenkorrektur
		$iPos2 = StringInStr($arFile[$iFile - 1], "\", 0, -1)
		$Ebene = $Ebene + (UBound(StringSplit($strLeft, "\"), 1) - UBound(StringSplit(StringLeft($arFile[$iFile - 1], $iPos2), "\"), 1))

		For $iSearch = 0 To $arTemp[0] - 1
			If StringLeft($arFile[$iFile - 1], StringLen($strLeft)) = $strLeft Then
				For $iInsert = $iSearch To 0 Step - 1

					If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

					Select
						Case $iInsert = 0
							; Dateiname
							If $Ebene = 0 Then $Ebene = 1
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
							$ext = StringTrimLeft($arTemp[$arTemp[0] - $iInsert], StringInStr($arTemp[$arTemp[0] - $iInsert], ".", 0, -1) - 1)
							$icon = RegRead("HKCR\" & $ext, "")
							$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
							$icon2 = "-1"
							$sis = StringInStr($icon, ",", 0, -1)
							If Not @error Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
;~ 			 MsgBox(0,$icon2,$icon)
							GUICtrlSetImage($Tree[$Ebene], $icon, $icon2)
							$FileTable[UBound($FileTable, 1) - 1][0] = $Tree[$Ebene]
							$FileTable[UBound($FileTable, 1) - 1][1] = $arFile[$iFile]
;~ 							GUICtrlSetOnEvent($Tree[$Ebene], "SelectFile")
							ReDim $FileTable[UBound($FileTable, 1) + 1][2]
						Case $iInsert = $arTemp[0] - 1
							; Laufwerksbezeichnung
							ControlSetText("dada","","Static1", $arTemp[$arTemp[0] - $iInsert])
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $TreeView)
							$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
							$icon2 = "-1"
							$sis = StringInStr($icon, ",", 0, -1)
							If Not @error Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
							GUICtrlSetImage(-1, $icon, $icon2)
							$Ebene = $Ebene + 1
						Case Else
							; Verzeichnisname
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
							$Ebene = $Ebene + 1

					EndSelect
				Next
				ExitLoop
			Else
				$Ebene = $Ebene - 1
			EndIf
			$iPos = StringInStr($strLeft, "\", 0, -2)
			$strLeft = StringLeft($strLeft, $iPos)
		Next
	Next
	_GUICtrlTreeViewSort ($TreeView)
EndFunc   ;==>MakeFileTree


;===============================================================================
;
; Description:			_GUICtrlTreeViewSort
; Parameter(s):		$i_treeview - controlID
; Requirement:			None
; Return Value(s):	None
; User CallTip:		_GUICtrlTreeViewSort($i_treeview) Sorts the items of a Tree-View control (required: <GuiTreeView.au3>)
; Author(s):			Gary Frost (custompcs at charter dot net)
; Note(s):			
;
;===============================================================================
Func _GUICtrlTreeViewSort($i_treeview)
	Local $h_item, $i, $hChild, $i_Recursive = 1
	Local $a_tree
	For $i = 0 To GUICtrlSendMsg($i_treeview, $TVM_GETCOUNT, 0, 0)
		If $i == 0 Then
			$h_item = GUICtrlSendMsg($i_treeview, $TVM_GETNEXTITEM, $TVGN_CHILD, $TVI_ROOT)

		Else
			$h_item = GUICtrlSendMsg($i_treeview, $TVM_GETNEXTITEM, $TVGN_NEXT, $h_item)
		EndIf
		If IsArray($a_tree) Then
			ReDim $a_tree[UBound($a_tree) + 1]
		Else
			Dim $a_tree[1]
		EndIf
		$a_tree[UBound($a_tree) - 1] = $h_item
	Next
	If IsArray($a_tree) Then
		For $i = 0 To UBound($a_tree) - 1
			GUICtrlSendMsg($i_treeview, $TVM_SORTCHILDREN, $i_Recursive, $a_tree[$i]) ; sort the items in root
			Do ; sort all the children
				$hChild = GUICtrlSendMsg($i_treeview, $TVM_GETNEXTITEM, $TVGN_CHILD, $h_item)
				If $hChild > 0 Then
					GUICtrlSendMsg($i_treeview, $TVM_SORTCHILDREN, $i_Recursive, $hChild)
				EndIf
				$h_item = $hChild
			Until $h_item <= 0
		Next
	EndIf
EndFunc   ;==>_GUICtrlTreeViewSort

Alles anzeigen

Mfg Spider

ytwinky

Hallo Moderator,
deine Anrede freut mich, dabei kann ich garnix dafür
Auf einmal war ich Doppel-As(oder kommt das immer mit dem 100. Post)..
MaxArray ist einfach nur der VariablenName für die ArrayObergrenze und bei
nullbasierten Indizes muß das eben -1 sein.
Gruß
ytwinky

**GtaSpider**

Hi!

Bin grad in der schule im Pc raum darf eigentlich garnet ins inet :-[

Doppelass kommt ab 100 post tripleass ab200 usw..

Achso! Danke für die info aber so wie ichs gemacht habs gehts ja auch

Mfg Spider

ytwinky

hi spider,
(ich sag extra nicht gtaspider, da du ja gar nicht im Intenet bist und nicht erkannt werden sollst )
Dank für die Info..
..wenn du Fenster 'bearbeiten' willst, schau in die Skripte
Gruß
ytwinky

**GtaSpider**

Hallo ytwinky (du bist doch nicht anonym oder?*g*)
Bitte..
Danke für die andere Info..

Jetzt aber nochmal zum thema ;):
Ich fände es gut wenn man die Dateien einmal nach Name (Also normales TreeViewSort) aber auch nach Erweiterung sortieren könnte!
Die Funktion _GUICtrlTreeViewSort haben wir ja in dem Skript! Kenne mich aber nicht so mit GUICtrlSendMsg aus.. könnte jemand anders es vielleicht umschreiben? Wäre toll

Achso, und könnte man den Vorgang etwas verschnellern? also das lesen.. Bei eine 6MB datei brauch er über 30minuten(und dann hab ich ihn gestoppt..)

!!EDIT: Meine natürlich 6MB nich GB!!!!

Mfg Spider

**bernd670**

Hallo,

ich bin auf ein neues Problem gestoßen. Zwar hab ich es geschaft eine ca. 6MB große Datei in etwa 6 Minuten einzulesen (immerhin über 93000 Zeilen), allerdings kann der TreeView nicht mehr als 4089 Elemente aufnehmen. Es kann sich dabei nur um einen Fehler im TreeView handeln, da ich es jetzt schon mit mehreren Dateien probiert habe und immer die gleiche anzahl enthalten ist.

**GtaSpider**

Hallo!

Stimmt! Ich habe grade in der Hilfe unter "Aut" den eintrag gefunden:
GUI_MAXCONTROLS 4093 Maximum number of controls in GUI box.
Dieses Problem haben ein paar im Englischen forum auch, aber nur mit ListView und nicht mitTreeView.. (http://www.autoitscript.com/forum/index.php?act=Search&CODE=show&searchid=bef61803bea2ecbaa992ef075e72df6e&search_in=posts&result_type=topics&highlite=%2B4093)
aber warum kannst du eine 6mb datei lesen und ich nicht?

Mfg Spider

**bernd670**

Ich habe die Funktion MakeFileTree etwas optimiert.

Die Änderungen beziehen sich auf die Zeilen: 3, 24, 61-64 und 110-113

Spoiler anzeigen

Code

Func MakeFileTree($strFileName)

	Local $arFile, $arTemp, $iFile, $iInsert, $iPos, $iPos2, $iFTNum

	If Not FileExists($strFileName) Then
		MsgBox(16, "Fehler", "Datei " & $strFileName & " wurde nicht gefunden!")
		Exit
	EndIf
	_FileReadToArray($strFileName, $arFile)
; 	_ArraySort($arFile,0,1)
	; Leerzeilen entfernen
	    $iPos = 1
	    While 1
	        If Not stringlen(StringStripWS($arFile[1],15)) Then 
		   _ArrayDelete($arFile,1)
		   $arFile[0] = $arFile[0] - 1
	        Else
		   ExitLoop
	        EndIf
	        $iPos = $iPos + 1
	    Wend


    $Ebene = 0
    $iFTNum = 0
	$arTemp = StringSplit(StringStripCR($arFile[1]), "\")
	For $iInsert = 1 To $arTemp[0]

		If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

		Select
			Case $iInsert = 1
				; Laufwerksbezeichnung
				ControlSetText("dada","","Static1", $arTemp[$iInsert])
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $TreeView)
				$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
				$icon2 = "-1"
				$sis = StringInStr($icon, ",", 0, -1)
				If Not @error Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
				GUICtrlSetImage(-1, $icon, $icon2)
				$Ebene = $Ebene + 1

			Case $iInsert = $arTemp[0]
				; Dateiname
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $Tree[$Ebene - 1])
				$ext = StringTrimLeft($arTemp[$iInsert], StringInStr($arTemp[$iInsert], ".", 0, -1) - 1)
				$icon = RegRead("HKCR\" & $ext, "")
				$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
				$icon2 = "-1"
				$sis = StringInStr($icon, ",", 0, -1)
				If Not @error Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
;~ 			 MsgBox(0,$icon2,$icon)
				GUICtrlSetImage($Tree[$Ebene], $icon, $icon2)
                $FileTable[$iFTNum][0] = $Tree[$Ebene]
                $FileTable[$iFTNum][1] = $arFile[1]
                $iFTNum = $iFTNum + 1
                If UBound($FileTable,1) <= $iFTNum Then ReDim $FileTable[$iFTNum + 10000][2]
;~ 				GUICtrlSetOnEvent($Tree[$Ebene], "SelectFile")

			Case Else
				; Verzeichnisname
				$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$iInsert], $Tree[$Ebene - 1])
				$Ebene = $Ebene + 1

		EndSelect
	Next

	For $iFile = 2 To $arFile[0]
		$arTemp = StringSplit(StringStripCR($arFile[$iFile]), "\")
		$iPos = StringInStr($arFile[$iFile], "\", 0, -1)
		$strLeft = StringLeft($arFile[$iFile], $iPos)

		; Ebenenkorrektur
		$iPos2 = StringInStr($arFile[$iFile - 1], "\", 0, -1)
        $Ebene = $Ebene + (UBound(StringSplit($strLeft, "\"), 1) - UBound(StringSplit(StringLeft($arFile[$iFile - 1], $iPos2), "\"), 1))


    ControlSetText("dada","","Static1", $iFile & " / " & $arFile[0])

		For $iSearch = 0 To $arTemp[0] - 1
			If StringLeft($arFile[$iFile - 1], StringLen($strLeft)) = $strLeft Then
				For $iInsert = $iSearch To 0 Step - 1

					If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

					Select
						Case $iInsert = 0
							; Dateiname
							If $Ebene = 0 Then $Ebene = 1
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
							$ext = StringTrimLeft($arTemp[$arTemp[0] - $iInsert], StringInStr($arTemp[$arTemp[0] - $iInsert], ".", 0, -1) - 1)
							$icon = RegRead("HKCR\" & $ext, "")
							$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
							$icon2 = "-1"
							$sis = StringInStr($icon, ",", 0, -1)
							If Not @error Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
;~ 			 MsgBox(0,$icon2,$icon)
							GUICtrlSetImage($Tree[$Ebene], $icon, $icon2)
;~ 							GUICtrlSetOnEvent($Tree[$Ebene], "SelectFile")
                            $FileTable[$iFTNum][0] = $Tree[$Ebene]
                            $FileTable[$iFTNum][1] = $arFile[$iFile]
                            $iFTNum = $iFTNum + 1
                            If UBound($FileTable,1) <= $iFTNum Then ReDim $FileTable[$iFTNum + 10000][2]

						Case $iInsert = $arTemp[0] - 1
							; Laufwerksbezeichnung
							ControlSetText("dada","","Static1", $arTemp[$arTemp[0] - $iInsert])
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $TreeView)
							$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
							$icon2 = "-1"
							$sis = StringInStr($icon, ",", 0, -1)
							If Not @error Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
							GUICtrlSetImage(-1, $icon, $icon2)
							$Ebene = $Ebene + 1

						Case Else
							; Verzeichnisname
							$Tree[$Ebene] = GUICtrlCreateTreeViewItem($arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
							$Ebene = $Ebene + 1

					EndSelect
				Next
				ExitLoop
			Else
				$Ebene = $Ebene - 1
			EndIf
			$iPos = StringInStr($strLeft, "\", 0, -2)
			$strLeft = StringLeft($strLeft, $iPos)
		Next
	Next
    MsgBox(0,"Elemente im TreeView",GUICtrlSendMsg($TreeView, $TVM_GETCOUNT, 0, 0))
	_GUICtrlTreeViewSort ($TreeView)
EndFunc   ;==>MakeFileTree

Alles anzeigen

**GtaSpider**

Hallo

Es gibt da noch eine Funktion: _GUICtrlTreeViewInsertItem() Mit der kann man unendlich vile erstellen! In der Beta! wer sie nicht hat:

Spoiler anzeigen

Code

;===============================================================================
;
; Description:		_GUITreeViewInsertItem
; Parameter(s):		$i_treeview		- controlID
;					$s_itemtext		- item text
;					$h_item			- Optional: parent item ID/handle
;					$h_item_after	- Optional: item ID to insert new item after
; Requirement:		<GuiTreeView.au3>
; Return Value(s):	Return the new item handle if successfull or 0 otherwise
; User CallTip:		_GUITreeViewInsertItem($i_treeview, $s_itemtext [, $h_item_parent = 0 [, $h_item_after = 0]])
; Author(s):		Holger Kotsch
; Note(s):			Insert an item into a treeview control
;
;===============================================================================
Func _GUICtrlTreeViewInsertItem($i_treeview, $s_itemtext, $h_item_parent = 0, $h_item_after = 0)
	Local $h_item_tmp
	Local $st_TVI	= DllStructCreate("uint;uint;" & $s_TVITEMEX)
	If @Error Then Return 0

	Local $st_text	= DllStructCreate("char[260]")
	If @Error Then Return 0

	If $h_item_parent = 0 Then
		$h_item_parent = $TVI_ROOT
	Else
		$h_item_tmp = GUICtrlGetHandle($h_item_parent)
		If $h_item_tmp <> 0 Then $h_item_parent = $h_item_tmp
				EndIf

	If $h_item_after = 0 Or _
		($h_item_after <> $TVI_ROOT And _
		$h_item_after <>  $TVI_FIRST And _
		$h_item_after <> $TVI_LAST And _
		$h_item_after <> $TVI_SORT) Then
		$h_item_after = $TVI_LAST
			EndIf

	DllStructSetData($st_text, 1, $s_itemtext)

	Local $u_mask = $TVIF_TEXT

	Local $h_icon = _TreeViewGetImageListIconHandle($i_treeview, 0)
	If $h_icon <> 0 Then
		$u_mask = BitOr($u_mask, $TVIF_IMAGE)
		DllStructSetData($st_TVI, 9, 0)
		DllCall("user32.dll", "int", "DestroyIcon", "hwnd", $h_icon)
				EndIf

	$h_icon = _TreeViewGetImageListIconHandle($i_treeview, 1)
	If $h_icon <> 0 Then
		$u_mask = BitOr($u_mask, $TVIF_SELECTEDIMAGE)
		DllStructSetData($st_TVI, 10, 1)
		DllCall("user32.dll", "int", "DestroyIcon", "hwnd", $h_icon)
			EndIf

	DllStructSetData($st_TVI, 1, $h_item_parent)
	DllStructSetData($st_TVI, 2, $h_item_after)
	DllStructSetData($st_TVI, 3, $u_mask)
	DllStructSetData($st_TVI, 7, DllStructGetPtr($st_text))

	Return GUICtrlSendMsg($i_treeview, $TVM_INSERTITEM, 0, DllStructGetPtr($st_TVI))
EndFunc   ;==>_GUITreeViewInsertItem

Alles anzeigen

**bernd670**

Werde ich gleich mal probieren! :comp2:

**bernd670**

hier ist die neue Version mit _GUICtrlTreeViewInsertItem, ist aber noch nicht das gelbe vom Ei, wenn ein bestimmter Speicherbereich überschritten wird, beendet das Programm!

Bei mir etwa nach 84000 eingelesenen Zeilen!

Spoiler anzeigen

C

;~ ###################################################
;~ # Funktion: Stellt Dateiinhalt als TreeView dar
;~ #
;~ # Autor: bernd670 & GtaSpider
;~ #
;~ # AutoIt-Version: 3.1.1.124 beta
;~ ##################################################
#include <File.au3>
#include <Array.au3>
#include <GUIConstants.au3>
#include <GuiTreeView.au3>


Global $Tree[1], $FileTable[1][2]


$datei = "WS2KADM002.txt"
SplashTextOn("dada","initalizing",200,20,-1,-1,17)


Opt("TrayIconDebug",1)


$mainwindow = GUICreate("BG Commander - "&$datei, 359, 439, 193, 126)
$TreeView = GUICtrlCreateTreeView(10, 10, 261, 397, BitOR($WS_BORDER, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS))
;GUICtrlSetImage(-1, "shell32.dll", 4, 3)
$Search = GUICtrlCreateInput("", 60, 410, 121, 20)
GUICtrlCreateLabel("Suche:", 20, 410, 38, 15)
$SearchBut = GUICtrlCreateButton("Suchen", 190, 410, 82, 25, 0)
$start = GUICtrlCreateButton("Datei &Starten", 280, 10, 75, 25, 0)
$exit = GUICtrlCreateButton("E&xit", 280, 410, 75, 25, 0)
GUICtrlCreateEdit("", 280, 40, 75, 359,  BitOR($ES_AUTOVSCROLL,$ES_AUTOHSCROLL,$ES_READONLY,$ES_WANTRETURN))
GUICtrlSetData(-1, "Copyright by"&@CRLF&"Bernd 670"&@CRLF&"& GtaSpider"&@CRLF&""&@CRLF&"Was macht"&@CRLF&"dieser"&@CRLF&"Commander?"&@CRLF&""&@CRLF&"Er listet von"&@CRLF&"einer Datei,"&@CRLF&"Dateien,"&@CRLF&"Ordner"&@CRLF&"und"&@CRLF&"Laufwerke"&@CRLF&"auf die er"&@CRLF&"dann in der"&@CRLF&"Box"&@CRLF&"Kompfortabel"&@CRLF&"anzeigt"&@CRLF&"werden"&@CRLF&""&@CRLF&"Was mach"&@CRLF&"ich bei Problemen?"&@CRLF&""&@CRLF&"Entweder eine"&@CRLF&"Im Forum"&@CRLF&"fragen!")
MakeFileTree($datei)


SplashOff()


GUISetState()


While 1
	$msg = GUIGetMsg()
	Select
		Case $msg = $GUI_EVENT_CLOSE Or $msg = $exit
			Exit
		Case $msg = $start
			SelectFile(GUICtrlSendMsg($TreeView, $TVM_GETNEXTITEM, $TVGN_CARET, 0))
		Case $msg = $SearchBut
			$SearchFile = GUICtrlRead($Search)
			Search($SearchFile)
	EndSelect
WEnd


Func Search($Search)
	;Hier kommt dann die Suchfunktion rein!
	MsgBox(0,"",$Search)
EndFunc
Func SelectFile($lastclick)
	;Beachte: an diesem Punkt wäre @GUI_CTRLID gleich $Tree[$Ebene]
	For $index = 0 To UBound($FileTable, 1) - 1
		If $FileTable[$index][0] = $lastclick Then
			RunWait(@ComSpec & ' /c start "' & $FileTable[$index][1] & '"', '', @SW_HIDE)
			ExitLoop
		EndIf
	Next
EndFunc   ;==>SelectFile




Func MakeFileTree($strFileName)

	Local $arFile, $arTemp, $iFile, $iInsert, $iPos, $iPos2, $iFTNum

	If Not FileExists($strFileName) Then
		MsgBox(16, "Fehler", "Datei " & $strFileName & " existiert nicht!")
		Exit
	EndIf
	_FileReadToArray($strFileName, $arFile)
    DirSort($arFile)
; 	_ArraySort($arFile,0,1)


    ; Leerzeilen entfernen
    $iPos = 1
    While 1
        If Not stringlen(StringStripWS($arFile[1],15)) Then 
            _ArrayDelete($arFile,1)
            $arFile[0] = $arFile[0] - 1
        Else
            ExitLoop
        EndIf
        $iPos = $iPos + 1
    Wend


    $Ebene = 0
    $iFTNum = 0
	$arTemp = StringSplit(StringStripCR($arFile[1]), "\")
	For $iInsert = 1 To $arTemp[0]

		If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

		Select
			Case $iInsert = 1
				; Laufwerksbezeichnung
				ControlSetText("dada","","Static1", $arTemp[$iInsert])
                $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$iInsert])
				$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,8"
				$icon2 = "0"
				$sis = StringInStr($icon, ",", 0, -1)
				If $sis Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
                _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], $icon, $icon2)
				$Ebene = $Ebene + 1

			Case $iInsert = $arTemp[0]
				; Dateiname
                $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$iInsert], $Tree[$Ebene - 1])
				$ext = StringTrimLeft($arTemp[$iInsert], StringInStr($arTemp[$iInsert], ".", 0, -1) - 1)
				$icon = RegRead("HKCR\" & $ext, "")
				$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
                If @error Then
                    $icon = RegRead("HKCR\" & $ext, "")
                    $icon = RegRead("HKCR\" & $icon & "\CurVer", "")
                    $icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
                EndIf
				If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
				$icon2 = "0"
				$sis = StringInStr($icon, ",", 0, -1)
				If $sis Then
					$icon2 = StringTrimLeft($icon, $sis)
					$icon = StringTrimRight($icon, StringLen($icon2) + 1)
				EndIf
                _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], $icon, $icon2)
                $FileTable[$iFTNum][0] = $Tree[$Ebene]
                $FileTable[$iFTNum][1] = $arFile[1]
                $iFTNum = $iFTNum + 1
                If UBound($FileTable,1) <= $iFTNum Then ReDim $FileTable[$iFTNum + 10000][2]

			Case Else
				; Verzeichnisname
                $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$iInsert], $Tree[$Ebene - 1])
                _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], "shell32.dll", 4)
				$Ebene = $Ebene + 1

		EndSelect
	Next

	For $iFile = 2 To $arFile[0]
		$arTemp = StringSplit(StringStripCR($arFile[$iFile]), "\")
		$iPos = StringInStr($arFile[$iFile], "\", 0, -1)
		$strLeft = StringLeft($arFile[$iFile], $iPos)

		; Ebenenkorrektur
		$iPos2 = StringInStr($arFile[$iFile - 1], "\", 0, -1)
        $Ebene = $Ebene + (UBound(StringSplit($strLeft, "\"), 1) - UBound(StringSplit(StringLeft($arFile[$iFile - 1], $iPos2), "\"), 1))


        ControlSetText("dada","","Static1", $iFile & " / " & $arFile[0])

		For $iSearch = 0 To $arTemp[0] - 1
			If StringLeft($arFile[$iFile - 1], StringLen($strLeft)) = $strLeft Then
				For $iInsert = $iSearch To 0 Step - 1

					If UBound($Tree, 1) <= $Ebene Then ReDim $Tree[$Ebene + 1]

					Select
						Case $iInsert = 0
							; Dateiname
							If $Ebene = 0 Then $Ebene = 1
                            $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
							$ext = StringTrimLeft($arTemp[$arTemp[0] - $iInsert], StringInStr($arTemp[$arTemp[0] - $iInsert], ".", 0, -1) - 1)
							$icon = RegRead("HKCR\" & $ext, "")
							$icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
                            If @error Then
                                $icon = RegRead("HKCR\" & $ext, "")
                                $icon = RegRead("HKCR\" & $icon & "\CurVer", "")
                                $icon = RegRead("HKCR\" & $icon & "\DefaultIcon", "")
                            EndIf
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,2"
							$icon2 = "0"
							$sis = StringInStr($icon, ",", 0, -1)
							If $sis Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
;~                             ControlSetText("dada","","Static1", $icon & "|"  & $icon2)
                            _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], $icon, $icon2)
                            $FileTable[$iFTNum][0] = $Tree[$Ebene]
                            $FileTable[$iFTNum][1] = $arFile[$iFile]
                            $iFTNum = $iFTNum + 1
                            If UBound($FileTable,1) <= $iFTNum Then ReDim $FileTable[$iFTNum + 10000][2]

						Case $iInsert = $arTemp[0] - 1
							; Laufwerksbezeichnung
                            $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$arTemp[0] - $iInsert])
							$icon = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons", "8")
							If $icon = "%1" Or @error Or $icon = "" Then $icon = "shell32.dll,8"
							$icon2 = "0"
							$sis = StringInStr($icon, ",", 0, -1)
							If $sis Then
								$icon2 = StringTrimLeft($icon, $sis)
								$icon = StringTrimRight($icon, StringLen($icon2) + 1)
							EndIf
                            _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], $icon, $icon2)
							$Ebene = $Ebene + 1

						Case Else
							; Verzeichnisname
                            $Tree[$Ebene] = _GUICtrlTreeViewInsertItem($TreeView, $arTemp[$arTemp[0] - $iInsert], $Tree[$Ebene - 1])
                            _GUICtrlTreeViewSetIcon($TreeView, $Tree[$Ebene], "shell32.dll", 4)
							$Ebene = $Ebene + 1

					EndSelect
				Next
				ExitLoop
			Else
				$Ebene = $Ebene - 1
			EndIf
			$iPos = StringInStr($strLeft, "\", 0, -2)
			$strLeft = StringLeft($strLeft, $iPos)
		Next
	Next
    ReDim $FileTable[$iFTNum]
    MsgBox(0,"Elemente im TreeView",GUICtrlSendMsg($TreeView, $TVM_GETCOUNT, 0, 0))
	;_GUICtrlTreeViewSort ($TreeView)
EndFunc   ;==>MakeFileTree




Func DirSort (ByRef $arUnSort)
    ;; Muss noch angepaßt werden damit die 
    ;; Dateien und Order in der richtigen Reihenfolge stehen
    Local $iIndex

    MyQuickSort($arUnSort,1,UBound($arUnSort,1)-1)


EndFunc


Func MyQuickSort (ByRef $arUnSort, $iFirst, $iLast)

    Local $iLeft = $iFirst
    Local $iRight = $iLast
    Local $arPivo = $arUnSort[($iFirst+$iLast)/2]
    Local $arTemp


    Do
        While $arUnSort[$iLeft] < $arPivo
            $iLeft = $iLeft + 1
        WEnd


        While $arUnSort[$iRight] > $arPivo
            $iRight = $iRight - 1
        WEnd


        If ($iLeft <= $iRight) Then
            $arTemp = $arUnSort[$iLeft]
            $arUnSort[$iLeft] = $arUnSort[$iRight]
            $arUnSort[$iRight] = $arTemp
            $iLeft = $iLeft + 1
            $iRight = $iRight - 1
        EndIf
    Until ($iLeft > $iRight)


    If ($iFirst < $iRight) Then MyQuickSort($arUnSort,$iFirst,$iRight)
    If ($iLeft < $iLast) Then MyQuickSort($arUnSort,$iLeft,$iLast)
EndFunc

Alles anzeigen