Programm zum durchsuchen von .inf Datein

hajoh25

Hallo Leute,
ich wollte in letzter Zeit ein Programm schreiben, mit dem ich eine .ini bzw. eine .inf Datei nach einem Wort zu durchsuchen und danach die Zeile auszugeben, die 2 Zeilen darunter liegt. Das Wort, wonach die Datei durchsucht werden soll, soll man vorher durch einen Input-Eingabefeld festlegen.
Bei meinem Code funktioniert das Fenster, aber wenn man den Button drckt, passiert nicht. Da ich mich erst 2 Tage mit dem Programm auseinander setze, bitte ich um eure Hilfe.
Danke im vorraus

#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>

$Form1 = GUICreate("Nummer suchen", 288, 130, 192, 124)
$Name = GUICtrlCreateLabel("Name", 16, 16, 48, 23)
GUICtrlSetFont(-1, 12, 800, 0, "Arial")
$Input = GUICtrlCreateInput("", 16, 40, 249, 28)
GUICtrlSetFont(-1, 12, 800, 0, "Arial Narrow")
$Button1 = GUICtrlCreateButton("Suchen", 16, 72, 81, 33)
GUICtrlSetFont(-1, 12, 800, 2, "Arial Narrow")
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit

EndSwitch
WEnd

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
case $Button1

$datei = IniRead("C:\Users\Johannes\Desktop\caller.inf", "section2", "key", "NotFound")
$eingabe = $Input

$count = _FileReadLines($datei)

For $i = 1 to $count
$line = FileReadLine($datei, $i)

If StringInStr($line, $Input) Then
$z = 2
$b = & i + $z

$line = FileReadLine($datei, $b)
MsgBox(0, "Nummer gefunden!" & $Input & @CRLF & "" & $line)
EndIf
Next

EndSwitch
WEnd

**Kanashius**

$eingabe=$input ist falsch. richtig wäre $eingabe=guictrlread($input). Ansonsten ließt du den handle des controls ein (oder die nummer). und code bitte in code tags ;), danke

**Oscar**

Außerdem:
Die erste While...WEnd-Schleife ist überflüssig.
Eine Datei zeilenweise einzulesen (noch dazu ohne ein Handle zu benutzen) ist sehr langsam. _FileReadToArray und anschließend das Array zu durchsuchen ist erheblich schneller.

Zitat

$b = & i + $z

ist von der Syntax her falsch. Mal abgesehen davon, dass man das nicht extra einer/zwei Variablen zuweisen muss = FileReadLine($datei, $i + 2) würde auch gehen, aber die Schleife darf dann auch nicht bis zum Ende der Zeilen durchlaufen. Aber wie gesagt: _FileReadToArray.
Insgesamt fehlt auch die Fehlerbehandlung. Was ist, wenn die Datei nicht existiert?

**AspirinJunkie**

Zitat von Oscar

Eine Datei zeilenweise einzulesen (noch dazu ohne ein Handle zu benutzen) ist sehr langsam. _FileReadToArray und anschließend das Array zu durchsuchen ist erheblich schneller.

Ohne Handle mit Angabe der Zeilennummer ist FileReadLine tatsächlich langsam aber _FileReadToArray (sicher das du die mit Unterstrich meinst?) muss nicht auf jeden Fall die schnellere Lösung sein.
Besonders hier nicht, da ja nicht die Datei bis zum Ende durchgesucht werden muss.

@hajoh25
Mal hier ein Grundaufbau mit (korrekter Verwendung von) FileReadLine - allerdings ohne GUI:

AutoIt

$s_IniPath = "Test.ini"
$Input = "irgendwas"


$hFile = FileOpen($s_IniPath) ; Datei zum lesen öffnen
If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")


Do ; Endlosschleife
	$s_Line = FileReadLine($hFile)   ; die nächste Zeile lesen
	If @error Then ExitLoop ; Falls Dateiende erreicht ist


	If StringInStr($s_Line, $Input) Then  
		FileReadLine($hFile) ; Ein Dummy-FileReadline zum überspringen
		$s_Line = FileReadLine($hFile)
		If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")


		MsgBox(0, "Ergebnis", $s_Line) ; Die zweite Zeile darunter ausgeben
		ExitLoop
	EndIf
Until 0


; Datei wieder schließen
FileClose($hFile)

Alles anzeigen

**BugFix**

