schlafen mit sleep oder besser?

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

Ich arbeite an einem kleinem Programm das folgendes können soll:
1) wird im Autostart gestartet
2) laüft solange der Rechner läuft
3) "hängt" sozusagen nur im Systray
4) macht weitgehend nichts
5) wenn ein bestimmtes Ereignis eintritt --> Action danach wieder nichts machen ab und an Prüfen ob Ereignis eingetroffen.
Also eine Art Verzeichnissüberwacher (was hier nicht wörtlich zu nehmen ist)

Bis nun habe ich an eine Dauerschleife mit sleep () gedacht. Mit enztsprechender verzweigung wenn Ereignis wahr.

Meine Frage: Ist das eine "vernünftige " Möglichkeit damit das Programm im Hintergrund werkelt oder gibt es da etwas "besseres". Angedacht hatte ich auch mal niedere Prozessorlast für diesen Prozess, bi mir aber nicht sicher ob das etwas bringt. Die "Arbeit" ist ja gelich --> niedrige Last = längere Zeit ?

Kennt sich da jemad in den Zusammenhängen aus?

Danke

Peter

PS.: ich hoffe keine Glaskugel Frage gestellt zu haben

**AspirinJunkie**

Zitat von Peter S. Taler

ab und an Prüfen ob Ereignis eingetroffen.
Also eine Art Verzeichnissüberwacher (was hier nicht wörtlich zu nehmen ist)

Du prüfst periodisch die Verzeichnisse selbst auf Veränderungen ab?
Dann wäre die bessere Alternative die FileSystem-Events zu nutzen.
Dein Skript läuft dann nur in einer Sleep-Dauerschleife und wird wirklich nur dann aktiv wenn tatsächlich eine Änderung eingetreten ist.

Hier mal als Beispielskript welches meldet sobald eine neue Datei im Ordner C:\Test erstellt wurde:

AutoIt

#include <APIShellExConstants.au3>
#include <WinAPI.au3>
#include <WinAPIShellEx.au3>


OnAutoItExitRegister(raus)
HotKeySet("^q", raus) ; mit Strg-q Programm beenden


;~ #Region ShellEvent registrieren
Global $h_GUI = GUICreate("")
Global $h_Msg = _WinAPI_RegisterWindowMessage('irgendwas') ; Die Message "irgendwas" wird an das Fenster $h_GUI gesendet wenn ein Event auftritt
GUIRegisterMsg($h_Msg, ReactOnEvents)


