Winkelfunktionen - Richtungspfeile am Rand

Texos

Moin moin,

Mir fällt leider keine direkte Überschrift dazu ein, ich versuchs euch aber mal zu erklären.

Ich habe ein Quadrat und die Mitte des Quadrads gibt die Position des Spielers an. Das Quadrad ist unterteilt in mehrere kleinere Quadrate (Felder). Spieler die sich außerhalb der Sichtweite befinden würde ich gerne Kennzeichnen und mit einem Richtungspfeil anzeigen lassen.

Was ich besitze: Den Winkel zum Spieler hin, die Pixellänge in 180* bzw 90* sagen wir einfach mal 200px. Das Problem jedoch ist, zeichne ich jetzt den Pfeil und der spieler hat einen Winkel von 135 (Diagonal linksoben) Dann würde der Pfeil miten im Quadrad iegen und nicht in der Ecke wo es hin soll.

Jedes Feld im "großen Quadrat" ist 20x20px

Hättet ihr ne möglichkeit dies zu lösen?

CentuCore

Mir fiele das ein:

Idee:
a) Wenn du die Endpunkte jeder Seite mit dem Mittelpunkt verbindest ist der Winkel zwischen diesen Linien immer 90°.
b) Ergo kann jedem Winkel eindeutig ein Punkt auf der Außenseite zugewiesen werden.

Algo:
1) Du dividierst durch 360.0. Dadurch hast du nun einen Wert von 0-1 (in den meisten Fällen mit 'ner Menge Nachkommastellen).
1a) Vorraussetzung ist, dass dein Winkel immer im Wertbereich [0; 360] ist.

2) Du multiplizierst das Ergebnis mit 4.0. Den neuen Wert nennen wir mal Index. (die Nachkommastellen sind immer noch wichtig)

3) Jetzt erstellst du ein Array mit 6 Einträgen:
[0]: Position vom 1. Endpunkt.
[1]: Position vom 2. Endpunkt.
[2]: Position vom 3. Endpunkt.
[3]: Position vom 4. Endpunkt.
[4]: Position vom 1. Endpunkt.
[5]: Position vom 2. Endpunkt. (Wird gebraucht wenn Index gleich 4 ist. Genau genommen kann da auch 0 drinnen stehen. Es muss halt derselbe Typ wie die anderen Einträge sein)

4) Du teilst "Index" auf
-> Ganzzahlanteil kommt in die Variable idx
-> Nachkommaanteil in die Variable factor.

5) Du interpolierst linear zwischen den Einträgen "idx" und "idx + 1" (aus dem Array) mit dem Faktor "factor".

6) Das Ergebnis der Interpolation ist deine gesuchte Postion am Rand des Quadrats.
7) Fertig.

Lineare Interpolation:

AutoIt

