gibts MsgBoxen in anderer als der Systemsprache?

WiDDoW

hallo zusammen,

hab mal ne kurze frage - hab zwar nicht viel Hoffnung, dass funktioniert was ich vorhabe - aber vielleicht hat ja jemand eine idee

habe ein fertiges Script wo etliche MsgBoxen beinhaltet - und jetzt ist mir eingefallen, dass es sein könnte das der Benutzer dieses Script an fremden Rechnern benutzt.
So könnte es sein, dass auf einem Russich eingestelltem PC meine MsgBox kommt und der user jetzt russich können muss um die Richtigen buttons zu drücken.

deswegen meine Frage:
kann ich für mein Script die Systemsprache zB in ENG überschreiben? oder muss ich jede msgBox in eine GUI umwandeln um auch die Buttons beschriften zu können?

hoffe ihr versteht was ich mein.
danke WiDDoW

**autoiter**

Hallo @WiDDoW

Entweder du baust einfach eine eigene GUI, die du dann mit deinen gewünschten Inhalten füllst und aufrufst - so viel Arbeit ist das nicht.
Du kannst auch z.B. folgende UDF benutzen - die ist super: https://www.autoitscript.com/forum/topic/10…rsion-9-aug-16/

**UEZ**

Du könntest immer Englisch als Sprache wählen:

AutoIt

#include <WinAPI.au3>
Opt("MustDeclareVars", 1)
Global $hHookMsgBox
_MsgBoxEnglish(0, "Title", "Text")
_MsgBoxEnglish(1, "Title", "Text")
_MsgBoxEnglish(2, "Title", "Text")
_MsgBoxEnglish(3, "Title", "Text")
_MsgBoxEnglish(4, "Title", "Text")
_MsgBoxEnglish(5, "Title", "Text")
_MsgBoxEnglish(6, "Title", "Text")
_MsgBoxEnglish(7, "Title", "Text")
#region English Button text for MsgBox!!
;##########################################################
Func _MsgBoxEnglish($flag, $title, $text, $timeout = 0, $hwnd = 0)
 Local $hProcMsgBox = DllCallbackRegister("CbtHookProcMsgBox", "int", "int;int;int")
 Local $TIDMsgBox = _WinAPI_GetCurrentThreadId()
 $hHookMsgBox = _WinAPI_SetWindowsHookEx($WH_CBT, DllCallbackGetPtr($hProcMsgBox), 0, $TIDMsgBox)
 Local $iRet = MsgBox($flag, $title, $text, $timeout, $hwnd)
 _WinAPI_UnhookWindowsHookEx($hHookMsgBox)
 DllCallbackFree($hProcMsgBox)
 Return $iRet
EndFunc   ;==>_MsgBoxEnglish
Func CbtHookProcMsgBox($nCode, $wParam, $lParam, $hHookMsgBox)
 Local $RET = 0, $hBitmap = 0, $xWnd = 0
 Local $sButtonText
 If $nCode < 0 Then
  $RET = _WinAPI_CallNextHookEx($hHookMsgBox, $nCode, $wParam, $lParam)
  Return $RET
 EndIf
 Switch $nCode
  Case 5 ;5=HCBT_ACTIVATE
   _WinAPI_SetDlgItemText($wParam, 1, "OK")
   _WinAPI_SetDlgItemText($wParam, 2, "Cancel")
   _WinAPI_SetDlgItemText($wParam, 3, "&Abort")
   _WinAPI_SetDlgItemText($wParam, 4, "&Retry")
   _WinAPI_SetDlgItemText($wParam, 5, "&Ignore")
   _WinAPI_SetDlgItemText($wParam, 6, "&Yes")
   _WinAPI_SetDlgItemText($wParam, 7, "&No")
   _WinAPI_SetDlgItemText($wParam, 8, "Help")
   _WinAPI_SetDlgItemText($wParam, 10, "&Try Again")
   _WinAPI_SetDlgItemText($wParam, 11, "&Continue")
 EndSwitch
 Return
EndFunc   ;==>CbtHookProcMsgBox
Func _WinAPI_SetDlgItemText($hDlg, $nIDDlgItem, $lpString)
 Local $aRet = DllCall('user32.dll', "int", "SetDlgItemText", _
   "hwnd", $hDlg, _
   "int", $nIDDlgItem, _
   "str", $lpString)
 Return $aRet[0]
EndFunc   ;==>_WinAPI_SetDlgItemText
;##########################################################
#endregion English Button text for MsgBox!!

Alles anzeigen

**autoiter**

Phänomenal, was manche hier ständig raushauen.
Das Skript habe ich mir mal gespeichert.

WiDDoW

find es auch nicht schlecht - immer English ist genau was ich will.

ich versuch mal ob ichs auch für die Input Boxen anpassen kann

danke mal bis hier her

--Edit----

da steht ja jetzt schon nur "ok" und "cancel" für meine zwecke also perfekt
aber trotzdem irgendwie perfide dass es in der MsgBox "abbrechen" und in der inputBox "cancel" heißt

**Kanashius**

Zitat von WiDDoW

aber trotzdem irgendwie perfide dass es in der MsgBox "abbrechen" und in der inputBox "cancel" heißt

Die Erklärung ist recht einfach. Die MsgBox ist von Windows und wird über DLLCalls erstellt und wird dann übergeben.
Die InputBox ist von AutoIt. Das ist eine Gui, die von AutoIt erstellt wird und deshalb die Beschriftung der AutoIt-Entwickler hat, welche Englisch nutzen. Die haben dabei nicht andere Sprachen bedacht