Dateien umbenennen

jmewald

Hallo zusammen,

ich habe mir ein kleines Script gebastelt, welches mir Dateinamen in einem Ordner umbenennt. Das funktioniert auch bestens, jedoch stehe ich jetzt vor einer Sache wo ich nicht genau weiß was ich anpassen muss. Vielleicht kann mir jemand kurz helfen.

Hier mal mein Script:
$search = FileFindFirstFile("*.jpg") ; vielleicht auch "*.jpg" ?

; Check if the search was successful
If $search = -1 Then
MsgBox(0, "Error", "Es existieren keine Dateien")
Exit
EndIf

While 1
$file = FileFindNextFile($search)
If @error Then ExitLoop

FileMove($file,StringReplace(StringReplace($file,"-"," "),"\\"," "))
;FileMove($file,StringReplace(StringReplace($file,"ß","ss")))
WEnd
FileClose($search)

Ich möchte nun folgendes erreichen:
Ich habe in einem Ordner z.B. folgende Dateien:
50000 Bild21 FW2015.jpg
50000 Bild22 FW2015.jpg
85001 Bild11 FW2015.jpg
85001 Bild12 FW2015.jpg

und davon hunderte.

Mein Ergebnis soll nun so aussehen:
50000.jpg
50000b.jpg
85001.jpg
85001b.jpg

D.h. ich würde gerne alles außer der fünfstelligen Zahl löschen wollen und wenn es doppelte gibt, das zweite File natürlich anders benennen. Ob ein "b" oder was auch immer ist egal, Hauptsache es heisst anders.

Hat jemand eine Idee wie ich mein Script anpassen müsste?

Herzlichen Dank

Gruß

Yaerox

Quellcode das nächste mal bitte in ein Code-Tag packen bitte

Wenn es immer 5-stellige Zahlen sind, kannst du einfach ein StringMid( $sString, 1, 5 ) machen. Dann jede Zahl die du ermittelt hast in ein Array "pushen" und vorher natürlich immer fragen ob es bereits einen Eintrag mit selber Nummer gibt, wenn ja irgendwas anhängen und push. Zum Schluss Array auslesen und ausgabe produzieren.

Update:

AutoIt: ungetestet

Local $aArray, $file, $dest, $i, $counter
Local $search = FileFindFirstFile("*.jpg") ; vielleicht auch "*.jpg" ?


; Check if the search was successful
If $search = -1 Then
	MsgBox(0, "Error", "Es existieren keine Dateien")
	Exit
EndIf


$i = 0
$counter = 1
While 1
	$file = FileFindNextFile($search)
	If @error Then ExitLoop


	$dest = StringMid( $file, 1, 5 )
	If $i <> 0 Then
		For $y = 0 To UBound($aArray) - 1 Step 1
			If $dest = $aArray[$y] Then
				$counter++
				$dest = $dest & $counter
			EndIf
		Next
	EndIf
	_ArrayAdd( $aArray, $dest )


	FileMove($file,$dest & ".jpg")
	;FileMove($file,StringReplace(StringReplace($file,"ß","ss")))
WEnd
FileClose($search)

Alles anzeigen

jmewald

Hallo Yaerox,

vielen Dank für deine Hilfe.
meine Autoit Kenntnisse sind leider ein wenig eingerostet. Hab mich lange damit nicht mehr beschäftigt.
Meinst du du könntest meinen Code kurz anpassen?

Vielen vielen Dank.

jmewald

Sorry, bin blind

Gruß und Danke

**Oscar**

Yaerox: Was soll das für ein Script sein?
If $i <> 0 Then... das tritt in Deinem Script nie ein.
$counter++ ist keine gültige AutoIt-Syntax.

@jmewald: versuch's mal hiermit:

AutoIt

#include <Array.au3>
#include <File.au3>


Global $sSourcePath = @ScriptDir ; <- Quellverzeichnis (evtl. anpassen)
If StringRight($sSourcePath, 1) <> '\' Then $sSourcePath &= '\'


Global $sDestPath = @ScriptDir ; <- Zielverzeichnis (evtl. anpassen)
If StringRight($sDestPath, 1) <> '\' Then $sDestPath &= '\'


Global $aFiles = _FileListToArray($sSourcePath, '*.jpg', $FLTA_FILES, False)
If @error Or $aFiles[0] = 0 Then Exit MsgBox(0, 'Fehler', 'Keine JPG-Dateien im Verzeichnis!')


_ArrayDisplay($aFiles)


Global $sDestFile = ''
For $i = 1 To $aFiles[0]
	$sDestFile = StringLeft($aFiles[$i], 5) & '.jpg'
	$sDestFile = $sDestPath & $sDestFile
	$sDestFile = _GetUniqueFileName($sDestFile)
	If Not @error Then FileMove($sSourcePath & $aFiles[$i], $sDestFile)
Next


;===============================================================================
; Function Name:   _GetUniqueFileName($sPath)
; Description::    Wenn der Dateiname bereits existiert wird ein Zähler
;                  in Form von: "_(1)" an den Dateinamen angehängt.
; Parameter(s):    $sPath = kompletter Pfad der Datei
; Requirement(s):  -
; Return Value(s): bei Erfolg = der (neue) Dateiname
;                  bei Fehler wird @error = 1 (Pfad falsch angegeben)
; Author(s):       Oscar (www.autoit.de)
;===============================================================================
Func _GetUniqueFileName($sPath)
	Local $aPath, $sNumber = '', $iCount = 0
	$aPath = StringRegExp($sPath, '(.+\\)(.+?)(?:_\(\d*\))*(\..+)', 3)
	If @error Then Return SetError(1, 0, 0)
	While FileExists($aPath[0] & $aPath[1] & $sNumber & $aPath[2])
		$iCount += 1
		$sNumber = '_(' & $iCount & ')'
	WEnd
	Return $aPath[0] & $aPath[1] & $sNumber & $aPath[2]
EndFunc   ;==>_GetUniqueFileName

Alles anzeigen