Es gibt auch die Option mit regulären Ausdrücken zu arbeiten. Bei großen Dateien kann das durchaus schneller gehen. Ich habe hier mal eine Bsp-Funktion erstellt, die für mehrfache Suchen konzipiert ist, den Text aber nur einmal lesen muss.

"test.txt"

Code

irgendwas
nochwas
was-anderes
suchwort
folgezeile_1
folgezeile_2
suche_2
usw
wieder-folgezeile_2

AutoIt

ConsoleWrite(_getIt('suchwort', 'test.txt') & @CRLF)
ConsoleWrite(_getIt('suche_2') & @CRLF)


Func _getIt($sSearch, $sPath='')
	Local Static $sRead = ''
	$sRead = $sPath <> '' ? FileRead($sPath) : $sRead
	If $sRead = '' Then Return SetError(1,0,0)
	Local $aMetaChar[] = ['\', '.', '^', ', '|', '[', '(', '{', '*', '+', '?', '#'] ; Metazeichen escapen
	For $i = 0 To UBound($aMetaChar) -1
		If StringInStr($sSearch, $aMetaChar[$i]) Then $sSearch = StringReplace($sSearch, $aMetaChar[$i], '\' & $aMetaChar[$i])
	Next
	Return StringRegExp($sRead, $sSearch & '\n[^\n]*\n([^\n]*)', 3)[0]
EndFunc

Alles anzeigen

EDIT: @Bernd oder @Gun-Food
Jungs, falls jemand zufällig hier liest.
BITTE bringt den Syntaxhighlighter in Ordnung - das ist doch eine Katastrophe.

hajoh25

Zitat von Kanashius

$eingabe=$input ist falsch. richtig wäre $eingabe=guictrlread($input). Ansonsten ließt du den handle des controls ein (oder die nummer). und code bitte in code tags ;), danke

Vielen Dank Kanashius, hat mir sehr geholfen und dieser Teil funktioniert jetzt super

hajoh25

Zitat von Oscar

Außerdem:
Die erste While...WEnd-Schleife ist überflüssig.
Eine Datei zeilenweise einzulesen (noch dazu ohne ein Handle zu benutzen) ist sehr langsam. _FileReadToArray und anschließend das Array zu durchsuchen ist erheblich schneller.

ist von der Syntax her falsch. Mal abgesehen davon, dass man das nicht extra einer/zwei Variablen zuweisen muss = FileReadLine($datei, $i + 2) würde auch gehen, aber die Schleife darf dann auch nicht bis zum Ende der Zeilen durchlaufen. Aber wie gesagt: _FileReadToArray.Insgesamt fehlt auch die Fehlerbehandlung. Was ist, wenn die Datei nicht existiert?

Danke, den Syntaxfehler habe ich erst gar nicht gesehen, habe ich jetzt aber verbessert und die erste Schleife auch entfernt

hajoh25

Zitat von AspirinJunkie
Ohne Handle mit Angabe der Zeilennummer ist FileReadLine tatsächlich langsam aber _FileReadToArray (sicher das du die mit Unterstrich meinst?) muss nicht auf jeden Fall die schnellere Lösung sein.Besonders hier nicht, da ja nicht die Datei bis zum Ende durchgesucht werden muss.

@hajoh25
Mal hier ein Grundaufbau mit (korrekter Verwendung von) FileReadLine - allerdings ohne GUI:
AutoIt
$s_IniPath = "Test.ini"
$Input = "irgendwas"


$hFile = FileOpen($s_IniPath) ; Datei zum lesen öffnen
If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")


Do ; Endlosschleife
	$s_Line = FileReadLine($hFile)   ; die nächste Zeile lesen
	If @error Then ExitLoop ; Falls Dateiende erreicht ist


	If StringInStr($s_Line, $Input) Then  
		FileReadLine($hFile) ; Ein Dummy-FileReadline zum überspringen
		$s_Line = FileReadLine($hFile)
		If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")


		MsgBox(0, "Ergebnis", $s_Line) ; Die zweite Zeile darunter ausgeben
		ExitLoop
	EndIf
Until 0


; Datei wieder schließen
FileClose($hFile)
Alles anzeigen

