Größe von ComboBox einstellen nicht möglich? Height-Parameter ohne Funktion?

**autoiter**

Hallo Leute,

ist vielleicht ein absolutes Idioten-Problem, aber das plumpe Anwenden der GUICtrlCreateCombo-Parameter hilft mir nicht.
Von anderen Controls kenne ich es nur so, dass ich die Größe per width und height definieren kann.

Bei GUICtrlCreateCombo funktioniert es nicht. Das angepasste Beispiel soll das zeigen:

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>


Example()


Func Example()
	; Create a GUI with various controls.
	Local $hGUI = GUICreate("Example", 300, 200)


	; Create a combobox control.
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185, 20)
	Local $idComboBox2 = GUICtrlCreateCombo("Item 1", 10, 40, 185, 60)
	Local $idComboBox3 = GUICtrlCreateCombo("Item 1", 10, 80, 185, 520)
	Local $idComboBox4 = GUICtrlCreateCombo("Item 1", 10, 120, 185, 120)
	Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)


	; Add additional items to the combobox.
	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")
	GUICtrlSetData($idComboBox2, "Item 2|Item 3", "Item 2")
	GUICtrlSetData($idComboBox3, "Item 2|Item 3", "Item 2")
	GUICtrlSetData($idComboBox4, "Item 2|Item 3", "Item 2")


	; Display the GUI.
	GUISetState(@SW_SHOW, $hGUI)


	Local $sComboRead = ""


	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop


			Case $idComboBox
				$sComboRead = GUICtrlRead($idComboBox)
				MsgBox($MB_SYSTEMMODAL, "", "The combobox is currently displaying: " & $sComboRead, 0, $hGUI)


		EndSwitch
	WEnd


	; Delete the previous GUI and all controls.
	GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

Wie funktioniert es?

**autoBert**

Zitat von autoiter

Von anderen Controls kenne ich es nur so, dass ich die Größe per width und height definieren kann.

Bei GUICtrlCreateCombo funktioniert es nicht. Das angepasste Beispiel soll das zeigen:
...

das angezeigte Beispiel zeigt das was ich vom Code erwarte, vielleicht definierst du ja (irgendwie anders) welche Anzeige du erwartest?

**autoiter** · Hallo autoBert, welche AutoIt-Version nutzt du? Hier mit 3.3.14.2 geht es nicht.

Hallo autoBert,
welche AutoIt-Version nutzt du?
Hier mit 3.3.14.2 geht es nicht.

**autoiter**

Hier nochmal, worum es mir prinzipiell geht.

Ich sehe ja selbst, der height-Parameter ist nicht völlig funktionslos. Er ändert etwas die Control-Abstände.
Eigentlich geht es mir darum in einer GUI Buttons und Comboboxen gleich groß zu machen. Das bekomme ich mit den vorgesehenen Methoden aber nicht hin.

Spoiler anzeigen

AutoIt

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>


Example()


Func Example()
	; Create a GUI with various controls.
	Local $hGUI = GUICreate("Example", 300, 200)


	; Create a combobox control.
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 80, 30)
	Local $idComboBox2 = GUICtrlCreateButton("Item 1", 100, 10, 80, 30)
	Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)


	; Add additional items to the combobox.
	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")


	; Display the GUI.
	GUISetState(@SW_SHOW, $hGUI)


	Local $sComboRead = ""


	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop


			Case $idComboBox
				$sComboRead = GUICtrlRead($idComboBox)
				MsgBox($MB_SYSTEMMODAL, "", "The combobox is currently displaying: " & $sComboRead, 0, $hGUI)


		EndSwitch
	WEnd


	; Delete the previous GUI and all controls.
	GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

Bei mir sieht das wie im Anhang aus.

**autoBert**

Genau die gleiche Version, allerdings zeigt mir auch dein Screenshot genau was ich von dem Code erwarte. Du solltest mal den Parameter Style benutzen, vielleicht erwartest du ja eine Anzeige die von Style: $CBS_SIMPLE erzeugt wird. Standardmäßig erhälst du eine Editbox, die bei Bedarf ausklappt.