;$a = erster Wert (wird return'ed wenn $s = 0)
;$b = zweiter Wert (wird return'ed wenn $s = 1)
;$s = Interpolationsfaktor (0-1)
Func lerp($a, $b, $s)
     Return( $a + (($b - $a) * $s) )
EndFunc

Texos

Damit würde ich die Diagonale bekommen die bis in die Ecke geht, fehlt nurnoch der Raum dazwischen den man mit PI im laufschritt verkleinern könnte jenachdem welchen winkel man hat?

**Andy**

Ich bin mir nicht ganz sicher, ob ich begriffen habe, um was es eigentlich geht?!
Das wird am X-Y-Problem liegen...wie so oft (siehe Link in meiner Signatur)

WO IST DAS PROBLEM? Den Pfeil zu zeichnen, die Richtung zu ermitteln, die Position der Linie zu zeichnen uswusf. ?
Wenn dein Richtungsanzeiger bis zum Rand des äußeren Quadrates reichen soll, wieso nutzt du nicht einfach nur das Dreieck, dessen Winkel bekannt ist und dessen Kathethe/Gegenkathete IMMER der Radius des Kreises ist?
Du musst auch nur den Winkel 0 bis 45° betrachten, alle anderen "Richtungsanzeiger" lassen sich durch Spiegeln an der X- und Y-Achse ermitteln.
Für a=30° und R=200 werden die Koordinaten auf dem äußeren Quadrat gesucht, dabei ist die X-Koordinate bekannt, nämlich R:
tan(a)= Y / R
0,577 * 200 = Y
115 = Y

Für 180-a ist Y=115
Für 180+a ist Y=-115
Für 360-a ist Y=-115

Jetzt die Frage an die Geometriker...wie sind X und Y bei 90-a, 90+a, 270-a und 270+a....*hust* wer dafür einen Taschenrechner braucht, der sollte besser sein Talent in anderen Bereichen ausbauen

CentuCore

Zitat von Texos

Damit würde ich die Diagonale bekommen die bis in die Ecke geht, fehlt nurnoch der Raum dazwischen den man mit PI im laufschritt verkleinern könnte jenachdem welchen winkel man hat?

Nein, ließ dir meinen Algo durch.
Mit der Interpolation kriegst du auch die Zwischenpunkte je nachdem welchen Winkel du eingibst.

Wenn du was anderes wolltest beschreib bitte was du möchtest.
Das fehlt mir irgendwie.

Texos

Nicht falsch verstehen, ich schau mir deinen Beitrag später in Ruhe an, wollte aber noch was beifügen das mir noch eingefallen ist. Bin noch auf der Arbeit,

Andy: Der Richtungszeiger soll nur am Ende als kleines Symbol dargestellt werden, jenachdem wie der Winkel zum Anderen Spieler ist. Er soll nicht auf dem Radius liegen sondern an den Kanten des Quadrats.

**Andy**

Zitat von Texos

Er soll nicht auf dem Radius liegen sondern an den Kanten des Quadrats.

Ja, das habe ich kapiert
Wie du an die Koordinaten auf der Quadratkante kommst, habe ich dir ja gezeigt. Und die "Pfeillänge" ist ja auch kein Problem. Der Endpunkt ist bekannt und die Pfeillänge wird durch die Koordinate beschrieben, die der Schnittpunkt eines Kreises mit kleinerem Radius und der "Pfeillinie" ergibt.
Kreisfunktion x²+y²=r² und Geradengleichung y=m*x+b mit Steigung m = (y2-y1)/(x2-x1)

**Andy**

So habe ich mir das vorgestellt...

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
$hgui = GUICreate("")
GUISetState(@SW_SHOW)








$center = 200                                                      ;mitte
$Radius1 = 140                                                     ;inneres quadrat
$Radius2 = 190                                                     ;äußeres quadrat
$pi = ATan(1) * 4                                                  ;pi...was sonst
$degToRad = $pi / 180                                              ;deg to rad




_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hgui)
$hPen = _GDIPlus_PenCreate(0xFFFF0000, 5)
_GDIPlus_GraphicsDrawLine($hGraphic, $center-$radius2,$center-$radius2, $center+$radius2, $center-$radius2, $hPen) ;quadrat1
_GDIPlus_GraphicsDrawLine($hGraphic, $center+$radius2, $center-$radius2, $center+$radius2, $center+$radius2, $hPen)     ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center+$radius2, $center+$radius2, $center-$radius2, $center+$radius2, $hPen)     ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center-$radius2, $center+$radius2, $center-$radius2, $center-$radius2, $hPen)       ;quadrat
$hPen = _GDIPlus_PenCreate(0xFF00FF00)
_GDIPlus_GraphicsDrawLine($hGraphic, $center-$radius1, $center-$radius1, $center+$radius1, $center-$radius1, $hPen)       ;quadrat2
_GDIPlus_GraphicsDrawLine($hGraphic, $center+$radius1, $center-$radius1, $center+$radius1, $center+$radius1, $hPen)     ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center+$radius1, $center+$radius1, $center-$radius1, $center+$radius1, $hPen)     ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center-$radius1, $center+$radius1, $center-$radius1, $center-$radius1, $hPen)       ;quadrat




