MouseWheel auswerten

**Oscar**

Nachdem ich bei meiner Suche nach dem auswerten des Mausrades etliche Scripte gefunden habe, die das per Callback lösen, musste ich jetzt feststellen, dass das viel einfacher geht.
Man kann einfach $WM_MOUSEWHEEL per GuiRegisterMsg registrieren und bekommt dann alle wichtigen Informationen.
Hier ist mal ein kleines Beispiel-Script:

AutoIt

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Global $iCount = 1000
Global $hGui = GUICreate('MouseWheel', 320, 240)
Global $idCounter = GUICtrlCreateLabel($iCount, 80, 20, 160, 40, $SS_RIGHT, $WS_EX_STATICEDGE)
GUICtrlSetFont(-1, 28, 800, 0, 'Courier New')
GUICtrlSetBkColor(-1, 0xDDDDDD)
GUISetState(@SW_SHOW, $hGui)
GUIRegisterMsg($WM_MOUSEWHEEL, '_WM_MOUSEWHEEL')
Do
Until GUIGetMsg() = -3
Exit


Func _WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
	Local $iWheel = _WinAPI_HiWord($wParam) / 120 ; down = -1, up = 1
	Local $aGuiInfo = GUIGetCursorInfo($hGui), $iStep = 5
	If $aGuiInfo[4] = $idCounter Then $iCount += $iWheel * $iStep
	GUICtrlSetData($idCounter, $iCount)
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Das zählt den Counter rauf/runter, wenn man sich mit der Maus über dem Counterfeld befindet und das Mausrad dreht.

Edit: Noch ein Nachtrag, weil mir das gerade erst aufgefallen ist. Wenn es noch andere Control-Elemente auf der GUI gibt, die ebenfalls ein scrollen mit dem Mausrad ermöglichen (z.B. Listviews), dann reicht das obige Beispiel nicht aus. Man muss dann dafür sorgen, dass das Label den Focus bekommt. Das geht ganz gut, indem man die Mausbewegung auswertet und dann dem Control-Element unter der Maus den Focus zuweist:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <StaticConstants.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>


Global $iCount = 1000
Global $hGui = GUICreate('MouseWheel', 320, 240)
Global $idCounter = GUICtrlCreateLabel($iCount, 80, 20, 160, 40, $SS_RIGHT, $WS_EX_STATICEDGE)
GUICtrlSetFont(-1, 28, 800, 0, 'Courier New')
GUICtrlSetBkColor(-1, 0xDDDDDD)
Global $idList = GUICtrlCreateListView('col1|col2|col3', 10, 70, 300, 150)
_GUICtrlListView_SetColumnWidth($idList, 0, 200)
_GUICtrlListView_SetColumnWidth($idList, 1, 200)
_GUICtrlListView_SetColumnWidth($idList, 2, 200)
GUISetState(@SW_SHOW, $hGui)
GUIRegisterMsg($WM_MOUSEWHEEL, '_WM_MOUSEWHEEL')
While True
	Switch GUIGetMsg()
		Case $GUI_EVENT_MOUSEMOVE
			$aGuiInfo = GUIGetCursorInfo($hGui)
			GUICtrlSetState($aGuiInfo[4], $GUI_FOCUS)
		Case $GUI_EVENT_CLOSE
			Exit
	EndSwitch
WEnd


Func _WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
	Local $iWheel = _WinAPI_HiWord($wParam) / 120 ; down = -1, up = 1
	Local $aGuiInfo = GUIGetCursorInfo($hGui), $iStep = 5
	If $aGuiInfo[4] = $idCounter Then
		$iCount += $iWheel * $iStep
		GUICtrlSetData($idCounter, $iCount)
	EndIf
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

**autoiter**

Coole Info Oscar. Vielen Dank!

**Oscar**

Ich habe oben noch einen Nachtrag hinzugefügt.

**autoiter**

TJF

Hallo,

ich bin ja dank Oscar auf die Lösung mit dem Focus hier gekommen. Allerdings ergibt sich trotzdem noch ein spezielles Problem i.V.m. Listview und der hier eingesetzten Child-Gui. Ich habe das mal hier auf das Grundproblem reduziert skizziert. Anliegend die GuiScroll.au3 und der Quelltext.

