Listenfeld mittels klick Überschrift sortieren

DerSchatten

Ich möchte gerne ein Listenfeld mittels den Spaltenüberschriften sortieren.

Dazu habe ich die Funktion _GUICtrlListView_SimpleSort gefunden: https://www.autoitscript.com/autoit3/docs/l…_SimpleSort.htm

Wäre diese Funktion: _WM_NOTIFY genau das?
Mir ist nur nicht ganz klar wie die aufgerufen wird?

**chip**

Schau dir das Beispiel an. Da wird genau das gezeigt was du willst.

Zeitriss

_WM_NOTIFY wird durch folgende Zeile regestriert:

AutoIt

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

Sobald sie regestriert ist wartet sie auf Events und löst dann die Funktion _WM_NOTIFY aus.
Folgende Zeilen prüfen dann ob es das richtige Control ($hWndFrom = $g_idListView) und das Richtige Event ist
($iCode = $LVN_COLUMNCLICK) und lösen dann die Sortierfunktion(_GUICtrlListView_SimpleSort) aus:

AutoIt

Local $hWndListView = $g_idListView
    If Not IsHWnd($g_idListView) Then $hWndListView = GUICtrlGetHandle($g_idListView)
    Local $tNMHDR = DllStructCreate($tagNMLISTVIEW, $lParam)
    Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    Local $iCode = DllStructGetData($tNMHDR, "Code")
    Switch $hWndFrom
        Case $hWndListView
            Switch $iCode
                Case $LVN_COLUMNCLICK ; A column was clicked
                    _GUICtrlListView_SimpleSort($hWndListView, $g_bSortSense, DllStructGetData($tNMHDR, "SubItem")) ; Sort direction for next sort toggled by default
            EndSwitch
    EndSwitch

Alles anzeigen

Hier wird auf das "$LVN_COLUMNCLICK" Event vom Control "$g_idListView" gewartet, was dem Klicken auf die Spaltenüberschrift entspricht.
Beim Googlen nach "WM_NOTIFY" wirst du auch folgendes finden was vielleicht zum Verständniss beiträgt:
https://msdn.microsoft.com/en-us/library/…3(v=vs.85).aspx

DerSchatten

geht das nicht einfacher?

**Kanashius**

Das ist doch einfach. Im vergleich zu anderen Hochsprachen...
Noch einfacher geht nicht.

Zeitriss

Man könnte auch die Funktion etwas umschreiben...

AutoIt

#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
   #forceref $hWnd, $iMsg, $wParam
   Local $tNMHDR = DllStructCreate($tagNMLISTVIEW, $lParam)
   Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
   Local $iCode = DllStructGetData($tNMHDR, "Code")
   Static Local $g_bSortSense = True
   If (_WinAPI_GetClassName($hWndFrom) = "SysListView32") and ($iCode = $LVN_COLUMNCLICK) Then
	  _GUICtrlListView_SimpleSort($hWndFrom, $g_bSortSense, DllStructGetData($tNMHDR, "SubItem"))
   EndIf
    Return $GUI_RUNDEFMSG
EndFunc   ;==>_WM_NOTIFY

Alles anzeigen

Sollte eigentlich dafür sorgen dass alle von dir erstellten "SysListView32" beim klicken auf den Title die Werte sortieren.

Kannst ja mal ausprobieren ob es klappt, habe nicht die Zeit um es groß zu testen.
Und viel einfacher als C&P geht es nun wirklich nicht mehr.

mfg
Zeitriss

DerSchatten

Funkt leider nicht.

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListview.au3>


Global $sDBFile = @ScriptDir & '\produkte.txt'
Global $sHeader = 'Produkt-Bezeichnung|Produkt-ID|Version|Dat.Inst.|Lokation'
Global $aHeader = StringSplit($sHeader, '|') ; Überschriften-Array
Global $bSortSense = False


$Form1 = GUICreate("Installierte Produkte - Windows 7 32bit", 965, 250)


Global $idListView = GUICtrlCreateListView($sHeader, 0, 0, 965, 250)
Global $hListView = GUICtrlGetHandle($idListView)


_GUICtrlListView_SetColumnWidth($idListView, 0, 330)
_GUICtrlListView_SetColumnWidth($idListView, 1, 50)
_GUICtrlListView_SetColumnWidth($idListView, 2, 50)
_GUICtrlListView_SetColumnWidth($idListView, 3, 50)
_GUICtrlListView_SetColumnWidth($idListView, 4, 400)


_GUICtrlListView_RegisterSortCallBack($idListView)


GUISetState(@SW_SHOW)
GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")


