Pixelganau zeichnen mit GDI+ / AutoIT - (wie) geht das ?

myicq

Ich möchte für eine Projekt pixel-genau zeichnen können. Schwarz auf Weiss.

Beispiel im Anhang.

Ich habe erfolgreich das Bild im Anhang mit Perl / Imagemagick gemacht. Problem ist: ich kann Perl nicht für die Kollegen kompilieren. Deshalb die Frage: kann ich das mit AutoIT irdgendwie machen ?

Ich muss im Bild haben

Linien horizontal oder Vertikal, in pixel-breite
Text horizontal oder Vertikal, in definierte größe, pixel-genau position

Ich brauche nicht die komplette Lösung, nur 1 oder 2 kleine Beispiele wie ich mit AutoIT linien ziechne.

Danke im Voraus!

(Bild ist Testbild einer Industriedrucker)

autobert2

Hallo myicq,

schau dir doch dazu in der Hilfe:

_GDIPlus_PenCreate
_GDIPlus_FontCreate

und die dazugehörigen Beispiele an.

myicq

@autobert2 : geht fast.. dank Beispiel im Englishen Forum. Aber es scheint als der Textumdrehung der ganze Canvas dreht. Deshalb kann ich meine Striche nicht zeichnen.

Ich sollte vielleicht mein Text separat zeichnen, und dann als Overlay einsetzen. Aber ich bin unsicher wie das geht.

Also: Text 0 Grad geht perfekt. Kann aber nur Beispiele für 90-Grad text im Gui finden.

Mein Code soweit:

Spoiler anzeigen

AutoIt

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include<Color.au3>


_GDIPlus_Startup()


#region GDI+


;create an empty bitmap
Global Const $iWidth = 2000, $iHeight = 900     ;dimension of the bitmap
Global Const $iStride = 0, $pScan0 = 0, $iPixelFormat =  $GDIP_PXF01INDEXED ;some bitmap parameters
$hBitmap = _GDIPlus_BitmapCreateFromScan0($iWidth, $iHeight, $iPixelFormat, $iStride, $pScan0)




; This is used where documentation mentions
; "handle to a graphics object"
Global Const $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)


Global Const $iBgColor = 0xFFFFFFFF ;define background color -> ARGB


;~ $hGraphics Handle to a Graphics object
_GDIPlus_GraphicsClear($hContext, $iBgColor) ;clear empty bitmap with new color




; define the pen
; default = 0xFF000000 = black solid.
$hPen = _GDIPlus_PenCreate(0xFF000000, 2,1)	; 2 px black


;
; DRAW the lines and text
	for $x = 10 to $iWidth Step 90
			ConsoleWrite("Drawing text line for --> " & $x & @lf)
			GDIPlus_SetAngledText($hContext, $x & "  pixel", $x+15,150, 45, "Arial", 25)
	Next


	for $x = 10 to $iWidth Step 90
			ConsoleWrite("Drawing graphics line for --> " & $x & @LF)
			_GDIPlus_GraphicsDrawLine($hContext, $x, 10, $x, $iHeight-10, $hPen)
		Next




;save result as JPG and PNG (conversation is done automatically)
_GDIPlus_ImageSaveToFile($hBitmap, @ScriptDir & "\New_Image.bmp")


_GDIPlus_BitmapDispose($hBitmap) ;release bitmap
_GDIPlus_GraphicsDispose($hContext)
_GDIPlus_Shutdown()
#endregion