Spoiler anzeigen

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
#include <ListViewConstants.au3>
#include <SendMessage.au3>
#include "GuiScroll.au3"    ; -> http://autoit.de/index.php?page=Thread&postID=162464#post162464

HotKeySet("{ESC}", "Terminate")

startGui()

Func startGui()
    $Gui = GUICreate("",700,600,-1,-1,$WS_POPUP)
    $up = GUICtrlCreateButton("UP",10,10,80,40)
    $down = GUICtrlCreateButton("DOWN",100,10,80,40)
    GUICtrlCreateLabel("Schliessen mit ESC", 550, 10, 120,40)
    GUIRegisterMsg($WM_MOUSEWHEEL, "_Scrollbars_WM_MOUSEWHEEL")
    $hScrollPl = GUICreate("$hScrollPl",500,400,10,100,BitOR($WS_POPUP,$WS_GROUP,$WM_VSCROLL,$WS_CLIPSIBLINGS),$WS_EX_MDICHILD,$Gui)
    GUISetBkColor(0xffffff)
    Scrollbar_Create($hScrollPl, $SB_VERT, 400)
    Scrollbar_Step(10, $hScrollPl, $SB_VERT)
    _GUIScrollBars_SetScrollInfoMax($hScrollPl, $SB_VERT, 500)

    $art = GUICtrlCreateLabel("", 1, 1) ; Label für folgenden Focus...

    $hListV = GUICtrlCreateListView("1|2", 100, 100, 300, 200, BitOR($LVS_REPORT, $LVS_NOCOLUMNHEADER, $LVS_SHOWSELALWAYS))
    GUISetState(@SW_SHOW, $Gui)
    GUISetState(@SW_SHOW, $hScrollPl)
    GUICtrlSetState($art, $GUI_FOCUS); Focus auf Label von $hScrollPl
    GUISwitch($Gui)
    ;GUISetState(@SW_SHOW, $Gui)
    While 1
        $iMsg3 = GUIGetMsg()
        $aCursorInfo = GUIGetCursorInfo()
        Switch $iMsg3
            Case $iMsg3 = $aCursorInfo
                Select
                    Case $aCursorInfo[2] And $aCursorInfo[4] = $up
                        MsgBox(0,"Info", "Button up gedrückt")
                    Case $aCursorInfo[2] And $aCursorInfo[4] = $down
                        MsgBox(0,"Info", "Button down gedrückt")
                    Case Else
                        ;GUICtrlSetState($art, $GUI_FOCUS)
                EndSelect
        EndSwitch
    WEnd
    GUIRegisterMsg($WM_MOUSEWHEEL, "")
EndFunc ; ==> startGui()

Func _Scrollbars_WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Local $i,$iDirn, $iDelta = BitShift($wParam, 16) ; Mouse wheel movement

    If BitAND($wParam, 0x0000FFFF) Then ; If Ctrl or Shft pressed move Horz scrollbar
        $iDirn = $SB_LINERIGHT
        If $iDelta > 0 Then $iDirn = $SB_LINELEFT
        For $i = 1 To 7
            _SendMessage($hWnd, $WM_HSCROLL, $iDirn)
        Next
    Else ; Move Vert scrollbar
        $iDirn = $SB_LINEDOWN
        If $iDelta > 0 Then $iDirn = $SB_LINEUP
        for $i = 1 to 7 ; Schleife regelt die Scroll Geschwindigkeit, je mehr Durchläufe desto schneller
            _SendMessage($hWnd, $WM_VSCROLL, $iDirn)
        Next

    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_Scrollbars_WM_MOUSEWHEEL

Func Terminate()
    Exit
EndFunc

Alles anzeigen

Folgendes tritt hier auf:

Im Bereich der weissen Child-Gui kann mit der Maus gescrollt werden wegen dem Focus drauf. Klickt man auf einen der beiden Buttons oben, muss man erst wieder innerhalb des Child-Bereiches (außerhalb des Listview-Rahmens) klicken, damit das wieder geht danach (logisch). Die auskommentierte Zeile unten im "Case Else" würde das automatisch machen. Ist die Zeile aktiv, kann man durch Klick in den Parent-Bereich die Sache wieder aktiv machen. Eine zweite Zeile, die z.B. zuerst den Focus auf den Parent-Bereich legt, hilft aber auch nicht.