If FileExists($sDBFile) Then Load()


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit


		Case $idListView
			Switch $iCode
				Case $LVN_COLUMNCLICK ; A column was clicked
				_GUICtrlListView_SimpleSort($hWndListView, $g_bSortSense, DllStructGetData($tNMHDR, "SubItem"))
			EndSwitch


   EndSwitch
WEnd


Func Load()
	Local $hFile, $sContent, $aNewItems
	$hFile = FileOpen($sDBFile, 0)
	If $hFile <> -1 Then
		$sContent = FileRead($hFile)
		FileClose($hFile) ; Datei schließen
		$sContent = StringTrimRight($sContent, 2)
		$aNewItems = StringSplit($sContent, @CRLF, 1)
		If Not IsArray($aNewItems) Then Return
		_GUICtrlListView_BeginUpdate($hListView)
		For $i = 1 To $aNewItems[0]
			GUICtrlCreateListViewItem($aNewItems[$i], $idListView)
		Next
		_GUICtrlListView_EndUpdate($hListView)
	EndIf
EndFunc


Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
	#forceref $hWnd, $iMsg, $wParam
	Local $tNMHDR = DllStructCreate($tagNMLISTVIEW, $lParam)
	Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
	Local $iCode = DllStructGetData($tNMHDR, "Code")
	Static Local $g_bSortSense = True
	If (_WinAPI_GetClassName($hWndFrom) = "SysListView32") and ($iCode = $LVN_COLUMNCLICK) Then
		_GUICtrlListView_SimpleSort($hWndFrom, $g_bSortSense, DllStructGetData($tNMHDR, "SubItem"))
	EndIf
	Return $GUI_RUNDEFMSG
EndFunc

Alles anzeigen

Line 35

Switch $iCode
Switch ^ ERROR

Error: Variable used without being declared

**Oscar**

Die einfachste Variante ist wohl, die UDF-Funktion "_GUICtrlListView_RegisterSortCallBack" zu benutzen:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>


Global $sHeader = 'Artikelnummer|Nummer|Baureihe'
Global $hGui = GUICreate('Listview-Sort', 600, 480)


Global $idListView = GUICtrlCreateListView($sHeader, 0, 0, 600, 400, $LVS_SHOWSELALWAYS)


Global $sItem = ''
For $iArtNr = 0 To 99
	$sItem = $iArtNr & '|' & Random(10000, 99999, 1) & '|' & Random(1000, 9999, 1)
	GUICtrlCreateListViewItem($sItem, $idListView)
Next


_GUICtrlListView_RegisterSortCallBack($idListView)
GUISetState(@SW_SHOW, $hGui)
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUICtrlListView_UnRegisterSortCallBack($idListView)
			Exit
		Case $idListView
			_GUICtrlListView_SortItems($idListView, GUICtrlGetState($idListView))
	EndSwitch
WEnd

Alles anzeigen

Aufpassen muss man nur, wenn die zu sortierenden Daten nicht von links nach rechts sortiert werden sollen (wie z.B. beim Datum).
In dem Fall muss man eine eigene Sortier-Funktion einbauen.

Zeitriss

Deine Zeilen 34 und 38 sind dort komplett deplaziert.
Lösch die einfach raus.

Edit: Nimm die Varriante von Oskar, die ist viel besser

mfg
Zeitriss

DerSchatten

Ahh, mit der Variante von Oskar seh ich auch die Pfeilchen nun.

Super, danke!

Wie kann ich jetzt noch beim öffnen automatisch nach der ersten Spalte sortieren?

Zeitriss

Die Pfeile gibt es bei _GUICtrlListView_SimpleSort nicht benütze statdessen _GUICtrlListView_SortItems wie Oscar es
gemacht hat.

Edit:

Zitat von DerSchatten

Wie kann ich jetzt noch beim öffnen automatisch nach der ersten Spalte sortieren?

mit folgender Codezeile:

AutoIt

_GUICtrlListView_SortItems($idListView,0)

Achte allerding darauf, dass diese Zeile nach _GUICtrlListView_RegisterSortCallBack kommt.

**Oscar**

Und für den Fall, dass in dem Listview irgendwo eine Datums-Spalte vorkommt, habe ich mal schnell eine Funktion zum umsortieren geschrieben:

AutoIt

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <ListViewConstants.au3>


Global $iDateColumn = 0 ; hier angeben welche Spalte die Datums-Spalte sein soll
Global $sHeader = 'Datum|Artikelnummer|Nummer|Baureihe'
Global $hGui = GUICreate('Listview-Sort', 600, 480)


Global $idListView = GUICtrlCreateListView($sHeader, 0, 0, 600, 400, $LVS_SHOWSELALWAYS)


