GDI Plus Bild aus dem Backbuffer zeichen

Gofel

Ich weiß, gefühlt schon 100 mal behandelt, leider konnte mir bisher kein Beitrag im Forum so richtig weiterhelfen.

Ich spiele grade etwas mit GDI Plus rum und versuche Buttons aus transparenten PNG Bilder zu erstellen. Ab und an kommt es beim neuzeichnen der png Bilder zu einem Flackern. Ich hörte von diesem Backbuffer, bekomme ihn aber einfach nicht umgesetzt.

Hier mal ein Beispiel, $Pic bitte anpassen:

AutoIt

#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>


Opt("GUIOnEventMode", 1) ;Gui on Event Mode




Global $Pic = @ScriptDir & "\lib\gra\buttons\play.png"
Global $hGUI_Main, $hGraphic, $hImage
Global $hGUI_Main_Color = 0xF0F0F0




;------------------


_Gui()
_Draw()


While 1
	Sleep(500)
	_Redraw()
WEnd


;------------------




Func _Gui()
	$hGUI_Main = GUICreate("", 400 , 400, -1, -1)
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Exit")
	GUISetState(@SW_SHOW, $hGUI_Main)
EndFunc


Func _Draw()


	;Pic einmal normal zeichen
	_GDIPlus_StartUp()
	$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI_Main)
	$hImage = _GDIPlus_ImageLoadFromFile($Pic)
	_GDIPlus_GraphicsDrawImageRect( $hGraphic, $hImage, 0, 0, 400, 400)




EndFunc


Func _Redraw()


	;Pinsel zum übermalen vorbereiten
	$hBrush = _GDIPlus_BrushCreateSolid(0xFF000000 + $hGUI_Main_Color)
	_GDIPlus_GraphicsFillRect($hGraphic, 0, 0, 400, 400, $hBrush)
	;Übermalen
	_GDIPlus_GraphicsDrawImageRect( $hGraphic, $hBrush, 0, 0, 400, 400)




	;Bild in den Backbuffer laden und neu zeichen


	;?????
	_GDIPlus_GraphicsDrawImageRect( $hGraphic, $hImage, 0, 0, 400, 400)


EndFunc


Func _Exit()
;~ 	_GDIPlus_GraphicsDispose($backbuffer)
;~     _GDIPlus_BitmapDispose($bitmap)
	Exit
EndFunc

Alles anzeigen

Im eigentlichen Programm zeichne ich natürlich nicht alle 500ms neu, ist nur ein Beispiel.
Kann mir bitte jemand auf die Sprünge helfen.

Edit: Das Beispiel ist vielleicht etwas unglücklich gewählt, ein Schuh wird draus wenn es nicht jedes mal wieder neu in den Backbuffer galaden wird sondern nur aus dem Backbuffer neu gezeichnet wird.
Mir geht es hauptsächlich um das WIE in den Backbuffer und WIE von dort aufs GUI zeichen.

**UEZ**

Wenn du tranparente PNG Bilder als Buttons verwenden möchtest, würde ich dir eher empfehlen die PNGs in den Button zu kopieren, um einfach das Neuzeichen zu vermeiden.

So was zum Beispiel:

AutoIt

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>


Global Const $hGUI = GUICreate("Test", 300, 250)
GUISetBkColor(0x808080)
Global Const $idButton = GUICtrlCreateButton("", 55, 20, 193, 184, $BS_BITMAP)
SendImageToBtnCtrl("c:\Program Files (x86)\AutoIt3\Beta\Examples\GUI\Torus.png", $idButton)
GUISetState()


Do
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			GUIDelete()
			Exit
	EndSwitch
Until False


Func SendImageToBtnCtrl($sFile, $iCtrl, $bDeleteBmp = True)
	If Not FileExists($sFile) Then Return SetError(1, 0, 0)
	_GDIPlus_Startup()
	Local Const $hImage = _GDIPlus_ImageLoadFromFile($sFile)
	If @error Then Return SetError(2, 0, 0)
	Local Const $hBitmapGDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
	_WinAPI_DeleteObject(_SendMessage(GUICtrlGetHandle($iCtrl), $BM_SETIMAGE, $IMAGE_BITMAP, $hBitmapGDI))
	_GDIPlus_ImageDispose($hImage)
	_GDIPlus_Shutdown()
	If $bDeleteBmp Then
		_WinAPI_DeleteObject($hBitmapGDI)
		Return 1
	EndIf
	Return $hBitmapGDI
EndFunc