**autoiter**

Sorry autoBert,
ich kann dir nicht folgen. Bevor wir jetzt über meine sprachlichen Fehler sprechen, mein Problem adäquat zu beschreiben. Erkläre mir bitte wie du die Größe dieses Controls erfolgreich änderst.

**autoBert**

über den Height-Parameterm dieser wirkt sich aber nicht bei Default-Style aus, benutze $CBS_Simple als Style und du erkennst einen Unterschied:

C

; *** Start added by AutoIt3Wrapper ***
#include <ComboConstants.au3>
; *** End added by AutoIt3Wrapper ***
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Add_Constants=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>


Example()


Func Example()
	; Create a GUI with various controls.
	Local $hGUI = GUICreate("Example", 300, 200)


	; Create a combobox control.
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185, 170, $CBS_Simple)
	Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)


	; Add additional items to the combobox.
	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")


	; Display the GUI.
	GUISetState(@SW_SHOW, $hGUI)


	Local $sComboRead = ""


	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop




		EndSwitch
	WEnd


	; Delete the previous GUI and all controls.
	GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

**autoiter**

Hey Leute,
ich habe das Skript von autoBert nun einmal mit seiner Höhe 170 height_170.png
und dann mit der Höhe 40 height_40.pnggestartet.

Das kann doch nicht richtig sein?!?

Ich erwarte analog zu den anderen Controls eine Änderung der Größe, damit ich sie eben in gleicher Größe neben Buttons verwenden kann.

**BugFix**

Ich denke, du hast den Sinn des Height-Parameters falsch verstanden. Es ist nicht die Höhe der Box.

Zitat von AutoIt-Hilfe

Under Windows XP/2003 Windows will adjust the size of the opened combo. On other Windows versions you can define this size with the "height" parameter if the default value is not BIG enough to contain at least one line.

Es geht um die Höhe der geöffneten Box.

CentuCore

Du musst die Größe der Font der Combobox verändern.
GuiCtrlSetFont()

**autoiter**

@BugFix
Danke, verstehe. Ich hoffe aber, mein Missverständnis ist nachvollziehbar, denn das unterscheidet sich völlig dem Handling aller andern Constrols.

@CentuCore
Das wäre ein Workaround. Allerdings sieht die Beschriftung dann natürlich ganz anders aus, als bei den normalen Buttons.

Fazit, es geht nicht wirklich, oder?

Ich bin völlig überrascht. Nie hätte ich gedacht, dass ich die ComboBoxen nicht frei in der Größe anpassen könnte, wie die anderen Controls.

Kennt jemand einen guten ComboBoxen-Selbstbau?

**BugFix**

Mein Workaround:
Hol dir das Handle des Inputs der Combo (haben wir im Forum schon mehrfach abgehandelt) und Resize dann die Größe mit WinMove.

**autoiter**

Hey BugFix,

hast du das mal ausprobiert?
Unbenannt.PNG

Spoiler anzeigen

AutoIt

; *** Start added by AutoIt3Wrapper ***
#include <ComboConstants.au3>
; *** End added by AutoIt3Wrapper ***
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Add_Constants=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>


Example()


Func Example()
	; Create a GUI with various controls.
	Local $hGUI = GUICreate("Example", 300, 200)


	; Create a combobox control.
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 80, 40)
	Local $idButton = GUICtrlCreateButton("Item 1", 100, 10, 80, 40)
	Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)


	; Add additional items to the combobox.
	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")


	; Display the GUI.
	GUISetState(@SW_SHOW, $hGUI)


	WinMove($idComboBox, "Item 1", 10,10, 80, 40)


	Local $sComboRead = ""


	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop




		EndSwitch
	WEnd


	; Delete the previous GUI and all controls.
	GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

Bei mir bleibt alles beim Alten!

Kann wirklich niemand das Problem nachvollziehen?

