Radiobuttons die in einer Schleife erstellt wurden

Jiyon

Hallo Zusammen,

wie kann ich auslesen welcher Radiobutton ausgewählt wurde?

Hier mein vereinfachter Code. Normalerweise ist das Array von unbekannter Länge und nicht wie hier vorgegeben, da er einer Zeile einer Textdatei entspricht.

#include <Array.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiButton.au3>
#include <MsgBoxConstants.au3>

Local $b_Split[20]
For $i = 0 To 19
$b_Split[$i] = $i
Next
$iCols = UBound($b_Split)

$gui_name = GUICreate("Händlername", 500, 500, 100, 100)
GUISetFont(10, $FW_BOLD)
$yPos = 10
For $j = 2 To $iCols - 5
$Radio_ = GUICtrlCreateRadio($b_Split[$j], 10, $yPos, 300, 20)
Assign("Radio_" & $j ,$Radio_)
$yPos = $yPos + 30
Next
$yPos = $yPos + 30
$ok = GUICtrlCreateButton("ok", 50, $yPos)
GUISetState()

While 1
Switch GUIGetMsg()
Case $GUI_EVENT_CLOSE
GUIDelete($gui_name)
ExitLoop
Case $ok
For $k = 2 To $iCols
If GUICtrlRead($Radio_[$k]) = $GUI_CHECKED Then
$temp2 = $b_Split[$k]
EndIf
Next
MsgBox(48, 1, $temp2)
GUIDelete($gui_name)
ExitLoop
EndSwitch
WEnd

**Oscar**

Vergiss Assign und benutze direkt ein Array zum speichern der Ctrl-IDs.
Wenn Du außerdem den OnEventMode für die GUI verwendest, kannst Du einfach @GUI_CtrlId auswerten.

Edit: Im OnEventMode brauchst Du die Ctrl-IDs noch nicht mal zu speichern:

AutoIt

#include <FontConstants.au3>
#include <GUIConstantsEx.au3>


Opt('GUIOnEventMode', 1)


Global $b_Split[20], $sCheck = ''
For $i = 0 To 19
	$b_Split[$i] = $i
Next
$iCols = UBound($b_Split)


$gui_name = GUICreate("Händlername", 500, 500, 100, 100)
GUISetOnEvent($GUI_EVENT_CLOSE, '_CloseGui')
GUISetFont(10, $FW_BOLD)
$yPos = 10
For $j = 2 To $iCols - 5
	GUICtrlCreateRadio($b_Split[$j], 10, $yPos, 300, 20)
	GUICtrlSetOnEvent(-1, '_CheckRadio')
	$yPos = $yPos + 30
Next
$yPos = $yPos + 30
$ok = GUICtrlCreateButton("ok", 50, $yPos, 50, 25)
GUICtrlSetOnEvent(-1, '_Ok')


GUISetState()
WinWaitClose($gui_name)
Exit


Func _CloseGui()
	GUIDelete($gui_name)
EndFunc


Func _Ok()
	MsgBox(48, 1, $sCheck)
EndFunc


Func _CheckRadio()
	$sCheck = GUICtrlRead(@GUI_CtrlId, 1)
EndFunc

Alles anzeigen

Jiyon

Danke, werde ich gleich morgen mal testen.

gmmg

Der Post ist zwar schon älter, aber vielleicht braucht das nochmal jemand ein Beispiel zum erzeugen dynamischer RadioButtons und der Abfrage, welcher Button Checked ist.

AutoIt

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <Array.au3>


Local $aArray[8]
$aArray[0] = "8"
$aArray[1] = "Test1"
$aArray[2] = "Test2"
$aArray[3] = "Test3"
$aArray[4] = "Test4"
$aArray[5] = "Test5"
$aArray[6] = "Test6"
$aArray[7] = "Test7"




Local $aRadio_array[0]


$Member = GUICreate("RadioButton", 310, 30*$aArray[0] +60)


$top = 30


For $i = 1 To $aArray[0]-1
        $aRadio = GUICtrlCreateRadio($aArray[$i], 40, $top, 150, 20)
		;MsgBox(0,"", $aRadio)
		_ArrayAdd($aRadio_array,$aRadio)
        $top += 30
Next


$Button = GUICtrlCreateButton("Test", 40, $top+10, 108, 25, $WS_GROUP)


GUISetState(@SW_SHOW)




While 1
	$nMsg = GUIGetMsg()
	Switch $nMsg
		Case $GUI_EVENT_CLOSE
			Exit


		Case $Button


			For $i = 0 to UBound($aRadio_array)-1


				$Checked = GUICtrlRead($aRadio_array[$i])
				$Checked_wert = GUICtrlRead($aRadio_array[$i],1)


				IF $Checked = 1 Then
					MsgBox(0,"","RadioButton " & $Checked_wert)


				EndIf
			Next


	EndSwitch
WEnd

Alles anzeigen

Gruß gmmg