; #FUNCTION# ================================================================
; Name...........: GDIPlus_SetAngledText
; Description ...: Adds text to a graphic object at any angle.
; Syntax.........: GDIPlus_SetAngledText($hGraphic, $nText, [$iCentreX, [$iCentreY, [$iAngle , [$nFontName , _
;										[$nFontSize, [$iARGB, [$iAnchor]]]]]]] )
; Parameters ....: $hGraphic   - The Graphics object to receive the added text.
;				   $nText      - Text string to be displayed
;                  $iCentreX       - Horizontal coordinate of horixontal centre of the text rectangle        (default =  0 )
;                  $iCentreY        - Vertical coordinate of vertical centre of the text rectangle             (default = 0 )
;                  $iAngle     - The angle which the text will be place in degrees.         (default = "" or blank = 0 )
;                  $nFontName  - The name of the font to be used                      (default = "" or Blank = "Arial" )
;                  $nFontSize  - The font size to be used                                  (default = "" or Blank = 12 )
;                  $iARGB      - Alpha(Transparency), Red, Green and Blue color (0xAARRGGBB) (Default= "" = random color
;           																		   or Default = Blank = 0xFFFF00FF )
;				   $iAnchor    - If zero (default) positioning $iCentreX, $iCentreY values refer to centre of text string.
;				   				 If not zero positioning $iCentreX, $iCentreY values refer to top left corner of text string.
; Return values .: 1
; Author ........: Malkey
; Modified.......:
; Remarks .......: Call _GDIPlus_Startup() before starting this function, and call _GDIPlus_Shutdown()after function ends.
;                  Can enter calculation for Angle Eg. For incline, -ATan($iVDist / $iHDist) * 180 / $iPI , where
;				   $iVDist is Vertical Distance,  $iHDist is Horizontal Distance, and, $iPI is Pi, (an added Global Const).
;				   When used with other graphics, call this function last. The MatrixRotate() may affect following graphics.
; Related .......: _GDIPlus_Startup(), _GDIPlus_Shutdown(), _GDIPlus_GraphicsDispose($hGraphic)
; Link ..........;
; Example .......; Yes
; ========================================================================================
Func GDIPlus_SetAngledText($hGraphic, $nText, $iCentreX = 0, $iCentreY = 0, $iAngle = 0, $nFontName = "Arial", _
		$nFontSize = 12, $iARGB = 0xFF000000, $iAnchor = 0)
	local Const $iPI = 3.1415926535897932384626433832795
	Local $x, $y, $iX, $iY, $iWidth, $iHeight
	Local $hMatrix, $iXt, $iYt, $hBrush, $hFormat, $hFamily, $hFont, $tLayout


	; Default values
	If $iAngle = "" Then $iAngle = 0
	If $nFontName = "" Or $nFontName = -1 Then $nFontName = "Arial" ; "Microsoft Sans Serif"
	If $nFontSize = "" Then $nFontSize = 12
	If $iARGB = "" Then ; Randomize ARGB color
		$iARGB = "0xFF" & Hex(Random(0, 255, 1), 2) & Hex(Random(0, 255, 1), 2) & Hex(Random(0, 255, 1), 2)
	EndIf


	$hFormat = _GDIPlus_StringFormatCreate(0)
	$hFamily = _GDIPlus_FontFamilyCreate($nFontName)
	$hFont = _GDIPlus_FontCreate($hFamily, $nFontSize, 1, 3)
	$tLayout = _GDIPlus_RectFCreate($iCentreX, $iCentreY, 0, 0)
	$aInfo = _GDIPlus_GraphicsMeasureString($hGraphic, $nText, $hFont, $tLayout, $hFormat)
	$iWidth = Ceiling(DllStructGetData($aInfo[0], "Width"))
	$iHeight = Ceiling(DllStructGetData($aInfo[0], "Height"))


	;Later calculations based on centre of Text rectangle.
	If $iAnchor = 0 Then ; Reference to middle of Text rectangle
		$iX = $iCentreX
		$iY = $iCentreY
	Else ; Referenced centre point moved to top left corner of text string.
		$iX = $iCentreX + (($iWidth - Abs($iHeight * Sin($iAngle * $iPI / 180))) / 2)
		$iY = $iCentreY + (($iHeight + Abs($iWidth * Sin($iAngle * $iPI / 180))) / 2)
	EndIf


	;Rotation Matrix
	$hMatrix = _GDIPlus_MatrixCreate()
	_GDIPlus_MatrixRotate($hMatrix, $iAngle, 1)
	_GDIPlus_GraphicsSetTransform($hGraphic, $hMatrix)


	;x, y are display coordinates of center of width and height of the rectanglular text box.
	;Top left corner coordinates rotate in a circular path with radius = (width of text box)/2.
	;Parametric equations for a circle, and adjustments for centre of text box
	$x = ($iWidth / 2) * Cos($iAngle * $iPI / 180) - ($iHeight / 2) * Sin($iAngle * $iPI / 180)
	$y = ($iWidth / 2) * Sin($iAngle * $iPI / 180) + ($iHeight / 2) * Cos($iAngle * $iPI / 180)


	;Rotation of Coordinate Axes formulae - To display at x and y after rotation, we need to enter the
	;x an y position values of where they rotated from. This is done by rotating the coordinate axes.
	;Use $iXt, $iYt in  _GDIPlus_RectFCreate. These x, y values is the position of the rectangular
	;text box point before rotation. (before translation of the matrix)
	$iXt = ($iX - $x) * Cos($iAngle * $iPI / 180) + ($iY - $y) * Sin($iAngle * $iPI / 180)
	$iYt = -($iX - $x) * Sin($iAngle * $iPI / 180) + ($iY - $y) * Cos($iAngle * $iPI / 180)


	$hBrush = _GDIPlus_BrushCreateSolid($iARGB)
	$tLayout = _GDIPlus_RectFCreate($iXt, $iYt, $iWidth, $iHeight)
	_GDIPlus_GraphicsDrawStringEx($hGraphic, $nText, $hFont, $tLayout, $hFormat, $hBrush)


	; Clean up resources
	_GDIPlus_MatrixDispose($hMatrix)
	_GDIPlus_FontDispose($hFont)
	_GDIPlus_FontFamilyDispose($hFamily)
	_GDIPlus_StringFormatDispose($hFormat)
	_GDIPlus_BrushDispose($hBrush)
	$tLayout = ""
	Return 1
