Prüfen ob eine Datei geöffnet ist

MadCatz

Hallo Leute,

ich war auf der suche nach einer Lösung zur Überprüfung, ob eine Datei geöffnet wurde.
Dabei kam ich bei :

cmd openfiles an

Allerdings dauert der Ausleseprozess in cmd ziemlich lange und benötigt zudem auch noch Adminrechte, was das ganze leider ziemlich unbrauchbar macht.

Schließlich stieß ich dann auf diesen Code:

AutoIt

;===============================================================================
;
; Function Name:    _FileInUse()
; Description:      Checks if file is in use
; Syntax.........: _FileInUse($sFilename, $iAccess = 1)
; Parameter(s):     $sFilename = File name
; Parameter(s):     $iAccess = 0 = GENERIC_READ - other apps can have file open in readonly mode
;                   $iAccess = 1 = GENERIC_READ|GENERIC_WRITE - exclusive access to file,
;                   fails if file open in readonly mode by app
; Return Value(s):  1 - file in use (@error contains system error code)
;                   0 - file not in use
;                   -1 dllcall error (@error contains dllcall error code)
; Author:           Siao
; Modified          rover - added some additional error handling, access mode
; Remarks           _WinAPI_CreateFile() WinAPI.au3
;===============================================================================
Func _FileInUse($sFilename, $iAccess = 0)
    Local $aRet, $hFile, $iError, $iDA
    Local Const $GENERIC_WRITE = 0x40000000
    Local Const $GENERIC_READ = 0x80000000
    Local Const $FILE_ATTRIBUTE_NORMAL = 0x80
    Local Const $OPEN_EXISTING = 3
    $iDA = $GENERIC_READ
    If BitAND($iAccess, 1) <> 0 Then $iDA = BitOR($GENERIC_READ, $GENERIC_WRITE)
    $aRet = DllCall("Kernel32.dll", "hwnd", "CreateFile", _
                                    "str", $sFilename, _ ;lpFileName
                                    "dword", $iDA, _ ;dwDesiredAccess
                                    "dword", 0x00000000, _ ;dwShareMode = DO NOT SHARE
                                    "dword", 0x00000000, _ ;lpSecurityAttributes = NULL
                                    "dword", $OPEN_EXISTING, _ ;dwCreationDisposition = OPEN_EXISTING
                                    "dword", $FILE_ATTRIBUTE_NORMAL, _ ;dwFlagsAndAttributes = FILE_ATTRIBUTE_NORMAL
                                    "hwnd", 0) ;hTemplateFile = NULL
    $iError = @error
    If @error Or IsArray($aRet) = 0 Then Return SetError($iError, 0, -1)
    $hFile = $aRet[0]
    If $hFile = -1 Then ;INVALID_HANDLE_VALUE = -1
        $aRet = DllCall("Kernel32.dll", "int", "GetLastError")
        ;ERROR_SHARING_VIOLATION = 32 0x20
        ;The process cannot access the file because it is being used by another process.
        If @error Or IsArray($aRet) = 0 Then Return SetError($iError, 0, 1)
        Return SetError($aRet[0], 0, 1)
    Else
        ;close file handle
        DllCall("Kernel32.dll", "int", "CloseHandle", "hwnd", $hFile)
        Return SetError(@error, 0, 0)
    EndIf
EndFunc

Alles anzeigen

Leider hab ich das Gefühl, dass der Code nicht wirklich funktionert, denn wenn ich hier per IF-Else-Abfrage abfrage, ob eine bestimmte Datei geöffnet ist, bekomme zu aller erst gesagt, dass $iAccess zuvor nicht deklariert wurde, bzw erhalte ich immer die Info, dass die gesuchte Datei geöffnet ist, egal ob dies zutrifft oder nicht.

Vielleicht kann mich jemand aufklären, an welcher Stelle mein Kopf gerade quer steht

Euer,
MadCatz

**autoBert**

zeige deinen Versuch wie du diese Func aufrufst.

MadCatz

Code

if _FileInUse("Dateiname", 0) then
....
else
....
endif

**autoBert**

Damit es überhaupt klappen kann muß Parameter 1 verwendet werden. Klappt aber bei meinen Tests auch nicht, Datei wird als geöffnet gemeldet egal ob geöffnet oder nicht.

Code

$sFilename="C:\Program Files\AutoIt3\Examples\Helpfile\Extras\_Excel2.txt"
$pid=ShellExecute($sFilename)
MsgBox(0,'Test (1)',_FileInUse($sFilename,1))
ProcessClose($pid)
Sleep(5000)
MsgBox(0,'Test (0)',_FileInUse($sFilename,1))