; hier ein paar Zufallsdaten generieren
Global $sItem = ''
For $iArtNr = 0 To 99
	$sDate = StringFormat('%02i.%02i.%04i', Random(1, 28, 1), Random(1, 12, 1), Random(2000, 2016, 1))
	$sItem = $sDate & '|' & $iArtNr & '|' & Random(10000, 99999, 1) & '|' & Random(1000, 9999, 1)
	GUICtrlCreateListViewItem($sItem, $idListView)
Next
_GUICtrlListView_SetColumnWidth($idListView, 0, 110)
; Zufallsdaten bereit


_GUICtrlListView_RegisterSortCallBack($idListView)
GUISetState(@SW_SHOW, $hGui)
While 1
	Switch GUIGetMsg()
		Case $GUI_EVENT_CLOSE
			_GUICtrlListView_UnRegisterSortCallBack($idListView)
			Exit
		Case $idListView
			_GUICtrlListView_BeginUpdate($idListView)
			$iCol = GUICtrlGetState($idListView)
			If $iCol = $iDateColumn Then _ChangeDateFormat($idListView, 0, 1) ; temporaer das Datum nach Jahr.Monat.Tag umwandeln
			_GUICtrlListView_SortItems($idListView, $iCol) ; Spalte sortieren
			If $iCol = $iDateColumn Then _ChangeDateFormat($idListView, 0, 0) ; hier das Datum wieder nach Tag.Monat.Jahr umwandeln
			_GUICtrlListView_EndUpdate($idListview)
	EndSwitch
WEnd


Func _ChangeDateFormat($idListView, $iCol, $iDir)
	Local $iItemCount = _GUICtrlListView_GetItemCount($idListView)
	If $iItemCount = 0 Then Return SetError(1, 0, False)
	Local $iColCount = _GUICtrlListView_GetColumnCount($idListView)
	If $iColCount = 0 Then Return SetError(2, 0, False)
	If $iCol > $iColCount Then Return SetError(3, 0, False)
	Local $sText = ''
	For $iIndex = 0 To $iItemCount - 1
		$sText = _GUICtrlListView_GetItemText($idListView, $iIndex, $iCol)
		If $iDir Then
			$sText = StringRegExpReplace($sText, '(\d{2}).(\d{2}).(\d{4})', '$3.$2.$1') ; Tag.Monat.Jahr -> Jahr.Monat.Tag
		Else
			$sText = StringRegExpReplace($sText, '(\d{4}).(\d{2}).(\d{2})', '$3.$2.$1') ; Jahr.Monat.Tag -> Tag.Monat.Jahr
		EndIf
		_GUICtrlListView_SetItemText($idListView, $iIndex, $sText, $iCol)
	Next
	Return True
EndFunc   ;==>_ChangeDateFormat

Alles anzeigen

DerSchatten

Zitat von Zeitriss
mit folgender Codezeile:
AutoIt
_GUICtrlListView_SortItems($idListView,0)
Achte allerding darauf, dass diese Zeile nach _GUICtrlListView_RegisterSortCallBack kommt.

Das funktioniert leider nur halb so toll. Wenn ich das Script starte wird zwar die Spalte sortiert. Klicke ich dann auf die Spaltenüberschrift wird zuerst nochmal aufsteigend sortiert (Der Pfeil bleibt in der gleichen Richtung) und wird erst nach dem zweiten Klick drauf absteigend sortiert.

Pfuscht da vielleicht diese Zeile hier rein:

_GUICtrlListView_SortItems($idListView, GUICtrlGetState($idListView))

Zeitriss

Hi,

Zitat von DerSchatten

Klicke ich dann auf die Spaltenüberschrift wird zuerst nochmal aufsteigend sortiert (Der Pfeil bleibt in der gleichen Richtung) und wird erst nach dem zweiten Klick drauf absteigend sortiert.

Kann das Problem nicht nachvolziehen.
Ein Beispielscript, weleches das Problem zeigt wäre hilfreich.

Zitat von DerSchatten

Pfuscht da vielleicht diese Zeile hier rein:

_GUICtrlListView_SortItems($idListView, GUICtrlGetState($idListView))

Kommt darauf an wo sich die Zeile befindet.

Edit:
Benützt du _GUICtrlListView_SimpleSort() oder _GUICtrlListView_SortItems() für das Sortieren am Anfang?
Wenn ersteres der Fall ist reicht es, wenn du auf _GUICtrlListView_SortItems() welchselst.

mfg

Zeitriss

**Kanashius**

