GUI Switch Case bei Mausklick via _GUICtrlListView_GetSelectionMark

horphi

Hallo zusammen,

ich möchte gerne _GUICtrlListView_GetSelectionMark als Case im Switch GUI benutzen, um eine Aktion direkt nach Klick in der Liste auszuführen.

Die selektierte Zeile soll direkt übergeben werden...

Geht sowas?

AutoIt

#include <ComboConstants.au3>
#include <GUIListBox.au3>
#include <StringConstants.au3>
#include <AutoItConstants.au3>
#include <ListViewConstants.au3>


$iSelectListItem = _GUICtrlListView_GetSelectionMark ($List1) ;gibt die selektierte Zeile wieder


While True
$nMsg = GUIGetMsg()
   Switch $nMsg
	  Case $GUI_EVENT_CLOSE
	    Exit
	  Case $iSelectListItem = 1
            Aktion()
   EndSwitch
WEnd

Alles anzeigen

VG
horphi

**Kanashius**

Sieh dir mal die Beispiele in der Hilfe zu _GUICtrlListView_Create durch. dort steht alles, was du brauchst.
Hier ist die wichtigste Funktion aus dem Beispiel kopiert.
Das ist eine Eventfunktion, die Registriert wird und dann bei klicks,... automatisch aufgerufen wird

AutoIt

Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo
    ; Local $tBuffer
    $hWndListView = $g_hListView
    If Not IsHWnd($g_hListView) Then $hWndListView = GUICtrlGetHandle($g_hListView)


    $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                    $tInfo = DllStructCreate($tagNMITEMACTIVATE, $lParam)
                    _DebugPrint("$NM_CLICK" & @CRLF & "--> hWndFrom:" & @TAB & $hWndFrom & @CRLF & _
                            "-->IDFrom:" & @TAB & $iIDFrom & @CRLF & _
                            "-->Code:" & @TAB & $iCode & @CRLF & _
                            "-->Index:" & @TAB & DllStructGetData($tInfo, "Index") & @CRLF & _
                            "-->SubItem:" & @TAB & DllStructGetData($tInfo, "SubItem") & @CRLF & _
                            "-->NewState:" & @TAB & DllStructGetData($tInfo, "NewState") & @CRLF & _
                            "-->OldState:" & @TAB & DllStructGetData($tInfo, "OldState") & @CRLF & _
                            "-->Changed:" & @TAB & DllStructGetData($tInfo, "Changed") & @CRLF & _
                            "-->ActionX:" & @TAB & DllStructGetData($tInfo, "ActionX") & @CRLF & _
                            "-->ActionY:" & @TAB & DllStructGetData($tInfo, "ActionY") & @CRLF & _
                            "-->lParam:" & @TAB & DllStructGetData($tInfo, "lParam") & @CRLF & _
                            "-->KeyFlags:" & @TAB & DllStructGetData($tInfo, "KeyFlags"))
                    ; No return value
 EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

horphi

Hallo Kanashius,

vielen Dank.

Das ist es.

Hab es grob schon überblickt und verstanden.

Werd das jetzt mal ins Script einbauen. Mit der DLL Thematik bin ich ja noch nicht so vertraut...

VG

horphi

**Kanashius**

Den Dll kram brauchst du eigentlich auch nicht. Kannst einfach beim Klick nachsehen, was markiert ist ^^.
Die ganzen Infos, die dir da ausgegeben werden braucht man meistens nicht.

**Oscar**

Hier mal ein Beispiel, wie das im OnEventMode ganz ohne WM_NOTIFY funktioniert:

AutoIt

#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>


Opt('GUIOnEventMode', 1)


$hGui = GUICreate('Test', 320, 300)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')


$idListview = GUICtrlCreateListView('col 1|col 2|col 3', 10, 10, 300, 280, $LVS_SHOWSELALWAYS)
For $i = 0 To 9
	$sItem = Random(1, 9, 1) & '|' & Random(1, 9, 1) & '|' & Random(1, 9, 1)
	GUICtrlCreateListViewItem($sItem, $idListview)
	GUICtrlSetOnEvent(-1, '_ClickListView')
Next
GUISetState(@SW_SHOW)


WinWaitClose($hGui)
Exit


Func _CloseGui()
	GUIDelete($hGui)
EndFunc   ;==>_CloseGui


Func _ClickListView()
	; Single-Select
	Local $sText = GUICtrlRead(@GUI_CtrlId)
	ConsoleWrite($sText & @CR)


	; Multi-Select
	Local $sSelected = ControlListView($hGui, '', $idListview, 'GetSelected', 1)
	If $sSelected = '' Then Return
	Local $aSelectedIndices = StringSplit($sSelected, '|', 2)
	Local $aSelectedText[UBound($aSelectedIndices)]
	For $i = 0 To UBound($aSelectedIndices) - 1
		For $j = 0 To 2
			$aSelectedText[$i] &= ControlListView($hGui, '', $idListview, 'GetText', $aSelectedIndices[$i], $j) & '|'
		Next
		$aSelectedText[$i] = StringTrimRight($aSelectedText[$i], 1)
	Next
	_ArrayDisplay($aSelectedText)
EndFunc   ;==>_ClickListView

Alles anzeigen

horphi

Zitat von Oscar

Hier mal ein Beispiel, wie das im OnEventMode ganz ohne WM_NOTIFY funktioniert:

Hallo Oscar,

das ist ja auch mal genial einfach....:-)

Vielen Dank.

2 super funktionierende Methoden.

Vielen Dank