Digitaler Planungsordner (GDI+ Zeichnen und speichern, Zoom)

x0r

Hi,

gibts unter euch jemanden, der einen "Digitalen Planungsordner" bauen kann?

Ne Art Vorlage hätte man hier: http://www.akgsoftware.de/OKview.93.0.html

- einfache Übersicht, vollständiges Projekt in einer Datei, inkl. Inhaltsverzeichnis bzw. Treeview
- Dateien direkt im Programm öffnen (nicht zwingend) und Notizen hinzufügen oder "zeichnen"
- Teile des Ordners als PDF exportieren

[Blockierte Grafik: http://www.akgsoftware.de/uploads/pics/OK_View_800x600.jpg]

Hoffe ihr könnt was damit anfangen, ich hab leider gar keinen Plan, wo ich am besten anfange. Ein Treeview ist nicht das Problem

€dit: Man muss die geöffnete Datei (zu 100% PDF) auch Zoomen können und dann das jeweils gezeichnete natürlich auch an der gezeichneten Position speichern und quasi "mitzoomen".
Hat wirklich sonst niemand Plan von sowas?

Gruß,
x0r

**Xorianator**

Zitat von AutoMit

daher mein Tipp, schaue Dir mal ISN an.

Was hat das ISN jetzt genau mit dem Projekt zu tun? Und nein, bitte antworte hier nicht, ich glaube er sucht ernsthaft Hilfe (für das Projekt).

Für die Controlleiste gibt es hier die Ribbons Bar UDF.
Anfangen würde ich damit, zu überlegen, wie ich was aufbaue (in der Datei) und wie ich das Produkt dann darstelle.
Die Zeichenfläche kannst du ganz klar per GDI+ erledigen, hier hat UEZ mal ein Beispiel gezeigt, wie man da was anklickt. Ich könnte aber fast schwören, schon mal eine UDF oder wenigstens ein paar mehr Beispiele gesehen zu haben, da eventuell mal warten, bis UEZ oder ein ähnlich oft GDI+ Nutzender sich hier meldet.
Das öffnen der Dateien im Programm kannst du doch über ein entsprechendes Kontextmenü machen, oder willst du eine hierarchisch aufgelistete Dateistruktur im Treeview? Wenn ja, da hatte Oscar mal eine UDF geschrieben:
Hier siehst du sie, die Einbindung in deine GUI sollte dem Beispiel zu entnehmen sein, wie es geht.

Das unten kannst du als ListView nehmen, willst du bei Klick auf eine Fläche in der Zeichenfläche, dass der Eintrag im ListView ausgewählt wird? Bzw. analog dazu auch das Gegenstück, also bei Klick im ListView die Fläche im Bild?

x0r

Ok, das sind schonmal echt gute Ansätze, mal sehen, wie ich das alles realisiert bekomme (muss bald sein, sonst latscht mir mein (neuer) Chef auf die Klöten :D).

Kann ich das gezeichnete auf der "Zeichenfläche" auch irgendwie speicher, damit ich es beim nächsten Öffnen wieder sehe?

Danke für deine Antwort übrigens

Leider seh ich nicht, was "der Andere da" mit ISN meinte...

**Xorianator**

Hi, klar.
Angenommen du zeichnest jetzt Polygone, dann kannst du ja jedes Polygon als 2-Dimensionales Array mit n-Punkten darstellen. Bzw. auch einfach alle mit einem 2-D Array, bei dem:
$arr[n][0] = x1, $arr[n][1] = y1, $arr[n][2] = x2, $arr[n][3] = y2, ... ist.
Das kannst du ja dann - je nachdem wie du es speichern willst, in einer Datei ablegen und wieder rauslesen.

Zu dem ISN: Keine Sorge, du verpasst nix, das war nicht wirklich hilfreich oder zielführend

x0r

So, n bissl was "zusammenkopiert" hab ich, nur zeigts mir keine PDF an, warum auch immer:

In Zeile 91 wird bzw sollte die PDF angezeigt werden, tut sich aber nix.

PDF raussuchen, rechtsklick drauf, läd kurz (Mauszeiger Sanduhr) und nix passiert. Ärgerlich

AutoIt

;~ #RequireAdmin
#Include <GUIConstantsEx.au3>
#Include <GUIImageList.au3>
#Include <GUITreeView.au3>
#Include <GUIToolBar.au3>
#Include <TreeViewConstants.au3>
#Include <WindowsConstants.au3>
#Include <WinAPIEx.au3>
;~ MsgBox(0,"", _WinAPI_GetVersion())
;~ Opt('MustDeclareVars', 1)


Global $sRoot = @ScriptDir ;sollte PDFs enthalten


Global $hForm, $hTreeView, $hImageList, $hItem, $hNext, $hSelect = 0, $hInput, $Input, $Dummy1, $Dummy2, $Edit1, $hToolBar
Global $X, $Y, $sPath


Global Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp


$hForm = GUICreate("MyGUI", 1150, 630, 192, 125)
$Input = GUICtrlCreateInput("", 20, 44, 560, 21)
$hInput = GUICtrlGetHandle(-1)
GUICtrlSetState(-1, $GUI_DISABLE)
$hToolBar = _GUICtrlToolbar_Create($hForm, 0)


$aSize = _GUICtrlToolbar_GetMaxSize($hToolbar)
_GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
; Add buttons
_GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
_GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
_GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
_GUICtrlToolbar_AddButtonSep($hToolbar)
_GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)


