SQLite Hilfe benötigt

MadCatz

Hallo Leute,

in einem kleinen Part meines Scripts hat sich ein Fehler eingeschlichen. Dieser Verursacht, dass keine Daten in meine SQLiteDatabase geschrieben werden, aber ich find diesen einfach nicht

alles läuft wunderbar bis zudem Part wo Daten geschrieben werden sollen. Als @error erhalte ich eine "0" zurück, was ja bedeuten würde, dass alles klappt.

Das ist auch alles an Code, welcher mit SQLite arbeitet. Um zu testen ob ein Fehler in meinem Code war hab ich den Code durch den der Hilfe Datei bei "_SQLite_Exec" eingefügt, allerdings besteht auch hier dieses Problem.
Ich hoffe mir kann geholfen werden

Viele Grüße,
MadCatz

Edit:

Hoffe ich hab nicht vergessen eine Variable mit reinzupasten

AutoIt

#include <ComboConstants.au3>
#include <Crypt.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>
#include <String.au3>
#include <StringConstants.au3>


Global $sWorkingPath = @WorkingDir
Global $sEncryptXDatabase = $sWorkingPath & "\EncryptXDatabase.db"


If Not FileExists($sEncryptXDatabase) Then					; Checks whether EncryptX.db exists
	Local $a = _SQLite_Startup()
	Local $sSQLiteDatabase = FileWrite($sEncryptXDatabase,"")
	Local $a = _SQLite_Open($sSQLiteDatabase)
	Sleep(1000)
	Local $c = _SQLite_Exec($a, "Create table tblTest (a,b int,c single not null);" & _
        "Insert into tblTest values ('1',2,3);" & _
        "Insert into tblTest values (Null,5,6);")
		MsgBox(0,0,$c & " | " & @error,0)
		_SQLite_Close()
	FileWriteLine($sWorkingPath &"\path.nfo", "PathDatabase = " & $sEncryptXDatabase)
Endif

Alles anzeigen

4ern

Versuch mal für jeden SQL Befehl ein eigenes exec. Hatte auch mal Probleme, das er das gebündelt nicht macht...

**BugFix**

Zitat

Local $sSQLiteDatabase = FileWrite($sEncryptXDatabase,"")

Local $a = _SQLite_Open($sSQLiteDatabase)

Welchen Wert hat jetzt $sSQLiteDatabase ? RICHTIG: den Rückgabewert der Funktion Filewrite! Und der ist... - Problem erkannt?

misterspeed

Außerdem könnte die Tabellendefinition fehlerhaft sein. Laut Dokumentation gibt es keinen Datentyp "single".

https://www.sqlite.org/datatype3.html

**BugFix**

Mal noch als Tipp für mehr Übersicht beim Arbeiten mit SQLite ein Auszug aus einem Projekt, in dem ich SQLite eingesetzt habe. So kann man sich immer sofort einlesen:

AutoIt