EDIT: Äh, gerade GUICtrlSetPos($idComboBox, 10,10, 80, 40) verwendet...
Hat aber leider nichts verändert.

Tagger

autoiter: die Höhenangabe des Controls beziehen sich auf die Anzeige-Höhe des ausgeklappten Controls.

**autoiter**

Hi tagger,
BugFix hat mich ja eigentlich aufgeklärt. Passt schon.

**BugFix**

Ich habe mal einen Workaround erstellt, wie du das Lösen kannst:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>


Example()
Func Example()
	Local $hGUI = GUICreate("Example", 300, 200)
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185)
	Local $hWnd = GUICtrlGetHandle($idComboBox)


	; geplante Höhe für Box (eingeklappt) und Button daneben
	Local $iBoxHeight = 40
	; Höhe als Item-Höhe setzen (real etwas größer als die gewünschte Höhe, da Input ein Child ist)
	_GUICtrlComboBox_SetItemHeight($hWnd, $iBoxHeight)
	; reale Größe abfragen
	$iHeightReal = (WinGetPos($hWnd))[3]
	; Größe neu festlegen aus Abweichung
	_GUICtrlComboBox_SetItemHeight($hWnd, $iBoxHeight-($iHeightReal-$iBoxHeight))
	; Button in gleicher Höhe
	Local $idClose = GUICtrlCreateButton("Close", 210, 10, 85, $iBoxHeight)


	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")
	; Display the GUI.


	GUISetState(@SW_SHOW, $hGUI)
	Local $sComboRead = ""
	; Loop until the user exits.
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop
		EndSwitch
	WEnd
	; Delete the previous GUI and all controls.
	GUIDelete($hGUI)
EndFunc   ;==>Example

Alles anzeigen

**autoiter**

Hallo BugFix,
coole Idee. Das ist für mich absolut brauchbar.

Vielen Dank

Runa

BugFix : Wollte gerade die gleiche Funktion vorschlagen. Die Abweichung beträgt aber - soweit ich weiß und hier nachstellen konnte - immer 8 Pixel. Deine Methode ist da natürlich deutlich störunanfälliger.

**BugFix**

Zitat von Bioshade

soweit ich weiß und hier nachstellen konnte - immer 8 Pixel

Bei mir waren es 6 Pixel. Und da ich annahm, dass das vom WindowStyle (Fensterränder) abhängt, bin ich auf die variable Variante gewechselt.
Besser ist es noch, den Workaround in eine Funktion auszulagern - sieht dann so aus:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiComboBox.au3>


Example()
Func Example()
	Local $hGUI = GUICreate("Example", 300, 200)
	Local $idComboBox = GUICtrlCreateCombo("Item 1", 10, 10, 185)
	GUICtrlSetData($idComboBox, "Item 2|Item 3", "Item 2")


	; Äußere Höhe der eingeklappten ComboBox festlegen
	_GuiCtrlComboBox_SetCtrlHeight($idComboBox, 40)
	; Button in gleicher Höhe
	Local $idClose = GUICtrlCreateButton("Close", 210, 10, 85, 40)


	GUISetState(@SW_SHOW, $hGUI)
	Local $sComboRead = ""
	While 1
		Switch GUIGetMsg()
			Case $GUI_EVENT_CLOSE, $idClose
				ExitLoop
		EndSwitch
	WEnd
	GUIDelete($hGUI)
EndFunc   ;==>Example




; Requires: #include <GuiComboBox.au3>
Func _GuiCtrlComboBox_SetCtrlHeight($_iID_Hwnd, $_iHeight)
	Local $hWnd = $_iID_Hwnd
	If Not IsHWnd($hWnd) Then $hWnd = GUICtrlGetHandle($hWnd)
	_GUICtrlComboBox_SetItemHeight($hWnd, $_iHeight)
	Local $iHeightReal = (WinGetPos($hWnd))[3]
	_GUICtrlComboBox_SetItemHeight($hWnd, $_iHeight-($iHeightReal-$_iHeight))
EndFunc

Alles anzeigen