; Die verschiedenen Ordner zur Überwachung registrieren:
Global $h_ShellNotify1 = _WinAPI_ShellChangeNotifyRegister($h_GUI, $h_Msg, $SHCNE_CREATE, 0x3, FileGetLongName("C:\Test\"))
If @error Or $h_ShellNotify1 = 0 Then Exit MsgBox(48, "Fehler", "Fehler bei _WinAPI_ShellChangeNotifyRegister()" & @CRLF & "@error = " & @error)
; hier gegegebenenfalls weitere Ordner registrieren
#EndRegion ShellEvent registrieren


; Endlosschleife
While Sleep(10000)
WEnd


; Funktion die aufgerufen wird wenn ein Event auftritt:
Func ReactOnEvents(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
	; vollständigen Pfad der erstellten Datei auslesen:
	Local $s_FullPath = DllCall("Shell32.dll", "BOOLEAN", "SHGetPathFromIDListW", "ptr", DllStructCreate("PTR A; PTR", $wParam).A, "wstr", "")[2]
	Local $s_Path = StringLeft($s_FullPath, StringInStr($s_FullPath, "\", 1, -1) - 1)
	Local $s_Filename = StringTrimLeft($s_FullPath, StringInStr($s_FullPath, "\", 1, -1))


	If $lParam = $SHCNE_CREATE Then ; Datei wurde erstellt (gibt noch weitere Events - muss man aber bei _WinAPI_ShellChangeNotifyRegister mit eintragen)
		MsgBox(0, "Datei erstellt", "In Ordner " & $s_Path & @CRLF & @CRLF & "wurde folgende Datei erstellt: " & $s_Filename)
	EndIf
EndFunc   ;==>ReactOnEvents


Func raus()
	_WinAPI_ShellChangeNotifyDeregister($h_ShellNotify1)
	Exit
EndFunc   ;==>raus

Alles anzeigen

**Alina**

Du schreibst "wenn ein bestimmtes Ereignis eintritt -->".

eine ganz kleine Glaskugel war es dann doch. Also das kann ich besser. *fg*

Wenn durch dieses "bestimmte Ereignis" ein Prozess gestartet wird, könntest Du abfragen, ob der Prozess gestartet (läuft er oder läuft er nicht?) ist und darauf reagieren.

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

JA wenn man mal meint...

Das Ereignis das primär überwcht werden soll:

Ist das Auftauchen eines USB Sticks durchgereicht via Remote Desktop.

In den neueren RMD von Windows kann man in den Oprionen tatsächlich dafür sorgen, dass ein USB Stick auf dem Zeilcomputer durchgereicht wird (Ich war vor einigen Tagen ganz baff als ich das entdeckte). Auf diesem Zielcomputer lasse ich per Autostart ein min autoit scribt laufen (per autostart) das nichts weiter macht als auf das Auftauchen dieses USB Sticks in einem def. Pfad zu warten. Damit habe ich zwei Fliegen mit einer Klappe:
1) wenn Stick da --> Remote Verbindung muss eingeleitet sein,
2) Stick ist vorhanden
3) das Abfragen ob die RMD Verbindung existiert bringt nichts, da es ein wenig dauerd bis der Stick tatsächlich zur Verfügung steht.
Ders Stick wied mit mit UNC pfad angezeigt.

Das ist der ursprüngliche und notwendige Plan.

Wenn man sowas allerdings mal andenkt weckt das Progrämchen Begehrlichkeiten - man könnte noch dieses und jenes....

Gruß

Peter

PS.: Alina Helene Fischer ???

kaesereibe

Ungetestet für deinen speziellen Fall zwecks durchreichen.
Aber evtl. mit der WM_DEVICECHANGE message. (Notifies an application of a change to the hardware configuration of a device or the computer.)

**AspirinJunkie**

Spontan zum testen (Skript meldet sobald ein neues Laufwerk erscheint):

AutoIt

#include <WindowsConstants.au3>


Global Const $DBT_DEVICEARRIVAL = 0x8000
Global Const $DBT_DEVICEREMOVECOMPLETE = 0x8004


Global Const $tagDEV_BROADCAST_HDR = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved"
Global Const $tagDEV_BROADCAST_VOLUME = "dword dbch_size; dword dbch_devicetype; dword dbch_reserved; dword dbcv_unitmask; word dbcv_flags"


HotKeySet("^q", raus) ; mit Strg-q Programm beenden


;~ #Region ShellEvent registrieren
Global $h_GUI = GUICreate("")
GUIRegisterMsg($WM_DEVICECHANGE, evDeviceChange)
#EndRegion ShellEvent registrieren


; Endlosschleife
While Sleep(10000)
WEnd


; Funktion die aufgerufen wird wenn ein Event auftritt:
Func evDeviceChange(Const $hWndGUI, Const $MsgID, Const $wParam, Const $lParam)
	Switch $wParam ; was ist passiert


		Case $DBT_DEVICEARRIVAL ; Device hinzugefügt
				Local $DEV_BROADCAST_HD = DllStructCreate($tagDEV_BROADCAST_HDR, $lParam)


				If $DEV_BROADCAST_HD.dbch_devicetype = 2 Then ; falls hinzugefügtes Device vom Typ "Volume" ist (Laufwerk)
					Local $DEV_BROADCAST_VOLUME = DllStructCreate($tagDEV_BROADCAST_VOLUME, $lParam) ; im Falle Volume entspricht die Struktur in $lparam einer DEV_BROADCAST_VOLUME
					Local $s_VolumeChar = Chr(65 + Int(log($DEV_BROADCAST_VOLUME.dbcv_unitmask) / log(2))) ; der Laufwerksbuchstabe des hinzugefügten Laufwerkes
					MsgBox(0,"Neues Volume", "Neues Volume " & $s_VolumeChar & ":\ hinzugefügt")
				Else
					ConsoleWrite("dbch_devicetype = " & $DEV_BROADCAST_HD.dbch_devicetype & @CRLF) ; für debugging
				EndIf


		Case $DBT_DEVICEREMOVECOMPLETE ; Device entfernt
				; Vorgehen ähnlich Zweig $DBT_DEVICEARRIVAL
	EndSwitch
EndFunc   ;==>ReactOnEvents




Func raus()
	Exit
EndFunc

Alles anzeigen

Peter S. Taler · *Ab 19-10-22 ergänzt um:*

@ Aspirin Junkie

danke erst mal - bin z.Z. ein wenig eingespannt brauche bis zum WE bis ich das ausprobieren kann, bis dahin lasse ich den Beitrag mal offen - vielleicht kommt noch die eine oder andere Idee.

Gruß

Peter