Alles anzeigen

Funzt ab Vista. Für WinXP muss man einen Workaround machen, damit die Hintergrundfarbe des transparenten Bildes nicht schwarz ist.

CentuCore

Ein Backbuffer ist im Prinzip nur ein leeres Bild in das du hineinzeichnest.
Wenn du dann mim Zeichnen fertig bist zeichnest du das Bild auf die GUI.

Spoiler anzeigen

AutoIt

#include <GDIPlus.au3>
_GDIPlus_Startup()
Local $gui = GUICreate("GDI+ Backbuffer Demo", 500, 200)
GUISetState()
Local $gui_width = WinGetPos($gui)[2], $gui_height = WinGetPos($gui)[3]
Local $fontsize = 60
Local $graphics = _GDIPlus_GraphicsCreateFromHWND($gui)
Local $backbuffer = _GDIPlus_BitmapCreateFromGraphics($gui_width, $gui_height, $graphics)
Local $bb = _GDIPlus_ImageGetGraphicsContext($backbuffer)


; In Backbuffer zeichnen
_GDIPlus_GraphicsDrawString($bb, "Hello World :)", ($gui_width / 2) - 230, ($gui_height / 2) - $fontsize, "CALIBRI", $fontsize)


While GUIGetMsg() <> -3
	; Backbuffer anzeigen
	_GDIPlus_GraphicsDrawImage($graphics, $backbuffer, 0, 0)


	Sleep(200)
WEnd


; GDI+ beenden
_GDIPlus_GraphicsDispose($bb)
_GDIPlus_BitmapDispose($backbuffer)
_GDIPlus_GraphicsDispose($graphics)
_GDIPlus_Shutdown()
Exit

Alles anzeigen

Wenn du den Backbuffer zB aber mehrmals beschreibst, musst du ihn mit _GDIPlus_GraphicsClear() vorher aber noch "leeren", da ja noch das Bild vom verherigen Frame drinnen ist.

Spoiler anzeigen

AutoIt

; Pseudo-code


while( zB Spiel läuft )


	; Backbuffer leeren
	_GDIPlus_GraphicsClear($bb, 0xFFFFFFFF) ;AARRGGBB-Format in Hexadezimal


	; zeichne Spiel in Backbuffer
	_DrawGame($bb)


	; Backbuffer anzeigen
	_GDIPlus_GraphicsDrawImage($graphics, $backbuffer, 0, 0)


WEnd

Alles anzeigen

Ich empfehl dir übrigens auch das was UEZ gesagt hat zu machen. Das ganze GUI-Zeugs mit dem Testen ist die Maus jz auf dem Button oder nicht ist einfach seeeehr umfangreich und kann sich mit solchen Tricks recht leicht umgehen lassen. Zudem sind dann solche "eigenen" Controls nicht so leicht zu automatisieren

Gofel

Zitat von CentuCore

Das ganze GUI-Zeugs mit dem Testen ist die Maus jz auf dem Button oder nicht ist einfach seeeehr umfangreich und kann sich mit solchen Tricks recht leicht umgehen lassen. Zudem sind dann solche "eigenen" Controls nicht so leicht zu automatisieren

Das habe ich bisher mit einem Pseudo Control gelöst. Event auf leeres GUICtrlCreatePic(), selbe stelle mit GDI Plus übermalen.
Dein Beispiel hilft mir leider nicht weiter, du backbufferst ein _GraphicsDrawString und nicht ein transparentes png, genau bei dieser Umstellung habe ich ja den Knoten im Kopf

An UEZ´s Variante stört mich jetzt nur noch das man den Button darunter noch sieht, ich wollte mir halt eigene Controls basteln die auch mal ihr Aussehen ändern können (aus Play Button wird z.B. der Laden Button). Ein unötiges neuzeichnen ließe sich sicherlich auch anders im Code abfangen, aber dann bleibt immer noch der Fall das wenn ich viele dieser eigenen Controls gleichzeitig ändern will ein deutliches nacheinander zeichen zu sehen ist. Schöner wäre wenn alle gepuffert wären und gleichzeitig angezeigt werden, dann flackert es zumindest nur einmal kurz.

Hier vielleicht mal ein Screenshot um sich das besser vorstellen zu können:

beispiel.JPG