Global $oPDF = ObjCreate("AcroPDF.PDF")
Global $GUI_ActiveX = GUICtrlCreateObj($oPDF, 256, 72, 865, 529)
GUICtrlSetStyle($GUI_ActiveX, $WS_VISIBLE)
GUICtrlSetResizing($GUI_ActiveX, $GUI_DOCKAUTO)


GUICtrlCreateTreeView(20, 74, 216, 530, -1, $WS_EX_CLIENTEDGE)
$hTreeView = GUICtrlGetHandle(-1)
$Dummy1 = GUICtrlCreateDummy()
$Dummy2 = GUICtrlCreateDummy()


If _WinAPI_GetVersion() >= '6.0' Then
    _WinAPI_SetWindowTheme($hTreeView, 'Explorer')
EndIf


$hImageList = _GUIImageList_Create(16, 16, 5, 1)
_GUIImageList_AddIcon($hImageList, @SystemDir & '\shell32.dll', 3)
_GUIImageList_AddIcon($hImageList, @SystemDir & '\shell32.dll', 4)
_GUICtrlTreeView_SetNormalImageList($hTreeView, $hImageList)
$sRoot = StringRegExpReplace($sRoot, '\\+\Z', '')
$sPath = StringRegExpReplace($sRoot, '^.*\\', '')
If StringInStr($sPath, ':') Then
    $sRoot &= '\'
    $sPath &= '\'
EndIf


_TVUpdate($hTreeView, _GUICtrlTreeView_AddChild($hTreeView, 0, $sPath, 0, 0))


GUIRegisterMsg($WM_NOTIFY, 'WM_NOTIFY')
GUISetState()


_GUICtrlTreeView_Expand($hTreeView, _GUICtrlTreeView_GetFirstItem($hTreeView))


While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            $oPDF.close
			Exit
        Case $Dummy1 ; Update
            GUISetCursor(1, 1)
            $hItem = _GUICtrlTreeView_GetFirstChild($hTreeView, GUICtrlRead($Dummy1))


            If $hItem Then
                While $hItem
                    $hNext = _GUICtrlTreeView_GetNextSibling($hTreeView, $hItem)
                    If Not _TVUpdate($hTreeView, $hItem) Then
                        _GUICtrlTreeView_Delete($hTreeView, $hItem)
                    EndIf
                    $hItem = $hNext
                WEnd
                _WinAPI_RedrawWindow($hTreeView)
            EndIf
            GUISetCursor(2, 0)


        Case $Dummy2 ; Show PDF
            $hItem = GUICtrlRead($Dummy2)
            $sPath = _TVGetPath($hTreeView, $hItem, $sRoot)


			$oPDF.src = '"' & $sPath & '"'
    EndSwitch
WEnd


Func _TVGetPath($hTV, $hItem, $sRoot)


    Local $Path = StringRegExpReplace(_GUICtrlTreeView_GetTree($hTV, $hItem), '([|]+)|(\\[|])', '\\')


    If Not $Path Then
        Return ''
    EndIf
    If Not StringInStr($Path, ':') Then
        Return StringRegExpReplace($sRoot, '(\\[^\\]*(\\|)+)\Z', '\\') & $Path
    EndIf
    Return $Path
EndFunc   ;==>_TVGetPath


Func _TVSetPath($hTV, $hItem, $sRoot)
    GUICtrlSetData($Input, _WinAPI_PathCompactPath($hInput, _TVGetPath($hTV, $hItem, $sRoot), 554))
    $hSelect = $hItem
EndFunc   ;==>_TVSetPath


