Firebird Query Result eingrenzen?

horphi

Hallo, ich habe eine Abrage auf eine Firebird Datenbank.

Problem dabei: das Ergebnis gibt alle Meta DAten mit. Die brauch ich aber nicht. Kann man das irgendwie unterdrücken?
Ich brauch nur die Eckigen Klammerwerte...

Code

<results><metadata><fields><name value="Title" alias="Title" type="5" size="255" scale="0" /></fields></metadata><data><row num="1" ><Title><![CDATA[Crew Member Windbreaker in schwarz]]></Title></row></data></results>

AutoIt

#include <Array.au3>
#include <String.au3>
#include <MsgBoxConstants.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <File.au3>
#include <GuiListView.au3>
#include <FireBird.au3>
#include <ImageSearch.au3>
#include <DesktopWidth.au3>
#include <DotNetIdentification.au3>
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StringConstants.au3>


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 625, 442, 192, 124)
$EAN = GUICtrlCreateInput("4250740300182", 32, 32, 233, 21)
$NAME = GUICtrlCreateInput("Name", 32, 80, 233, 21)
$Amount = GUICtrlCreateInput("Amount", 32, 128, 233, 21)
$Button1 = GUICtrlCreateButton("Search", 288, 32, 193, 49, $WS_GROUP)
GUICtrlSetFont(-1, 15, 400, 0, "MS Sans Serif")
$Button2 = GUICtrlCreateButton("Save", 288, 96, 193, 57, $WS_GROUP)
GUICtrlSetFont(-1, 15, 400, 0, "MS Sans Serif")
$List1 = GUICtrlCreateEdit("", 32, 176, 449, 227)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###




Global $h_fbDll = DllOpen(@ScriptDir & "\fbdll4vb20.dll")
Global $servername=@ComputerName
;~ Global $g_DBName="E:/Organisation/AUTOIT/Scripts/AuctionStudio1.fdb"
Global $g_DBName="C:/Program Files (x86)/Auction Studio/Data/AuctionStudio.fdb"
Global $i1 = 0
Global $g_idMemo


;~ _FireBird_About($h_fbDll)
;~ _FireBird_Help($h_fbDll)
;~ MsgBox(0, "Execute Firesird_SetDebug Function.", _FireBird_SetDebug($h_fbDll,True))


While True
$nMsg = GUIGetMsg()
   Switch $nMsg
	  Case $GUI_EVENT_CLOSE
	    Exit
	  Case $Button1
		 SearchItem()
 EndSwitch
WEnd








Func TestSelect($h_fbDll,$sServerName,$sDBName)
Local $rv, $rcount, $result, $xmldoc
$rv = _FireBird_ConnectDatabase($h_fbDll,$sServerName,$sDBName, "SYSDBA", "masterkey")
If $rv Then
Local $isEAN = GUICtrlRead($EAN)
$rcount = _FireBird_ExecuteSelect($h_fbDll,"SELECT Distinct ""Title"" FROM ""StockItem"" Where ""EAN"" like '%" & $isEAN & "%'", $result)
EndIf


_FireBird_DisConnectDatabase($h_fbDll)


ConsoleWrite ($result)
GUICtrlSetData ($List1,$result)


EndFunc


Func SearchItem()
TestSelect($h_fbDll, $servername, $g_DBName)


;~ DllClose($h_fbDll)
;~ Exit




EndFunc

Alles anzeigen

Danke und Gruß,

horphi

**BugFix**

Verwende doch zum Abfragen ADODB. Nutze ich immer für Firebird. Hier ein Bsp. von mir, kannst es für dich anpassen.

AutoIt

#include<array.au3>


#region - Allgemeine Deklaration
Global $oMyError = ObjEvent("AutoIt.Error","MyErrFunc")    ; Initialisieren COM error handler
#endregion


#region - Database Deklaration (im Bsp. Firebird)
; Datenbank:
Global $data_source   = "C:/Daten/Muster.GDB"


; Verbindungsstring:
Global $strConnection = "DRIVER=Firebird/InterBase(r) driver; UID=SYSDBA; PWD=masterkey; DBNAME=" & $data_source & ";"


; SQL-String zum Auslesen aller Usertabellen mit Angabe aller Felder und Typ:
Global $sql_str = "SELECT RDB$RELATION_NAME, RDB$FIELD_NAME, RDB$FIELD_SOURCE " & _
				  "FROM   RDB$RELATION_FIELDS " & _
				  "WHERE  RDB$RELATION_NAME NOT CONTAINING ' " & _
				  "ORDER  BY RDB$RELATION_NAME, RDB$FIELD_NAME;"


		$sql_str = "Select NM_KVNR from Kunden where kundennr = 10008;"


Global $array
#endregion - Database


#region - Beispielsprogramm
; DB-Verbindungsobjekt wird erstellt:
$oConn = _oSQLDB_Connect($strConnection)
If @error Then Exit MsgBox(0, 'Datenbank', 'keine Verbindung')


; Ausführung eines SQL-Statements mit Methode Execute ==> liefert Recordset zurück:
$oRecSet = _oSQLDB_Execute($oConn, $sql_str)
If @error Then
	MsgBox(0, 'Execute', 'Fehler Beim Ausführen des SQL-Statements')
	_close()
EndIf