Links ist eine Liste mit Spielen die ich habe, rechts werden die Artworks für das Spiel gesetzt. Wähle ich ein anderes Spiel bauen sich die Artworks und Sprachen Symbole (manchmal) merklich nacheinander auf. Klicke ich auf das gleiche Spiel nur in einer anderen Sprache wird womöglich wieder das selbe Cover Artwork angezeigt (weil ich für die englische und deutsche Variante eventuell das gleiche Bild hinterlegt habe). Leider Flackert dann wieder alles. Sollte das mit dem Backbuffer nicht klappen müsste ich erstmal die Checksummen der Bilder vergleichen und dann nur bei Bedarf neu zeichnen, was wieder neu Probleme aufwirft da sich die Bilder teilweise überlagern...
Dem Problem wollte ich am liebsten mit einem "unbemerkten" neuzeichnen entgegen treten.

CentuCore

Zitat von Gofel

Das habe ich bisher mit einem Pseudo Control gelöst. Event auf leeres GUICtrlCreatePic(), selbe stelle mit GDI Plus übermalen.

Nice, auf die Idee wär ich nicht gekommen.
Ich mach echt zu wenig mit AutoIt

Zitat von Gofel

Dein Beispiel hilft mir leider nicht weiter, du backbufferst ein _GraphicsDrawString und nicht ein transparentes png, genau bei dieser Umstellung habe ich ja den Knoten im Kopf

na anstelle von DrawString fügst du einfach jeden Zeichenbefehl ein den du willst und schon ist das "gebackbuffert".

Gofel

Zitat von CentuCore

na anstelle von DrawString fügst du einfach jeden Zeichenbefehl ein den du willst und schon ist das "gebackbuffert".

Ich mache schon den 2. Tag nichts anderes als von solchen Beispielen zu versuchen auf _GDIPlus_GraphicsDrawImageRect() umzustellen.
Ich habe da entweder einen riesen Knoten im Kopf oder Transparente PNG lassen sich nicht mal ebend auf diese Weise in den Backbuffer schieben, ich erhalte immer eine leeres Bild.
Daher meine Bitte mir möglichst meinen Code oben anzupassen.

**Oscar**

Vielleicht möchtest Du ja meine UDF "_GuiCtrlSetImageEx" benutzen?!

Damit kannst Du Pic-Controls beliebige Bilder (PNG, GIF, JPG, ICO, BMP, etc.) zuweisen.
Auch transparente PNGs sind kein Problem (Hintergrundfarbe kann man angeben).

Hier mal ein Beispiel:

AutoIt

#include <GUIConstantsEx.au3>
#include '_GuiCtrlSetImageEx.au3'


Opt('GUIOnEventMode', 1)


Global $hGui = GUICreate('Test', 800, 600)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetBkColor(0xF0F0F0)
Global $idButton1 = GUICtrlCreatePic('', 20, 20, 600, 400)
GUICtrlSetOnEvent(-1, '_Button1Func')
_GuiCtrlSetImageEx(-1, @ScriptDir & '\test.png', False, 0xF0F0F0)
GUISetState(@SW_SHOW, $hGui)
WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc


Func _Button1Func()
	MsgBox(0, 'test', 'Button1')
EndFunc

Alles anzeigen

Gofel

Das klingt zu schön um wahr zu sein Oscar, ich schaue es mir morgen gleich an. Jetzt muss ich erstmal Sohnemann bespaßen. Ich geb dann bescheid.

**UEZ**

Du kannst auch das Picture Control nehmen oder machst den Button "Flat", wenn du den Button nicht als Button nehmen willst.

Dazu müsste mein Code umgeschrieben werden, aber Oscar ist ja eingesprungen, so dass du seine UDF nehmen kannst.

**chesstiger**

Nur der Vollständigkeit halber, auch wenn die UDF von Oscar schon die Lösung ist: Statt mit einem Backbuffer immer wieder dasselbe zu malen, kannst du auch einfach WM_PAINT abfangen.

Findest du irgendwo in meinem GDI+-Tutorial.

Gofel

"WM_PAINT" und "einfach" in einem Satz zu verwenden betrachte ich jetzt "einfach" mal als Provokation
Spaß, ich verwende ja WM_PAINT. Aber ich zeichne ja ebend nicht immer das selbe sondern die Artworks zum Spiel ändern sich. Dabei muss wieder die Stelle neutral eingefärbt werden und ein neues Bild gezeichnet werden. Das ganze 5 mal hintereinander für 5 Artworks ergibt ein leichtes Flackern.

Egal, Oscar hat tatsächlich die Lösung geliefert wie mir scheint. Der komplette Umbau wird mich noch etwas Zeit kosten, aber erste Tests laufen schon sehr erfreulich.

Danke