Func _TVUpdate($hTV, $hItem)


    Local $hImageList = _SendMessage($hTV, $TVM_GETIMAGELIST)
    Local $Path = StringRegExpReplace(_TVGetPath($hTV, $hItem, $sRoot), '\\+\Z', '')
    Local $hSearch, $hIcon, $Index, $File


    $hSearch = FileFindFirstFile($Path & '\*')
    If $hSearch = -1 Then
        If Not @error Then
            If not FileExists($Path) Then
                Return 0
            EndIf
        EndIf
    Else
        While 1
            $File = FileFindNextFile($hSearch)
            If @error Then
                ExitLoop
            EndIf
            If @extended Then
                _GUICtrlTreeView_AddChild($hTV, $hItem, $File, 0, 0)
            EndIf
        WEnd
        FileClose($hSearch)
    EndIf
    $hSearch = FileFindFirstFile($Path & '\*.pdf')
    If $hSearch = -1 Then


    Else
        While 1
            $File = FileFindNextFile($hSearch)
            If @error Then
                ExitLoop
            EndIf
            If Not @extended Then
                $hIcon = _WinAPI_ShellExtractAssociatedIcon($Path & '\' & $File, 1)
                $Index = _GUIImageList_ReplaceIcon($hImageList, -1, $hIcon)
                _GUICtrlTreeView_AddChild($hTV, $hItem, $File, $Index, $Index)
                _WinAPI_DestroyIcon($hIcon)
            EndIf
        WEnd
        FileClose($hSearch)
    EndIf
    Return 1
EndFunc   ;==>_TVUpdate


Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)


    Local $tNMTREEVIEW = DllStructCreate($tagNMTREEVIEW, $lParam)
    Local $hItem = DllStructGetData($tNMTREEVIEW, 'NewhItem')
    Local $iState = DllStructGetData($tNMTREEVIEW, 'NewState')
    Local $hTV = DllStructGetData($tNMTREEVIEW, 'hWndFrom')
    Local $ID = DllStructGetData($tNMTREEVIEW, 'Code')
    Local $tTVHTI, $tPoint


    Switch $hTV
        Case $hTreeView
            Switch $ID
                Case $TVN_ITEMEXPANDEDW
                    If Not FileExists(_TVGetPath($hTV, $hItem, $sRoot)) Then
                        _GUICtrlTreeView_Delete($hTV, $hItem)
                        If BitAND($iState, $TVIS_SELECTED) Then
                            _TVSetPath($hTV, _GUICtrlTreeView_GetSelection($hTV), $sRoot)
                        EndIf
                    Else
                        If Not BitAND($iState, $TVIS_EXPANDED) Then
                            _GUICtrlTreeView_SetSelectedImageIndex($hTV, $hItem, 0)
                            _GUICtrlTreeView_SetImageIndex($hTV, $hItem, 0)
                        Else
                            _GUICtrlTreeView_SetSelectedImageIndex($hTV, $hItem, 1)
                            _GUICtrlTreeView_SetImageIndex($hTV, $hItem, 1)
                            If Not _GUICtrlTreeView_GetItemParam($hTV, $hItem) Then
                                _GUICtrlTreeView_SetItemParam($hTV, $hItem, 0x7FFFFFFF)
                                GUICtrlSendToDummy($Dummy1, $hItem)
                            EndIf
                        EndIf
                    EndIf
                Case $TVN_SELCHANGEDW
                    If BitAND($iState, $TVIS_SELECTED) Then
                        If Not FileExists(_TVGetPath($hTV, $hItem, $sRoot)) Then
                            _GUICtrlTreeView_Delete($hTV, $hItem)
                            $hItem = _GUICtrlTreeView_GetSelection($hTV)
                        EndIf
                        If $hItem <> $hSelect Then
                            _TVSetPath($hTV, $hItem, $sRoot)
                        EndIf
                    EndIf
                Case $NM_RCLICK
                        $tPoint = _WinAPI_GetMousePos(1, $hTV)
                        $tTVHTI = _GUICtrlTreeView_HitTestEx($hTV, DllStructGetData($tPoint, 1), DllStructGetData($tPoint, 2))
                        $hItem = DllStructGetData($tTVHTI, 'Item')
                        If BitAND(DllStructGetData($tTVHTI, 'Flags'), $TVHT_ONITEM) Then
                            _GUICtrlTreeView_SelectItem($hTreeView, $hItem)
                            If Not FileExists(_TVGetPath($hTV, $hItem, $sRoot)) Then
                                _GUICtrlTreeView_Delete($hTV, $hItem)
                                $hItem = _GUICtrlTreeView_GetSelection($hTV)
                            Else
                                GUICtrlSendToDummy($Dummy2, $hItem)
                            EndIf
                            If $hItem <> $hSelect Then
                                _TVSetPath($hTV, $hItem, $sRoot)
                            EndIf
                        EndIf
                EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

Alles anzeigen

€dit: 500. Beitrag, wohooo!!!