$hPen = _GDIPlus_PenCreate(0xFF0000FF, 2)
$hEndCap = _GDIPlus_ArrowCapCreate(15, 5)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)


For $alpha = 0 To 360 Step 5
    $q = Int($alpha / 45)                                          ;quadrant


    If $q = 0 Or $q = 3 Or $q = 4 Or $q = 7 Then                   ;je quadrant anpassen
        $xfaktor = ($q = 0 Or $q = 3 Or $q = 4 Or $q = 7) * (-2 * ($q = 3 Or $q = 4) + 1);-1, 1 oder 0
        $yfaktor = ($q = 1 Or $q = 2 Or $q = 5 Or $q = 6) * (-2 * ($q = 5 Or $q = 6) + 1);-1, 1 oder 0
        $x1 = $Radius1 * ($xfaktor - Tan($alpha * $degToRad) * $yfaktor) ;inneres quadrat startpunkt
        $y1 = $Radius1 * ($yfaktor - Tan($alpha * $degToRad) * $xfaktor)
        $x2 = $Radius2 * ($xfaktor - Tan($alpha * $degToRad) * $yfaktor);äußeres quadrat endpunkt
        $y2 = $Radius2 * ($yfaktor - Tan($alpha * $degToRad) * $xfaktor)
    Else
        $yfaktor = ($q = 1 Or $q = 2 Or $q = 5 Or $q = 6) * (-2 * ($q = 1 Or $q = 2) + 1);-1, 1 oder 0
        $xfaktor = ($q = 0 Or $q = 3 Or $q = 4 Or $q = 7) * (-2 * ($q = 5 Or $q = 6) + 1);-1, 1 oder 0
        $x1 = $Radius1 / ($xfaktor - Tan($alpha * $degToRad) * $yfaktor)
        $y1 = $Radius1 / ($yfaktor - Tan($alpha * $degToRad) * $xfaktor)
        $x2 = $Radius2 / ($xfaktor - Tan($alpha * $degToRad) * $yfaktor)
        $y2 = $Radius2 / ($yfaktor - Tan($alpha * $degToRad) * $xfaktor)
    EndIf


    Sleep(50)


    _GDIPlus_GraphicsDrawLine($hGraphic, $center + $x1, $center + $y1, $center + $x2, $center + $y2, $hPen) ;quadrat


Next


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE


; Ressourcen freigeben
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()

Alles anzeigen

Man kann natürlich massiv zusammenfassen, um auch die Ausführungsgeschwindigkeit zu erhöhen (darauf kommts bei Spielen meistens an).
Letztendlich bleibt pro Pfeil 1x der Tangens zu berechnen und bissl Bitgeschiebe durch OR und die Multiplikation/Division...
Wenn in einer (Compiler-) Hochsprache der Tangens zu lange dauert (FPTAN Latency ca. 250-300 Takte, Throughput ca. 170 Takte) legt man sich eine LookUpTabelle mit den Tangenswerten von 0-359° in ein Array und greift über den Index zu (maximal 5-10 Takte aus dem Speicher / Prozessorcache)

Nach einigen Optimierungen und Vereinfachungen sieht das doch schon ganz schön schnell aus.
Jetzt werden auch nur 4 Quadranten benutzt...

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
$hgui = GUICreate("")
GUISetState(@SW_SHOW)








$center = 200                        ;mitte
$Radius1 = 140                       ;inneres quadrat
$Radius2 = 190                       ;äußeres quadrat
$pi = ATan(1) * 4                    ;pi...was sonst
$degToRad = $pi / 180                ;deg to rad