Klickt man nun innerhalb des Listview-Rahmens ist der Focus nicht zurückholbar - ausser man klickt erst wieder auf einen Button innerhalb. Wie könnte man das hinbekommen, dass der Focus zwischen beiden automatisch wechselt in dieser Konstellation mit dieser GUIGetCursorInfo-Schleife?

Dank und Gruß Thomas

**Oscar**

Du musst den Focus jedes Mal auf den zu scollenden Bereich legen:

Spoiler anzeigen

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <GUIScrollBars.au3>
#include <ScrollBarConstants.au3>
#include <ListViewConstants.au3>
#include <SendMessage.au3>
#include "GuiScroll.au3" ; -> http://autoit.de/index.php?page=Thread&postID=162464#post162464

startGui()

Func startGui()
    $Gui = GUICreate("", 700, 600, -1, -1, $WS_POPUP)
    $up = GUICtrlCreateButton("UP", 10, 10, 80, 40)
    $down = GUICtrlCreateButton("DOWN", 100, 10, 80, 40)
    GUICtrlCreateLabel("Schliessen mit ESC", 550, 10, 120, 40)
    GUIRegisterMsg($WM_MOUSEWHEEL, "_Scrollbars_WM_MOUSEWHEEL")
    $hScrollPl = GUICreate("$hScrollPl", 500, 400, 10, 100, BitOR($WS_POPUP, $WS_GROUP, $WM_VSCROLL, $WS_CLIPSIBLINGS), $WS_EX_MDICHILD, $Gui)
    GUISetBkColor(0xffffff)
    Scrollbar_Create($hScrollPl, $SB_VERT, 400)
    Scrollbar_Step(10, $hScrollPl, $SB_VERT)
    _GUIScrollBars_SetScrollInfoMax($hScrollPl, $SB_VERT, 500)

    $art = GUICtrlCreateLabel("", 1, 1) ; Label für folgenden Focus...

    $hListV = GUICtrlCreateListView("1|2", 100, 100, 300, 200, BitOR($LVS_REPORT, $LVS_NOCOLUMNHEADER, $LVS_SHOWSELALWAYS))
    GUISetState(@SW_SHOW, $Gui)
    GUISetState(@SW_SHOW, $hScrollPl)
    GUICtrlSetState($art, $GUI_FOCUS); Focus auf Label von $hScrollPl
    GUISwitch($Gui)
    ;GUISetState(@SW_SHOW, $Gui)
    While 1
        $iMsg3 = GUIGetMsg()
        Switch $iMsg3
            Case $GUI_EVENT_CLOSE
                Exit
            Case $up
                MsgBox(0, "Info", "Button up gedrückt")
                GUICtrlSetState($art, $GUI_FOCUS); Focus auf Label von $hScrollPl
            Case $down
                MsgBox(0, "Info", "Button down gedrückt")
                GUICtrlSetState($art, $GUI_FOCUS); Focus auf Label von $hScrollPl
        EndSwitch
    WEnd
EndFunc   ;==>startGui

Func _Scrollbars_WM_MOUSEWHEEL($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $lParam
    Local $i, $iDirn, $iDelta = BitShift($wParam, 16) ; Mouse wheel movement

    If BitAND($wParam, 0x0000FFFF) Then ; If Ctrl or Shft pressed move Horz scrollbar
        $iDirn = $SB_LINERIGHT
        If $iDelta > 0 Then $iDirn = $SB_LINELEFT
        For $i = 1 To 7
            _SendMessage($hWnd, $WM_HSCROLL, $iDirn)
        Next
    Else ; Move Vert scrollbar
        $iDirn = $SB_LINEDOWN
        If $iDelta > 0 Then $iDirn = $SB_LINEUP
        For $i = 1 To 7 ; Schleife regelt die Scroll Geschwindigkeit, je mehr Durchläufe desto schneller
            _SendMessage($hWnd, $WM_VSCROLL, $iDirn)
        Next

    EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_Scrollbars_WM_MOUSEWHEEL

Alles anzeigen

TJF

Tausend Dank Oscar!