Danke, dein Grundaufbau hat mir sehr geholfen, mit dem Funktioniert es viel besser. Jedoch wird mir die zweite Zeile in der MsgBox angezeigt, allerdings wollte ich 2 Zeilen UNTER dem Suchbegriff und nicht die zweite Zeile. Wenn du mir ein weiteres mal helfen könntest, wäre ich dir serh dankbar

**AspirinJunkie**

Im Grunde sollte es zwei Zeilen unter dem Fund die Zeile zurückgeben.
Wie hast du denn das Skript angepasst?
Sonst könnte es eigentlich nur sein, das $Input schon in der ersten Zeile gefunden wird.

hajoh25

Also der jezige Code sieht so aus:

AutoIt: Testversion 2.0

#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>




$Form1 = GUICreate("Nummer suchen", 288, 130, 192, 124)
$Name = GUICtrlCreateLabel("Name", 16, 16, 48, 23)
GUICtrlSetFont(-1, 12, 800, 0, "Arial")
$Input = GUICtrlCreateInput("", 16, 40, 249, 28)
GUICtrlSetFont(-1, 12, 800, 0, "Arial Narrow")
$Button1 = GUICtrlCreateButton("Suchen", 16, 72, 81, 33)
GUICtrlSetFont(-1, 12, 800, 2, "Arial Narrow")
GUISetState(@SW_SHOW)




	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch


While 1
   $nMsg = GUIGetMsg()
   Switch $nMsg
   Case $GUI_EVENT_CLOSE
	  Exit
   case $Button1


   $datei = IniRead("C:\Users\Johannes\Desktop\caller.inf", "section2", "key", "NotFound")
   $eingabe = guictrlread($input)


$s_IniPath = "callers.inf"


$hFile = FileOpen($s_IniPath)
If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")
Do
	$s_Line = FileReadLine($hFile)
	If @error Then ExitLoop
	If StringInStr($s_Line, $Input) Then
		FileReadLine($hFile)
		$s_Line = FileReadLine($hFile)
		If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")
		MsgBox(0, "Ergebnis", $s_Line)
		ExitLoop
	EndIf
Until 0


FileClose($hFile)


   EndSwitch
WEnd

Alles anzeigen

**AspirinJunkie**

Du liest den Suchbegriff in die Variable $eingabe.
Im StringInStr wird diese aber nicht verwendet sondern $input.
Es wird also gar nicht mit deinem Suchbegriff gesucht.

Geändert:

AutoIt

#include <GUIConstantsEx.au3>


Global $s_IniPath = "C:\Users\Johannes\Desktop\caller.inf"


$Form1 = GUICreate("Nummer suchen", 288, 130, 192, 124)
$Name = GUICtrlCreateLabel("Name", 16, 16, 48, 23)
GUICtrlSetFont(-1, 12, 800, 0, "Arial")
$Input = GUICtrlCreateInput("", 16, 40, 249, 28)
GUICtrlSetFont(-1, 12, 800, 0, "Arial Narrow")
$Button1 = GUICtrlCreateButton("Suchen", 16, 72, 81, 33)
GUICtrlSetFont(-1, 12, 800, 2, "Arial Narrow")
GUISetState(@SW_SHOW)




While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			Exit
		Case $Button1
			$eingabe = GUICtrlRead($Input)


			$hFile = FileOpen($s_IniPath)
			If $hFile = -1 Then Exit MsgBox(48, "Fehler", "Konnte ini-Datei nicht öffnen")
			Do
				$s_Line = FileReadLine($hFile)
				If @error Then ExitLoop
				If StringInStr($s_Line, $eingabe) Then
					FileReadLine($hFile)
					$s_Line = FileReadLine($hFile)
					If @error Then Exit MsgBox(48, "Fehler", "Konnte keine zwei Zeilen darunter lesen")
					MsgBox(0, "Ergebnis", $s_Line)
					ExitLoop
				EndIf
			Until 0
			FileClose($hFile)
	EndSwitch
WEnd

Alles anzeigen

hajoh25

Okay danke, letzte kleine Frage: Wie ist die Variable, die den Namen in der .ini datei liest?
Danke im vorraus

SmileMan

Um die gefundene Line aus der Datei in Deiner GUI anzeigen zu lassen, musst Du noch ein zusätzlliches GUICtrlCreateLabel an die Stelle setzen, wo das Ergebnis angezeigt werden soll.

Bei der Suchfunktion kannst Du dann das Ergebnis mit GUICtrlSetData in das extra dafür erstellte Label schreiben.