_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hgui)
$hPen = _GDIPlus_PenCreate(0xFFFF0000, 5)
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius2, $center - $Radius2, $center + $Radius2, $center - $Radius2, $hPen) ;quadrat1
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius2, $center - $Radius2, $center + $Radius2, $center + $Radius2, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius2, $center + $Radius2, $center - $Radius2, $center + $Radius2, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius2, $center + $Radius2, $center - $Radius2, $center - $Radius2, $hPen) ;quadrat
$hPen = _GDIPlus_PenCreate(0xFF00FF00)
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius1, $center - $Radius1, $center + $Radius1, $center - $Radius1, $hPen) ;quadrat2
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius1, $center - $Radius1, $center + $Radius1, $center + $Radius1, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius1, $center + $Radius1, $center - $Radius1, $center + $Radius1, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius1, $center + $Radius1, $center - $Radius1, $center - $Radius1, $hPen) ;quadrat




$hPen = _GDIPlus_PenCreate(0xFF0000FF, 2)
$hEndCap = _GDIPlus_ArrowCapCreate(15, 5)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)


For $alpha = 0 To 360 Step 5         ;alle winkel
    $q = Int(($alpha + 45) / 90)     ;quadrant ermitteln
    If $alpha >= 315 Then $q = 0


    $tan = Tan($alpha * $degToRad)   ;tangens berechnen


    $q0 = ($q = 0)
    $q1 = ($q = 1)
    $q2 = ($q = 2)
    $q3 = ($q = 3)
    $q1q3 = ($q1 Or $q3)
    $q0q2 = ($q0 Or $q2)


    If $q0q2 Then                    ;je quadrant anpassen
        $xfaktor = $q0q2 * (-2 * $q2 + 1) ;-1, 1 oder 0
        $yfaktor = $q1q3 * (-2 * $q3 + 1) ;-1, 1 oder 0
        $t1 = ($xfaktor - $tan * $yfaktor)
        $t2 = ($yfaktor - $tan * $xfaktor)
        $x1 = $Radius1 * $t1         ;inneres quadrat startpunkt
        $y1 = $Radius1 * $t2
        $x2 = $Radius2 * $t1         ;äußeres quadrat endpunkt
        $y2 = $Radius2 * $t2
    Else
        $yfaktor = $q1q3 * (-2 * $q1 + 1);-1, 1 oder 0
        $xfaktor = $q0q2 * (-2 * $q3 + 1);-1, 1 oder 0
        $t1 = ($xfaktor - $tan * $yfaktor)
        $t2 = ($yfaktor - $tan * $xfaktor)
        $x1 = $Radius1 / $t1         ;inneres quadrat startpunkt
        $y1 = $Radius1 / $t2
        $x2 = $Radius2 / $t1         ;äußeres quadrat endpunkt
        $y2 = $Radius2 / $t2
    EndIf


    Sleep(50)


    _GDIPlus_GraphicsDrawLine($hGraphic, $center + $x1, $center + $y1, $center + $x2, $center + $y2, $hPen) ;quadrat


Next


Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE


; Ressourcen freigeben
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()

Alles anzeigen

**Andy**

Hi,
ich vermute mal, so soll es letztendlich funktionieren. Mausposition abfragen und den Pfeil zeichnen.
Das Puffergedöns um den Pfeil wieder zu "löschen" und die Abfrage, ob die Mausposition innerhalb des Fensters ist, überlasse ich mal dem TE.

AutoIt

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
$hgui = GUICreate("")
GUISetState(@SW_SHOW)








$center = 200                         ;mitte Fenster
$Radius1 = 140                        ;inneres quadrat
$Radius2 = 190                        ;äußeres quadrat
$pi = ATan(1) * 4                     ;pi...was sonst
$degToRad = $pi / 180                 ;deg to rad




