ControlID ListViewItem

Fr34k.

Hi zusammen,

Kurze Frage. Ich generiere mir eine ListView. Füge Dynamisch (Lese ich aus einer Datenbank aus) etwa 100 Einträge dieser Liste hinzu.

Code

GuiCtrlCreateListViewItem($a& '|' & $b& '|' & $c& '|' & $d& '|' & $e  & '|' & $f& '|' & $g& '|' & 'Bitte warten..' & '|' & '', $idListview)

Das funktioniert auch. Jedoch möchte ich danach noch etwas errechnen was teilweise bis zu 5 Sekunden geht.
Nach diesen 5 Sekunden soll das 'Bitte Warten' "geupdated" werden. Nur wie mach ich das? Ich möchte die Tabelle bereits von anfang an anzeigen.

Daher wie kann ich auf ein einzelnes ListViewItem zugreifen?

Hoffe ihr könnt mir helfen.

Vielen Dank
Fr34k

**Schnuffel**

Hi Fr34k,

ich würde statt den Standard Funktionen auf _GuiCtrlListView - Funktionen ausweichen.
Da hast du die Möglichkeit Items direkt anzusprechen.

Fr34k.

Hi, könntest du mir sagen wie ich diese dann direkt anspreche? Habe es nun, so umgebaut dass die Liste korrekt generiert wird.

Folgende Fragen habe ich nun:

Wie spreche ich ein einzelnes Item nun an?// Habe ich herausgefunden. _GUICtrlListView_SetItemText
Ist es möglich den Hintergrund einer 'Zeile' / Spalte zu ändern?
Gibt es eine Funktion das ganze auf Klick zu sortieren?

Danke schon mal für die Hilfe

Fr34k

Gofel

Zu Punkt 3:

C

#include <GuiListView.au3>
#include <GUIConstantsEx.au3>
Opt("GUIOnEventMode", 1)


Global $GE_Main, $GE_Listview


_Gui()
GUISetState(@SW_SHOW, $GE_Main)


While 1
	Sleep(50)
WEnd




Func _Gui()
	$GE_Main = GUICreate("Sort", 800, 600, -1, -1)
	GUISetOnEvent($GUI_EVENT_CLOSE, "_Program_Exit")


	;Listview
	$GE_Listview = GUICtrlCreateListView("", 5, 5, 790, 590)




	;Spalten erstellen
	_GUICtrlListView_AddColumn($GE_Listview, "Name", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Typ", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Size", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Player", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Balance", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Difficulty", 100)
	_GUICtrlListView_AddColumn($GE_Listview, "Version", 100)


	;Test Array mit Werten füllen
	Local $Array[51][9]
	$Array[0][0] = 50


	For $i = 1 To $Array[0][0]
		$Array[$i][0] = "Name " & $i
		$Array[$i][1] = "Typ " & $i
		$Array[$i][2] = "Size " & $i
		$Array[$i][3] = "Player " & $i
		$Array[$i][4] = "Balance " & $i
		$Array[$i][5] = "Difficulty " & $i
		$Array[$i][6] = "Version " & $i
	Next


	;Listview füllen
	For $i = 1 To $Array[0][0]
		_GUICtrlListView_AddItem($GE_Listview, $Array[$i][0], 0)             ;Name
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][1], 1)   ;Typ
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][2], 2)   ;Size
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][3], 3)   ;Player
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][4], 4)   ;Balance
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][5], 5)   ;Difficulty
		_GUICtrlListView_AddSubItem($GE_Listview, $i -1, $Array[$i][6], 6)   ;Version
	Next


	;_RegisterSortCallBack
	_GUICtrlListView_RegisterSortCallBack($GE_Listview)
	GUICtrlSetOnEvent($GE_Listview, '_GE_Listview_Sort')
EndFunc






Func _GE_Listview_Sort() ;Listview sortieren
	_GUICtrlListView_SortItems($GE_Listview, GUICtrlGetState($GE_Listview))
EndFunc


Func _Program_Exit()
	Exit
EndFunc

Alles anzeigen