Label-Text ausgeben -> Kontextmenü

svart

Hallo,

wie kann ich den Label-Text ausgeben, wenn ich per Kontext-Menü auf "TEST" klicke? (siehe Beispiel:)

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Opt("GUIOnEventMode", 1)
$MainGUI = GUICreate("", 250, 250)
$Button  = GUICTRLCreateButton("TEST",20,220,100,20)
GUISetState(@SW_SHOW)


GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")


$arLabels=_CreateLabel()


While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit
		Case $button


	EndSwitch
WEnd


Func _CreateLabel()
	local $Array[10]
	for $i = 0 to UBound($Array)-1 step 1
		$Array[$i]=GUICTRLCreateLabel("Test" & $i, 20,20*$i,200,15)
			GUICtrlSetBkColor(-1,0x0B610B)
			$context 	= GUICtrlCreateContextMenu($Array[$i])
			$context_test 	= GUICtrlCreateMenuItem("TEST",$context)
					  GUICtrlSetOnEvent(-1, "_TEST")
	Next
	return $Array
EndFunc


func _Exit()
	Exit
EndFunc


func _Test()
	msgbox(0,"","TEXT?!")
EndFunc

Alles anzeigen

**BugFix**

Zitat von svart

wenn ich per Kontext-Menü auf "TEST" klicke?

Du hast aber kein Kontextmenü erstellt

**Kanashius**

AutoIt

Case $button
			msgbox(48,"",GuiCtrlRead($arLabels[0]))
	EndSwitch

Das ist glaub ich was du willst, soll es ein anderes Label sein musst du die 0 erhöhen.
Du solltest dir wirklich Arrays ansehen, sonst kommen hier ständig solche fragen^^

MfG Kanashius

**Oscar**

Man kann nicht den OnEventMode und den MsgLoopMode gleichzeitig benutzen!
Es geht zwar wechselweise, aber nicht gleichzeitig!
Außerdem erstellst Du für jedes Label ein ContextMenu, benutzt dafür aber immer die gleiche Variable. Wenn Du wirklich für jedes Label ein eigenes ContextMenu brauchst, dann musst Du auch dafür ein Array verwenden.
Du kannst natürlich auch nur ein ContextMenu für die ganze Gui erstellen, und benutzt dann in der EventFunktion @GUI_CtrlID für die Auswahl.
Aber woher sollen wir wissen, was Du vorhast?

svart

Zitat von Oscar

Man kann nicht den OnEventMode und den MsgLoopMode gleichzeitig benutzen!
Es geht zwar wechselweise, aber nicht gleichzeitig!

Das weiß ich, hatte nur mit Koda ein GUI erstellt und vergessen den Part zu löschen, aber darum gings ja in dem Beispiel nicht.

Zitat von Oscar

Du kannst natürlich auch nur ein ContextMenu für die ganze Gui erstellen, und benutzt dann in der EventFunktion @GUI_CtrlID für die Auswahl.
Aber woher sollen wir wissen, was Du vorhast?

Mit @GUI_CtrlID würde ich doch dann die ID vom Kontextmenü-Punkt "TEST" erhalten?

Also wie bereits geschrieben möchte ich gerne den Text des Labels auf das ich klicke in der Funktion als variable haben.

**Oscar**

Es geht aber darum, dass Du kein lauffähiges Beispiel zur Verfügung stellst. Sollen wir jetzt erstmal ein Beispielscript erstellen?
Außerdem wissen wir gar nicht, was Du eigentlich willst.

Du schreibst, dass Du den Text des Label haben willst, auf das Du klickst. Wozu dann ein ContextMenü?
Label können direkt ein Event auslösen.
GuiCtrlSetOnEvent(-1, "LabelKlick") jedem Label zuweisen und in der Funktion "LabelKlick" dann mit GuiCtrlRead(@GUI_CtrlID) den Text des Labels auslesen.

svart

Zitat von Oscar

GuiCtrlSetOnEvent(-1, "LabelKlick") jedem Label zuweisen und in der Funktion "LabelKlick" dann mit GuiCtrlRead(@GUI_CtrlID) den Text des Labels auslesen.

-> das ist mir bewusst, wie in meinem Beispiel zu sehen ist möchte ich das aber nicht.

Zitat von Oscar

Du schreibst, dass Du den Text des Label haben willst, auf das Du klickst. Wozu dann ein ContextMenü?

-> weil ich möchte, dass ein Kontextmenü erscheint wenn ich mit der rechten Maustaste auf ein Label klicke, in den Funktionen die ich dann per Kontextmenü (mehrere Punkte) aufrufe, benötige ich dann den Labeltext.

Ich hoffe es ist jetzt verständlicher.

**BugFix**

Statt jedem Label ein Kontextmenü zuzuweisen, empfehle ich dir die folgende Variante.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Array.au3>


$MainGUI = GUICreate("", 250, 250)
$Button  = GUICTRLCreateButton("TEST",20,220,100,20)


$CmdGUI = GUICreate('', 200, 105, -1, -1, Default, $WS_EX_MDICHILD, $MainGUI)
$btCmd1 = GUICtrlCreateButton('Funktion A', 5, 5, 190, 20)
$btCmd2 = GUICtrlCreateButton('Funktion B', 5, 30, 190, 20)
$btCmd3 = GUICtrlCreateButton('Funktion C', 5, 55, 190, 20)
$btClose = GUICtrlCreateButton('Close', 5, 80, 190, 20)


GUISetState(@SW_SHOW, $MainGUI)


$arLabels=_CreateLabel()




While True
	$aMsg = GUIGetMsg(1)
	Switch $aMsg[1]
		Case $MainGUI
			Switch $aMsg[0]
				Case $GUI_EVENT_CLOSE
					Exit
				Case $GUI_EVENT_SECONDARYDOWN
					_secCklick((GUIGetCursorInfo($MainGUI))[4])
			EndSwitch
		Case $CmdGUI
			Switch $aMsg[0]
				Case $GUI_EVENT_CLOSE, $btClose
					GUISetState(@SW_HIDE, $CmdGUI)
				Case $btCmd1
					;
				Case $btCmd2
					;
				Case $btCmd3
					;
			EndSwitch
	EndSwitch
WEnd


Func _secCklick($iID)
	If _ArraySearch($arLabels, $iID) > -1 Then
		WinSetTitle($CmdGUI, '', ControlGetText($MainGUI, '', $iID))
		GUISetState(@SW_SHOW, $CmdGUI)
	EndIf
EndFunc


Func _CreateLabel()
	local $Array[10]
	for $i = 0 to UBound($Array)-1
		$Array[$i]=GUICTRLCreateLabel("Test" & $i, 20,20*$i,200,15)
		GUICtrlSetBkColor(-1,0x0B610B)
	Next
	return $Array
EndFunc

Alles anzeigen

Bei Rechtsklick auf ein Label rufst du eine zweite GUI auf und übergibst den Text des Labels (im Bsp. setze ich den Fensternamen damit). Dann kannst du weiterverfahren, wie bei einem Kontextmenü.

svart

Vielen Dank, das löst mein Problem.