EndFunc   ;==>GDIPlus_SetAngledText


Func Color_SetHSL($iHue, $Saturation = 180, $Brightness = 160)
	local $aInput =""
	If IsArray($iHue) Then
		$aInput = $iHue
	Else
		Local $aInput[3] = [$iHue, $Saturation, $Brightness]
	EndIf
	Local $aiRGB = _ColorConvertHSLtoRGB($aInput)
	Return "0x" & Hex(Round($aiRGB[0]), 2) & Hex(Round($aiRGB[1]), 2) & Hex(Round($aiRGB[2]), 2)
EndFunc   ;==>_Color_SetHSL

Alles anzeigen

**BugFix**

Zitat von myicq

Kann aber nur Beispiele für 90-Grad text im Gui finden.

Ich hatte mal eine kleine Oberfläche zum Testen gebastelt - Text in jedem Winkel. Probier einfach mal.

AutoIt

; ver 3.2.12.1
#Include <WinAPI.au3>
#include <GUIConstantsEx.au3>
#include <StructureConstants.au3>
#include <WindowsConstants.au3>


Global $GUI = GUICreate('Test Rotation')
GUICtrlCreateLabel('Text:', 10, 13, 50, 17)
Global $In = GUICtrlCreateInput('Hallo!', 70, 10, 150, 20)
Global $bt = GUICtrlCreateButton('Schreibe Text', 250, 10, 100, 20)
Global $btDel = GUICtrlCreateButton('Lösche Text', 250, 40, 100, 20)
GUICtrlCreateLabel('Pos. X:', 10, 43, 50, 17)
Global $inX = GUICtrlCreateInput('80', 70, 40, 30, 20)
GUICtrlCreateLabel('Pos. Y:', 110, 43, 50, 17)
Global $inY = GUICtrlCreateInput('280', 170, 40, 30, 20)
GUICtrlCreateLabel('Winkel:', 10, 73, 50, 17)
Global $inDeg = GUICtrlCreateInput('30', 70, 70, 30, 20)
GUICtrlCreateLabel('Höhe:', 110, 73, 50, 17)
Global $inSize = GUICtrlCreateInput('60', 170, 70, 30, 20)
GUICtrlCreateLabel('Breite:', 10, 103, 50, 17)
Global $inWeight = GUICtrlCreateInput('400', 70, 100, 30, 20)
GUICtrlCreateLabel('Font:', 110, 103, 50, 17)
Global $inFont = GUICtrlCreateInput('Comic Sans MS', 170, 100, 200, 20)
GUICtrlCreateGroup(' Stil ', 10, 130, 280, 40)
Global $rDef = GUICtrlCreateRadio('Standard', 15, 145, 65)
GUICtrlSetState(-1, $GUI_CHECKED)
Global $rIt = GUICtrlCreateRadio('Italic', 85, 145, 45)
Global $cbUn = GUICtrlCreateCheckbox('Underlined', 135, 145, 70)
Global $cbSt = GUICtrlCreateCheckbox('StrikeOut', 215, 145, 70)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateLabel('Farbe    Schrift:', 10, 183, 80, 17)
Global $inCol = GUICtrlCreateInput('', 90, 180, 60, 20)
GUICtrlCreateLabel('Hintergrund:', 160, 183, 80, 17)
Global $inbCol = GUICtrlCreateInput('', 230, 180, 60, 20)


GUISetState()
Global $Rect


