Ein Process - unterschiedliche PID's

AutoItler

Hallo, Ihe alle,

in meinem Script (unten beigefügt) starte ich den Windows Explorer mit Run() und lasse mir die PID via Rückgabewert übergeben.
Dieser Rückgabewert soll dazu dienen, den speziellen Prozess mittels ProzessClose(#ID) wieder zu schließen.
Zu meinem großen Erstaunen stellte ich fest, dass der Prozess nicht geschlossen wird. Bei der Fehleranalyse fiel mir auf, dass PID, ermittelt durch Run(), und die im Taskmgr ausgewiesene PID nicht identisch sind. Ich habe dafür keine Erklärung, bin auch nicht so der Profi vor dem Herrn.
Vielleicht kann mir jemand erklären, wie es dazu kommen und wie ich die richtige PID zum Weiterbenutzen ermitteln kann.

Hier der Code:

AutoIt

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\..\..\Icons\Burning.ico
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Run_Tidy=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <Misc.au3>
#include <Constants.au3>
#include <WinAPI.au3>


Opt("TrayIconDebug", 1)
Opt("WinWaitDelay", 500)
Opt("WinTitleMatchMode", 2)


Local $folder = "Burning", $width = 450, $hight = 450


Local $hGui = GUICreate($folder, $width, $hight), $msg, $hDll = DllOpen("user32.dll")


Local $hPid = Run(@WindowsDir & "\explorer.exe /N, " & @HomeDrive & @HomePath & "\DeskSub\" & $folder, "", @SW_HIDE)
#cs
Die ermittelte PID in $hPid stimmt nicht mit der im Taskmgr ausgewiesenen PID für diesen Process überein
#ce
WinWait("[CLASS:CabinetWClass]", "", 5)
Local $hChild = WinGetHandle("[CLASS:CabinetWClass]", "")
_WinAPI_SetWindowLong($hChild, -20, $WS_EX_TOOLWINDOW)
$NEXSTYLE = DllCall($hDll, "int", "GetWindowLong", "hwnd", $hChild, "int", 236)
DllCall($hDll, "int", "SetWindowLong", "hwnd", $hChild, "int", 236, "int", BitOR($NEXSTYLE[0], $WS_EX_MDICHILD))
DllCall($hDll, "int", "SetParent", "hwnd", $hChild, "hwnd", $hGui)
WinActivate($hChild)
Send("{F11}")
Sleep(100)
WinMove($hChild, "", 0, 0, $width, $hight)
GUISetState(@SW_SHOW, $hGui)
WinSetState($hChild, "", @SW_SHOW)
WinActivate($hGui)
While 1
	$msg = GUIGetMsg()
	If $msg = $GUI_EVENT_CLOSE Then ExitLoop
	Sleep(10)
WEnd
DllClose($hDll)
GUIDelete($hGui)


ProcessClose($hPid) ; Diese Funktion führt nicht zu dem gewünschten Resultat


Exit

Alles anzeigen

Vielen Dank schon mal vorab.

**BugFix**

Zitat von AutoItler

Zu meinem großen Erstaunen stellte ich fest, dass der Prozess nicht geschlossen wird. Bei der Fehleranalyse fiel mir auf, dass PID, ermittelt durch Run(), und die im Taskmgr ausgewiesene PID nicht identisch sind.

Das liegt daran, dass der Prozeß die "explorer.exe" ist. Das ist ein Windows-systemprozeß, der auch immer läuft. Du öffnest nur eine weitere Instanz dieses Prozesses. Mit ProcessList("explorer.exe") bekommst du ein Array mit allen PID aller Instanzen.

Für "normale" Prozesse findest du in der Regel nur eine PID.

AutoItler

Danke für die Antwort, BugFix.
Nun bleibt für mich die weiterführende Frage: Wie kann ich die PID der durch das Script geöffneten Instanz ermitteln um diese wieder zu schließen "ProcessClose($PID)".
Oder gibt es vielleicht einen anderen Weg, diese Inszanz zu schließen?
Dank schon mal für einen eventuellen Tip ....

**Bitnugger**

Schaue dir mal an, was ich hier für Dich gebastelt habe...

Spoiler anzeigen

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\..\..\Icons\Burning.ico
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_Run_Tidy=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


;-- TIME_STAMP   2016-09-03 02:19:45   v 1.1


#include <Array.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>
#include <Misc.au3>
#include <Constants.au3>
#include <WinAPI.au3>
#include <WinAPIProc.au3>


#NoTrayIcon


Opt("MustDeclareVars", 1)
Opt("TrayIconDebug", 1)
Opt("WinWaitDelay", 500)
Opt("WinTitleMatchMode", 2)


Local $hWnd = WinGetHandle('[TITLE:Program Manager]')
Local $sClassName = _WinAPI_GetClassName($hWnd)
ConsoleWrite('! ClassName der ersten mit Windows gestarten Explorer-Instanz: ' & $sClassName & @CRLF)
ConsoleWrite('! ProcessName = ' & _WinAPI_GetProcessName(WinGetProcess($hWnd)) & @CRLF)


Local $sFolder = @HomeDrive & @HomePath & '\DeskSub\Burning', $width = 800, $hight = 480
Local $hGUI = GUICreate($sFolder, $width, $hight), $msg


Run(@WindowsDir & "\explorer.exe /N, " & $sFolder, "", @SW_HIDE)
If @error Then Exit MsgBox(0, '', 'Fehler: Run() zickt mal wieder rum...') + 1
Local $iMyExplorerInstance = WinList('[CLASS:CabinetWClass]')[0][0] + 1 ; Hier bekommen wir die Anzahl der bereits geöffneten Instanzen - und + 1 ist dann unsere Instanz
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iMyExplorerInstance --> " & $iMyExplorerInstance & @LF)
Local $hChild = WinWait('[CLASS:CabinetWClass; INSTANCE:' & $iMyExplorerInstance & ']', '', 10) ; Dies ist unser Explorer-Window
If $hChild = 0 Then Exit MsgBox(0, '', 'Fehler: Explorer wurde nicht gestartet...') + 2
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $hChild              --> " & $hChild & @LF)
Local $iPID = WinGetProcess($hChild) ; PID von unserer Explorer-Instanz holen
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iPID                --> " & $iPID & @LF)
$sClassName = _WinAPI_GetClassName($hChild)
ConsoleWrite('! ClassName der von uns gestarteten Explorer-Instanz: ' & $sClassName & @CRLF)
ConsoleWrite('! ProcessName = ' & _WinAPI_GetProcessName($iPID) & @CRLF)


Local $EXTSTYLE = _WinAPI_GetWindowLong($hChild, $GWL_WNDPROC)
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $EXTSTYLE            --> " & $EXTSTYLE & @LF)
Local $iRes = _WinAPI_SetWindowLong($hChild, $GWL_EXSTYLE, BitOR($EXTSTYLE, $WS_EX_TOOLWINDOW, $WS_EX_MDICHILD)) ; Change it to a tool window and set it as a child window included in its parent window (simulation not real MDI).
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iRes                --> " & $iRes & @LF)
$iRes = _WinAPI_SetParent($hChild, $hGUI) ; Changes the parent window of the specified child window
ConsoleWrite("@@ Debug line" & @TAB & @ScriptLineNumber & "   var: $iRes                --> " & $iRes & @LF)
; Send('{LWIN}{UP}') 	; Explorer-Windows können (seit Vista?) via Send() nur mit "Windows key + Up arrow" maximiert werden.
; Sleep(100)			; Doch wofür gibt es die Funktion WinSetState()?
; WinSetState($hChild, '', @SW_SHOW + @SW_MAXIMIZE) ; Explorer-Window sichtbar machen und maximieren
WinSetState($hChild, '', @SW_SHOW) ; Explorer-Window sichtbar machen


WinMove($hChild, "", 0, 0, $width, $hight) ; Send() und @SW_MAXIMIZE sind hiermit aber überflüssig!
GUISetState(@SW_SHOW, $hGUI)
WinActivate($hGUI)


While 1
	$msg = GUIGetMsg()
	If $msg = $GUI_EVENT_CLOSE Then ExitLoop
	Sleep(10)
WEnd


ProcessClose($iPID) ; Diese Funktion führt zum gewünschten Resultat  ;-)
GUIDelete($hGUI)
Exit 0

Alles anzeigen