_GDIPlus_Startup()
$hGraphic = _GDIPlus_GraphicsCreateFromHWND($hgui)
$hPen = _GDIPlus_PenCreate(0xFFFF0000, 5)
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius2, $center - $Radius2, $center + $Radius2, $center - $Radius2, $hPen) ;quadrat1
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius2, $center - $Radius2, $center + $Radius2, $center + $Radius2, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius2, $center + $Radius2, $center - $Radius2, $center + $Radius2, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius2, $center + $Radius2, $center - $Radius2, $center - $Radius2, $hPen) ;quadrat
$hPen = _GDIPlus_PenCreate(0xFF00FF00)
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius1, $center - $Radius1, $center + $Radius1, $center - $Radius1, $hPen) ;quadrat2
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius1, $center - $Radius1, $center + $Radius1, $center + $Radius1, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center + $Radius1, $center + $Radius1, $center - $Radius1, $center + $Radius1, $hPen) ;quadrat
_GDIPlus_GraphicsDrawLine($hGraphic, $center - $Radius1, $center + $Radius1, $center - $Radius1, $center - $Radius1, $hPen) ;quadrat




$hPen = _GDIPlus_PenCreate(0xFF0000FF, 2)
$hEndCap = _GDIPlus_ArrowCapCreate(15, 5)
_GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)




$opt = Opt("MouseCoordMode")


Opt("MouseCoordMode", 2)


Do                                    ;Pfeil folgt Mauscursor


    $maus_x = -(MouseGetPos(0) - $center)
    $maus_y = (MouseGetPos(1) - $center)


    $alpha = (atan2($maus_y, $maus_x)) / $degToRad + 180


    $q = Int(($alpha + 45) / 90)      ;quadrant ermitteln
    If $alpha >= 315 Then $q = 0


    $tan = Tan($alpha * $degToRad)    ;tangens berechnen


    $q0 = ($q = 0)
    $q1 = ($q = 1)
    $q2 = ($q = 2)
    $q3 = ($q = 3)
    $q1q3 = ($q1 Or $q3)
    $q0q2 = ($q0 Or $q2)


    If $q0q2 Then                     ;je quadrant anpassen
        $xfaktor = $q0q2 * (-2 * $q2 + 1) ;-1, 1 oder 0
        $yfaktor = $q1q3 * (-2 * $q3 + 1) ;-1, 1 oder 0
        $t1 = ($xfaktor - $tan * $yfaktor)
        $t2 = ($yfaktor - $tan * $xfaktor)
        $x1 = $Radius1 * $t1          ;inneres quadrat startpunkt
        $y1 = $Radius1 * $t2
        $x2 = $Radius2 * $t1          ;äußeres quadrat endpunkt
        $y2 = $Radius2 * $t2
    Else
        $yfaktor = $q1q3 * (-2 * $q1 + 1);-1, 1 oder 0
        $xfaktor = $q0q2 * (-2 * $q3 + 1);-1, 1 oder 0
        $t1 = ($xfaktor - $tan * $yfaktor)
        $t2 = ($yfaktor - $tan * $xfaktor)
        $x1 = $Radius1 / $t1          ;inneres quadrat startpunkt
        $y1 = $Radius1 / $t2
        $x2 = $Radius2 / $t1          ;äußeres quadrat endpunkt
        $y2 = $Radius2 / $t2
    EndIf


    _GDIPlus_GraphicsDrawLine($hGraphic, $center + $x1, $center + $y1, $center + $x2, $center + $y2, $hPen) ;quadrat


Until GUIGetMsg() = $GUI_EVENT_CLOSE




; Ressourcen freigeben
_GDIPlus_PenDispose($hPen)
_GDIPlus_GraphicsDispose($hGraphic)
_GDIPlus_Shutdown()




Func atan2($y, $x)
    Return (2 * ATan($y / ($x + Sqrt($x * $x + $y * $y))))
EndFunc                               ;==>atan2

Alles anzeigen

Texos

Hui, das sieht super aus, super Beispielcode und danke auch an die anderen.