Nur zum Verständnis:
- Es läuft eine Konsolenanwendung in eigener Konsole
- Der Outstream soll in diese Konsole geschrieben werden aber auch für dich in einen eigenen Output dupliziert werden.
Ist das korrekt?
Gib bitte mal ein lauffähiges Bsp., damit man das testen kann.
Hallo BugFix
- Es läuft eine Konsolenanwendung in eigener Konsole
- Der Outstream soll in diese Konsole geschrieben werden aber auch für dich in einen eigenen Output dupliziert werden.
Ist das korrekt?
Ja, das ist korrekt.
Beispiel, ist etwas schwierig, da es eine node.js Anwendung ist und ich
davon ausgehe, das du nicht alles dafür installieren möchtest?!
Hier ein Beispiel wie es vom Prinzip her läuft:
$PID=Run($INI_PATH_CONSOLE, "", @SW_SHOW, $STDERR_CHILD + $STDOUT_CHILD)
While 1
$SOR=StdoutRead($PID)
ConsoleWrite($SOR &@CRLF)
WEnd
Vielen Dank für deine Hilfe.
Gruß
Homer J. S.
Mir fallen 2 Möglichkeiten ein:
1) "Eigenes" Consolenfenster
Du startest Run mit dem Parameter @SW_HIDE und erstellst selber eine GUI in welcher du deie gelesenen Daten ausgibst
2) Mit einer Pipe auf ein eigenes externes Tool weiterleiten
Zunächst kompilierst du dieses Script als Pipe.exe:
#AutoIt3Wrapper_Change2CUI = y
#include <WinAPI.au3>
#include <NamedPipes.au3>
Global Const $sPIPE_NAME = "\\.\pipe\AutoItPipe"
If $CmdLine[0] <> 1 Then Exit
Global $hPipe = $CmdLine[1]
Global $hPipe = _WinAPI_CreateFile($sPIPE_NAME, 2, 4)
Global $tBuffer, $iWritten, $iStatus
Global $sStd
While 1
$sStd = ConsoleRead()
If @error Then ExitLoop
If $sStd Then
$tBuffer = DllStructCreate("char[" & StringLen($sStd) & "];")
DllStructSetData($tBuffer, 1, $sStd)
$iStatus = _WinAPI_WriteFile($hPipe, $tBuffer, DllStructGetSize($tBuffer), $iWritten, 0)
ConsoleWrite($sStd)
EndIf
WEnd
$tBuffer = DllStructCreate("byte;")
DllStructSetData($tBuffer, 1, 0x1A)
_WinAPI_WriteFile($hPipe, $tBuffer, DllStructGetSize($tBuffer), $iWritten, 0) ;EndOfFile
_WinAPI_CloseHandle($hPipe)Im Hauptscript erstellst du eine NamedPipe.
Dessen Handle übergibst du an Pipe.exe und mit dem Zeichen "|" leitest du den Output an Pipe.exe weiter
In etwa so:
#include <WinAPI.au3>
#include <NamedPipes.au3>
Global Const $sPIPE_NAME = "\\.\pipe\AutoItPipe"
Global Const $iBufferSize = 512
Global $hPipe = _NamedPipes_CreateNamedPipe($sPIPE_NAME, 0, 0, 0, 0, 0, 1, 1, $iBufferSize, $iBufferSize)
_NamedPipes_WaitNamedPipe($sPIPE_NAME)
Global $tBuffer = DllStructCreate("char[" & $iBufferSize & "];")
Global $iPID = Run(@ComSpec & " /c " & 'Test.exe | Pipe.exe ' & $hPipe & ' 2>&1', @ScriptDir, @SW_SHOW)
Global $sOutput = ""
Global $iRead
While 1
If _WinAPI_ReadFile($hPipe, $tBuffer, $iBufferSize, $iRead, 0) Then
If DllStructGetData($tBuffer, 1, $iRead) = Chr(0x1A) Then ExitLoop
$sOutput &= DllStructGetData($tBuffer, 1)
ToolTip($sOutput)
EndIf
WEnd
MsgBox(0, "", "Output " & $sOutput)
_WinAPI_CloseHandle($hPipe)Pipe.exe bekommt nun via StdIn die Daten, schreibt diese in die NamedPipe und parallel dazu wieder in die Console
Das Haupscript erhält die Daten über die NamedPipe.
"|" leitet den Output weiter an Pipe.exe
"2>&1" leitet auch den StdErr an StdOut um, und somit auch an Pipe.exe
Damit das Hauptscript weiß, wann die Daten zu Ende sind, schreib ich "0x1A" ans Ende der Pipe.
Wahrscheinlich gibts eine sicherere Methode, aber da bin ich der falsche Ansprechpartner... 
Edit:
Kommt auch drauf an, wass du erreichen willst!
Evtl reicht es doch auch, wenn du im Hauptscript mit RunWait startest und die Auswertung komplett in Pipe.exe stattfindet!
Dann würdest du dir den Rückschliff via NamedPipe ersparen!
Von Interesse wäre noch:
Ist die Ausführung in der Konsole von längerer Dauer und musst du parallel mitlesen? (halte ich eigentlich für wenig wahrscheinlich)
Oder wird einfach ein Befehl in kurzer Zeitspanne abgearbeitet und du brauchst das Ergebnis? - Dann leite doch die Ausgabe in eine Textdatei um und schreibe anschliessend den Dateiinhalt wieder in die Konsole.