Func _DB_Init()
	; Erstellen Tabellen:
	$sSQL = _
		"CREATE TABLE IF NOT EXISTS [kunden] (" & _
			"[kdnr]    INTEGER PRIMARY KEY AUTOINCREMENT," & _
			"[titel]   TEXT," & _
			"[firma]   TEXT," & _
			"[name]    TEXT NOT NULL," & _
			"[vorname] TEXT," & _
			"[strasse] TEXT," & _
			"[nr]      TEXT," & _
			"[plz]     TEXT," & _
			"[ort]     TEXT," & _
			"[telefon] TEXT," & _
			"[gebdat]  TEXT," & _
			"[re_strasse] TEXT," & _
			"[re_nr]      TEXT," & _
			"[re_plz]     TEXT," & _
			"[re_ort]     TEXT);" & _
		"CREATE TABLE IF NOT EXISTS [rechnungen] (" & _
			"[renr]         INTEGER PRIMARY KEY AUTOINCREMENT," & _
			"[kdnr]         INTEGER NOT NULL," & _
			"[datum]        TEXT NOT NULL," & _
			"[datum_an]     TEXT," & _
			"[datum_ab]     TEXT," & _
			"[zahlweise]    TEXT," & _   ; 'bar' oder 'überw.'
			"[netto_voll]   REAL," & _
			"[netto_erm]    REAL," & _
			"[ustsatz_voll] REAL," & _
			"[ustsatz_erm]  REAL);" & _
		"CREATE TABLE IF NOT EXISTS [positionen] (" & _
			"[posnr]       INTEGER PRIMARY KEY AUTOINCREMENT," & _
			"[renr]        INTEGER NOT NULL," & _
			"[anzahl]      INTEGER NOT NULL," & _
			"[artnr]       INTEGER NOT NULL," & _
			"[arttext]     TEXT NOT NULL," & _
			"[einzelnetto] REAL NOT NULL," & _
			"[usttyp]      TEXT NOT NULL);" & _   ; 'erm' oder 'voll'
		"CREATE TABLE IF NOT EXISTS [stammdaten] (" & _
			'[voll] REAL,' & _  ; == Steuersatz voll
			'[erm]  REAL,' & _  ; == Steuersatz ermäßigt
			'[firma] TEXT,' & _
			'[inhaber] TEXT,' & _
			'[strasse] TEXT,' & _
			'[nr] TEXT,' & _
			'[plz] TEXT,' & _
			'[ort] TEXT,' & _
			'[tel] TEXT,' & _
			'[fax] TEXT,' & _
			'[email] TEXT,' & _
			'[bank] TEXT,' & _
			'[bic] TEXT,' & _
			'[iban] TEXT,' & _
			'[ustid] TEXT);' & _
		"CREATE TABLE IF NOT EXISTS [artikel] (" & _
			'[artnr]   INTEGER NOT NULL,' & _
			'[arttext] TEXT NOT NULL,' & _
			'[netto]   REAL NOT NULL,' & _
			'[usttyp]  TEXT NOT NULL);'
	_SQLite_Exec($hSQL, $sSQL)
	_SQLErr()
	; == Tabellen KU & RE: Index auf Startwert setzen, wenn bei Stammdaten Startwert gesetzt und Tabelle noch nicht aktualisiert
	_SetSequences()


	; == USt-Sätze Ersteintrag
	If _CountRows('stammdaten') = 0 Then
		_SQLite_Exec($hSQL, "INSERT INTO stammdaten VALUES (19,7,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL,NULL);")
		_SQLErr()
	EndIf
EndFunc


Func _SetSequences()
	If _Table_GetSequence('kunden') = -1 Then
		If $iKDNR_Start > 0 Then
			_SQLite_Exec($hSQL, "INSERT INTO sqlite_sequence VALUES ('kunden', " & $iKDNR_Start-1 & ");")
			_SQLErr()
		EndIf
	EndIf
	If _Table_GetSequence('rechnungen') = -1 Then
		If $iRENR_Start > 0 Then
			_SQLite_Exec($hSQL, "INSERT INTO sqlite_sequence VALUES ('rechnungen', " & $iRENR_Start-1 & ");")
			_SQLErr()
		EndIf
	EndIf
EndFunc


Func _Table_GetSequence($_sTable)
	If Not _TableExists($_sTable) Then Return SetError(1,0,-2)
	Local $iRet = -1
	_SQLite_Query($hSQL, "SELECT seq FROM sqlite_sequence WHERE name = '" & $_sTable & "'", $hQuery)
	_SQLErr()
	While _SQLite_FetchData($hQuery, $aQuery) = $SQLITE_OK
		$iRet = $aQuery[0]
	WEnd
	_SQLite_QueryFinalize($hQuery)
	_SQLErr()
	Return $iRet
EndFunc


Func _TableExists($_sTable)
	Local $fRet = False
	_SQLite_Query($hSQL, "SELECT name FROM sqlite_master WHERE type='table'", $hQuery)
	_SQLErr()
	While _SQLite_FetchData($hQuery, $aQuery) = $SQLITE_OK
		If $aQuery[0] = $_sTable Then
			$fRet = True
			ExitLoop
		EndIf
	WEnd
	_SQLite_QueryFinalize($hQuery)
	_SQLErr()
	Return $fRet
EndFunc

Alles anzeigen

MadCatz

Zitat von BugFix

Welchen Wert hat jetzt $sSQLiteDatabase ? RICHTIG: den Rückgabewert der Funktion Filewrite! Und der ist... - Problem erkannt?

Fu** hast recht, nach Stunden auf den Bildschirm schauen hab ich das nicht gesehen -.-

Edit:

Das im Verbund mit:

Zitat von 4ern

Versuch mal für jeden SQL Befehl ein eigenes exec. Hatte auch mal Probleme, das er das gebündelt nicht macht...

hat funktioniert

Vielen Dank an euch alle für die sehr sehr schnelle Hilfe