Do
	$msg = GUIGetMsg()
	If $msg = $bt Then
		Local $type = 1, $col = -1, $bkcol = -1
		If BitAND(GUICtrlRead($rIt), $GUI_CHECKED) Then $type = 2
		If BitAND(GUICtrlRead($cbUn), $GUI_CHECKED) Then $type += 4
		If BitAND(GUICtrlRead($cbSt), $GUI_CHECKED) Then $type += 8
		Local $readFont = GUICtrlRead($inFont)
		If $readFont = '' Then $readFont = -1
		Local  $col = GUICtrlRead($inCol), $bkcol = GUICtrlRead($inbCol)
		If $col = '' Then $col = -1
		If $bkcol = '' Then $bkcol = -1
		_WriteRotateText($GUI, GUICtrlRead($In), GUICtrlRead($inX), GUICtrlRead($inY), GUICtrlRead($inDeg), _
			GUICtrlRead($inSize), GUICtrlRead($inWeight), $type, $readFont, $col, $bkcol)
	ElseIf $msg = $btDel Then
		_WinAPI_RedrawWindow($GUI)
	EndIf
Until $msg = $GUI_EVENT_CLOSE


;==================================================================================================
; Function Name:   _WriteRotateText($hWnd, $sWrite, $iX, $iY, $iDeg, $iSize [, $iWeight=400 _
;                               [, $iType=1 [, $sFont=-1 [, $iCol=-1 [, $iBkCol=-1 [,$bRedraw=True]]]]]])
; Description:     Schreibt einen Text mit bestimmtem Winkel in das angegebene Fenster
; Parameter(s):    $hWnd	Handle des Fensters
;                  $sWrite	der zu schreibende Text
;                  $iX		x-Position auf dem Fenster
;                  $iY		y-Position auf dem Fenster
;                  $iDeg	Rotationswinkel des Textes
;                  $iSize	Höhe des Textes
;     optional:    $iWeight	Fontbreite 0 - 1000 (Standard 400)
;     optional:    $iType	Fonttyp		1=normal (Standard); 2=Italic; 4=Underline; 8=StrikeOut
;                                       1 oder 2 können mit 4 und 8 kombiniert werden (5;9 od. 6;10)
;     optional:    $sFont	Fontname	-1=Font der Form (Standard)
;     optional:    $iCol	Fontfarbe			-1=schwarz (Standard)
;     optional:    $iBkCol	Hintergrundfarbe	-1=Hintergrundfarbe des Fensters (Standard)
;     optional:    $bRedraw	True=Fenster vorher neu zeichnen (vorige Beschriftung löschen - Standard)
; Requirement(s):  #Include <WinAPI.au3>; #include <StructureConstants.au3>; #include <WindowsConstants.au3>
;==================================================================================================
Func _WriteRotateText($hWnd, $sWrite, $iX, $iY, $iDeg, $iSize, $iWeight=400, $iType=1, $sFont=-1, $iCol=-1, $iBkCol=-1, $bRedraw=True)
	If $bRedraw Then _WinAPI_RedrawWindow($hWnd)
	Local $tRect = DllStructCreate($tagRECT)
	DllStructSetData($tRect, 'Left', $iX)
	DllStructSetData($tRect, 'Top', $iY)
	Local $rotate = $iDeg *10
	If ($rotate = 900) Or ($rotate = 1800) Or ($rotate = 2700) Then $rotate += 1
	Local $RotateMe = DllStructCreate($tagLOGFONT)
	DllStructSetData($RotateMe, 'Escapement', $rotate)
	DllStructSetData($RotateMe, 'Height', ($iSize * -20)/_WinAPI_TwipsPerPixelY())
	If $iWeight <> 400 Then DllStructSetData($RotateMe, 'Weight', $iWeight)
	If BitAND($iType, 2) Then DllStructSetData($RotateMe, 'Italic', True)
	If BitAND($iType, 4) Then DllStructSetData($RotateMe, 'Underline', True)
	If BitAND($iType, 8) Then DllStructSetData($RotateMe, 'StrikeOut', True)
	If $sFont <> -1 Then DllStructSetData($RotateMe, 'FaceName', $sFont)
	Local $rFont = _WinAPI_CreateFontIndirect($RotateMe)
	Local $hDC = _WinAPI_GetDC($hWnd)
	If $iCol <> -1 Then _WinAPI_SetTextColor($hDC, $iCol)
	If $iBkCol <> -1 Then _WinAPI_SetBkColor($hDC, $iBkCol) ; wenn Transparenz gewünscht, Folgezeile aktivieren
;~ 	_WinAPI_SetBkMode($hDC, $TRANSPARENT)
	_WinAPI_SelectObject($hdc, $rFont)
	_WinAPI_DrawText($hDC, $sWrite, $tRect, BitOR($DT_NOCLIP,$DT_NOPREFIX))
	_WinAPI_ReleaseDC($hWnd, $hDC)
EndFunc  ;==>_WriteRotateText

Alles anzeigen