Edit: Diese Lösung:

AutoIt

#include <APIErrorsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>


;https://www.autoitscript.com/forum/topic/153060-_fileinuse-to-check-if-file-is-in-used-or-not-work-on-both-local-and-network-drive/?do=findComment&comment=1100491
; Works with v3.3.9.6+


$sFile="C:\Program Files\AutoIt3\Examples\Helpfile\Extras\Test.doc"
Local $hFileOpen = FileOpen($sFile, $FO_READ)
MsgBox($MB_SYSTEMMODAL, 'True', 'Is the file in use: ' & _FileIsUsed($sFile) & @CRLF)
FileClose($hFileOpen)
MsgBox($MB_SYSTEMMODAL, 'False', 'Is the file in use: ' & _FileIsUsed($sFile) & @CRLF)
$pid=ShellExecute($sFile)
Sleep(6000)
MsgBox($MB_SYSTEMMODAL, 'True', 'Is the file in use: ' & _FileIsUsed($sFile) & @CRLF)
ProcessClose($pid)
Sleep(6000)
MsgBox($MB_SYSTEMMODAL, 'False', 'Is the file in use: ' & _FileIsUsed($sFile) & @CRLF)


Func _FileIsUsed($sFilePath) ; By Nessie. Modified by guinness.
    Local Const $hFileOpen = _WinAPI_CreateFile($sFilePath, $CREATE_ALWAYS, (DriveGetType($sFilePath)) = 'NETWORK' ? $FILE_SHARE_READ : $FILE_SHARE_WRITE)
    Local $fReturn = True
    If $hFileOpen Then
        _WinAPI_CloseHandle($hFileOpen)
        $fReturn = False
    EndIf


    If $fReturn Then
        $fReturn = _WinAPI_GetLastError() = $ERROR_SHARING_VIOLATION
    EndIf
    Return $fReturn
EndFunc   ;==>_FileIsUsed

Alles anzeigen

hat die Tests für offene Worddokumente bestanden. Bei in NotePad geöffneten Dateien versagt es aber auch.

MadCatz

Hi, erstmal Danke für deine Hilfe

Aber bei deinem Skript gehst du ja hin und öffnest mit FileOpen die Datei, ich will die Datei aber nicht per Script öffnen, sondern nur abfragen, ob eine bestimmte Datei geöffnet ist.

Korrigiere mich bitte, falls ich da falsch liege

Gruß,
MadCatz

Edit:

Sorry, habs grad gesehen alles richtig

**Kanashius**

Das was er da gemacht hat nennt man Testprogramm. Dort wird dir gezeigt, wie die Funktion funktioniert. Der Aufruf steht dort.
Sieh dir das Beispiel doch mal genau und vernünftig an

misterspeed

Zitat von autoBert

hat die Tests für offene Worddokumente bestanden. Bei in NotePad geöffneten Dateien versagt es aber auch.

Nun ohne es genau zu wissen könnte ich mir vorstellen, dass Notepad die Datei nicht sperrt bzw. geöffnet hält, sondern lediglich einmalig einliest und die Datei dann bis zum Speichervorgang geschlossen lässt. Eine Prüfung ob die Datei von einem Programm "geöffnet" ist und bearbeitet wird ist in solch einem Fall jedenfalls nicht möglich. Daher wäre es vielleicht noch interessant was genau der TE mit der Prüfung überhaupt sicherstellen möchte.

MadCatz

Zitat von Kanashius

Das was er da gemacht hat nennt man Testprogramm. Dort wird dir gezeigt, wie die Funktion funktioniert. Der Aufruf steht dort.
Sieh dir das Beispiel doch mal genau und vernünftig an

Hi, wenn du mein Edit gelesen hättest hättest du bemerkt, dass ich es nochmal durchgelesen hab

MadCatz

Zitat von misterspeed

Nun ohne es genau zu wissen könnte ich mir vorstellen, dass Notepad die Datei nicht sperrt bzw. geöffnet hält, sondern lediglich einmalig einliest und die Datei dann bis zum Speichervorgang geschlossen lässt. Eine Prüfung ob die Datei von einem Programm "geöffnet" ist und bearbeitet wird ist in solch einem Fall jedenfalls nicht möglich. Daher wäre es vielleicht noch interessant was genau der TE mit der Prüfung überhaupt sicherstellen möchte.

Geht überwiegend um PDF, Word, Excel, Powerpoint Dateien, daher ist es kein Problem, dass Notepad nicht klappt