Nein. Da fuscht nichts rein. Das Sortieren durch dein Programm zeigt nur nicht, dass der User sortiert hat. (Könnte ja auch unerwünscht sein.)
Wenn dich das wirklich stört kannst du ja statt des sortierens einen Klick auf die Spalte simulieren.

Zeitriss

Zitat von Kanashius

Das Sortieren durch dein Programm zeigt nur nicht, dass der User sortiert hat.

Doch _GUICtrlListView_SortItems hat den selben effekt, wie ein Mausklick auf die Überschrift.
Vorausgesetzt er hat die Methode von Oscar ohne die Datums-umsortierung übernommen, ansonsten müsste er natürlich auch das berücksichtigen.

mfg

Zeitriss

DerSchatten

Sieht so aus das ganze:

C

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIListview.au3>


Global $sDBFile = @ScriptDir & '\produkte.txt'
Global $sHeader = 'Produkt-Bezeichnung|Produkt-ID|Version|Dat.Inst.|Lokation'
Global $aHeader = StringSplit($sHeader, '|')
Global $bSortSense = False


$Form1 = GUICreate("Installierte Produkte - Windows 7 32bit", 974, 600)


Global $idListView = GUICtrlCreateListView($sHeader, 0, 0, 965, 600)
Global $hListView = GUICtrlGetHandle($idListView)


_GUICtrlListView_SetColumnWidth($idListView, 0, 330)
_GUICtrlListView_SetColumnWidth($idListView, 1, 50)
_GUICtrlListView_SetColumnWidth($idListView, 2, 50)
_GUICtrlListView_SetColumnWidth($idListView, 3, 50)
_GUICtrlListView_SetColumnWidth($idListView, 4, 400)


_GUICtrlListView_RegisterSortCallBack($idListView)


GUISetState(@SW_SHOW)


If FileExists($sDBFile) Then Load()


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit


		Case $idListView
			_GUICtrlListView_SortItems($idListView, GUICtrlGetState($idListView))


   EndSwitch
WEnd


Func Load()
	Local $hFile, $sContent, $aNewItems
	$hFile = FileOpen($sDBFile, 0)
	If $hFile <> -1 Then
		$sContent = FileRead($hFile)
		FileClose($hFile) ; Datei schließen
		$sContent = StringTrimRight($sContent, 2)
		$aNewItems = StringSplit($sContent, @CRLF, 1)
		If Not IsArray($aNewItems) Then Return
		_GUICtrlListView_BeginUpdate($hListView)
		For $i = 1 To $aNewItems[0]
			GUICtrlCreateListViewItem($aNewItems[$i], $idListView)
		Next
		_GUICtrlListView_EndUpdate($hListView)
	EndIf
EndFunc

Alles anzeigen

Datum sortiere ich keines. Sind alles Textfelder.

Zeitriss

Hi,

Kann immer noch nicht den beschriebenen Fehler entdecken, habe die Sortierfunktion Testweise hier eingefügt:

AutoIt

_GUICtrlListView_RegisterSortCallBack($idListView)


GUISetState(@SW_SHOW)


If FileExists($sDBFile) Then Load()
_GUICtrlListView_SortItems($idListView, 0)

Funktioniert alles prima.
Hast du vielleicht vor der Load() Funktion Sortiert?

mfg

Zeitriss

**Oscar**

Mal ein kleines Zitat aus der Hilfe:

Zitat von AutoIt-Hilfe

For each call to _GUICtrlListView_RegisterSortCallBack() there must be a call to _GUICtrlListView_UnRegisterSortCallBack() when done (before exit).

It is up to the user to call _GUICtrlListView_UnRegisterSortCallBack() for each _GUICtrlListView_RegisterSortCallBack() call made.

DerSchatten

Ich hab die Sortierung jetzt unten in die LOAD-Funktion gepackt.
jetzt funktionierts.

Code

Func Load()
	Local $hFile, $sContent, $aNewItems
	$hFile = FileOpen($sDBFile, 0)
	If $hFile <> -1 Then
		$sContent = FileRead($hFile)
		FileClose($hFile) ; Datei schließen
		$sContent = StringTrimRight($sContent, 2)
		$aNewItems = StringSplit($sContent, @CRLF, 1)
		If Not IsArray($aNewItems) Then Return
		_GUICtrlListView_BeginUpdate($hListView)
		For $i = 1 To $aNewItems[0]
			GUICtrlCreateListViewItem($aNewItems[$i], $idListView)
		Next
		_GUICtrlListView_SortItems($idListView, 0)
		_GUICtrlListView_EndUpdate($hListView)
	EndIf
EndFunc

Alles anzeigen

UnRegisterSortCallBack hat auch noch gefehlt. danke für den Hinweis.