; Recordset in Array wandeln:
$array = $oRecSet.GetRows
If Not IsArray($array) Then
	MsgBox(0, 'Array', 'kein Ergebnis')
	_close()
EndIf


MsgBox(0, 'KV-Nr', $array[0][0])
;~ _ArrayDisplay($array, 'Alle User Tabellen')  ;[i][0]=Tabelle, [i][1]=Feld, [i][2]=Typ-Länge
_close()


Func _close()
	If IsObj($oRecSet) Then _oRecSet_Close($oRecSet)
	If IsObj($oConn) Then _oSQLDB_Close($oConn)
	Exit
EndFunc
#endregion - Beispielsprogramm


#region - Functions
;===============================================================================
; Function Name:   _oSQLDB_Connect($connStr)
; Description::    erstellt eine Objektreferenz auf die im $connStr angegebene Datenbank
; Parameter(s):    $connStr  Connection-String enthält die Verbindungsparameter
; Return Value(s): Erfolg   Referenz des ADODB-Objektes
;                  Fehler   1, @error 1
;===============================================================================
Func _oSQLDB_Connect($connStr)
	Local $objConnection = ObjCreate("ADODB.Connection")
	If Not IsObj($objConnection) Then Return SetError(1,0,1)
	$objConnection.Open($connStr)
	Return $objConnection
EndFunc  ;==>_oSQLDB_Connect


;===============================================================================
; Function Name:   _oSQLDB_Execute($oConn, $strCommand, $Options=-1)
; Description::    führt Kommandostring (SQL-Sequenz) aus
; Parameter(s):    $oConn      Referenz des Connection-Objektes
;                  $strCommand Kommandostring
;     optional     $Options    CommandTypeEnum   (http://msdn.microsoft.com/en-us/library/ms675946(VS.85).aspx) oder
;                              ExecuteOptionEnum (http://msdn.microsoft.com/en-us/library/ms676517(VS.85).aspx)
; Return Value(s): Eine Recordset Objekt-Referenz, ein Stream oder Nichts
;===============================================================================
Func _oSQLDB_Execute($oConn, $strCommand, $Options=-1)
	Local $recAffected
	Return $oConn.Execute($strCommand, $recAffected, $Options)
EndFunc  ;==>_oSQLDB_Execute


;===============================================================================
; Function Name:   _oRecSet_Close($oRecSet)
; Description::    Beendet ein RecordsetObjekt
; Parameter(s):    $oRecSet  Referenz des Objektes
;===============================================================================
Func _oRecSet_Close($oRecSet)
	$oRecSet.Close
EndFunc  ;==>_oRecSet_Close


;===============================================================================
; Function Name:   _oSQLDB_Close($oConn)
; Description::    Beendet die Verbindung
; Parameter(s):    $oConn  Referenz des Connection-Objektes
;===============================================================================
Func _oSQLDB_Close($oConn)
	$oConn.Close
EndFunc  ;==>_oSQLDB_Close


Func MyErrFunc()
  Msgbox(0,"AutoItCOM Test","Ein COM-Fehler ist aufgetreten !"  & @CRLF  & @CRLF & _
             "err.description is: "    & @TAB & $oMyError.description    & @CRLF & _
             "err.windescription:"     & @TAB & $oMyError.windescription & @CRLF & _
             "err.number is: "         & @TAB & hex($oMyError.number,8)  & @CRLF & _
             "err.lastdllerror is: "   & @TAB & $oMyError.lastdllerror   & @CRLF & _
             "err.scriptline is: "     & @TAB & $oMyError.scriptline     & @CRLF & _
             "err.source is: "         & @TAB & $oMyError.source         & @CRLF & _
             "err.helpfile is: "       & @TAB & $oMyError.helpfile       & @CRLF & _
             "err.helpcontext is: "    & @TAB & $oMyError.helpcontext )
    Local $err = $oMyError.number
    If $err = 0 Then $err = -1
    Local $g_eventerror = $err
Endfunc
#endregion - Functions

Alles anzeigen

horphi

Hallo BugFix,

PERFEKT!!!

So geht´s also auch....

Vielen Dank. DAs erleichtert es erheblich.

VG

horphi

horphi

Mal ne andere Frage.

Ich habe zum Test nur ein Feld was ich auslese.

Nun möchte ich mehrere Felder nehmen, bekomme aber immer einen Fehler, dass die Abfrage so nicht funktioniert....:-(

Ich bin mit den Hochkomma ein bisschen irritiert...

So funktionierts....

AutoIt

Global	$sql_str = "SELECT Distinct ""RefCode"" FROM ""StockItem"" Where ""EAN"" like '%" & $isEAN & "%';"

So nicht...

AutoIt

Global	$sql_str = "SELECT Distinct ""RefCode,Title"" FROM ""StockItem"" Where ""EAN"" like '%" & $isEAN & "%';"

AutoIt

Global	$sql_str = "SELECT Distinct ""RefCode", "Title"" FROM ""StockItem"" Where ""EAN"" like '%" & $isEAN & "%';"

DAnke und Gruß,

horphi

**Kanashius**

Code

Global	$sql_str = "SELECT Distinct ""RefCode"", ""Title"" FROM ""StockItem"" Where ""EAN"" like '%" & $isEAN & "%';"

Du hast die inneren doppelten Anführungszeichen vergessen

horphi

Zitat von Kanashius

Du hast die inneren doppelten Anführungszeichen vergessen

Vielen Dank.