Frage zu ListView-Handle: Warum geht es manchmal verloren?

**autoiter**

Hi Leute,

ich bastele gerade an einem Programm und dabei ist mir an neuer Stelle ein Problem untergekommen, dass ich nun zwar schon umgehen kann, aber doch gerne verstehen würde.

Bei meinem Programm funktionierte das Hin und Her springen zwischen markierten Suchbegriffen in der Listview nicht. Erst als ich das Bsp für euch erstellt habe, konnte ich mein Problem lösen, nur eben nicht verstehen.

Spoiler anzeigen

AutoIt

#include <GuiListView.au3>
Example()


Func Example()
	Local $idListview


	GUICreate("ListView Ensure Visible", 400, 400)
	$idListview = GUICtrlCreateListView("Items", 2, 2, 394, 268)
	$forward = GUICtrlCreateButton("Vorwärts", 10, 320, 100, 40)
	$backward = GUICtrlCreateButton("Rückwärts", 120, 320, 100, 40)
	_GUICtrlListView_SetColumnWidth($idListview, 0, 100)
	_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
	GUISetState(@SW_SHOW)


	_GUICtrlListView_BeginUpdate($idListview)
	For $i = 1 To 200
		GUICtrlCreateListViewItem("Item " & $i, $idListview)
	Next
	_GUICtrlListView_EndUpdate($idListview)






	Local $sItems = "1|29|70|108|186" ; Die Items zu denen ich springen möchte


	Local $iListposition = 1


	MsgBox(0, "Beispiel 1", "Beide Buttons wechseln einfach hin und her. Egal ob man wiederholt den einen drückt, oder abwechselt." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")


	Do
		$msg = GUIGetMsg()
		Select
			Case $msg = $forward
				If $iListposition = 1 Then
					$iListposition = 2
					_GUICtrlListView_EnsureVisible($idListview, 180)
				Else
					$iListposition = 1
					_GUICtrlListView_EnsureVisible($idListview, 10)
				EndIf
			Case $msg = $backward
				If $iListposition = 1 Then
					$iListposition = 2
					_GUICtrlListView_EnsureVisible($idListview, 180)
				Else
					$iListposition = 1
					_GUICtrlListView_EnsureVisible($idListview, 10)
				EndIf
		EndSelect
	Until $msg = -3


	MsgBox(0, "Beispiel 2", "Keine Reaktion auf die Buttons, obwohl in der Konsole alles gut aussieht." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")


	Do
		$msg = GUIGetMsg()
		Select
			Case $msg = $forward
				$aItems = StringSplit($sItems, "|") ; $aItems[0] beeinhaltet die Anzahl der gefundenen Strings.
				If $iListposition = $aItems[0] Then
					$iListposition = 1
				Else
					$iListposition += 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($idListview, $aItems[$iListposition])
			Case $msg = $backward
				$aItems = StringSplit($sItems, "|")
				If $iListposition = 1 Then
					$iListposition = $aItems[0]
				Else
					$iListposition -= 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($idListview, $aItems[$iListposition])


		EndSelect
	Until $msg = -3




	MsgBox(0, "Beispiel 3", "Fast das Gleiche wie Bsp 2 - mit dem Unterschied, das nach Klick noch einmal das Listviewhandle geholt wird. Schon geht es." & @CRLF & @CRLF & "Schließen führt zum nächsten Beispiel.")


	Do
		$msg = GUIGetMsg()
		Select
			Case $msg = $forward
				$hListview = GUICtrlGetHandle($idListview)
				$aItems = StringSplit($sItems, "|") ; $aItems[0] beeinhaltet die Anzahl der gefundenen Strings.
				If $iListposition = $aItems[0] Then
					$iListposition = 1
				Else
					$iListposition += 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
			Case $msg = $backward
				$hListview = GUICtrlGetHandle($idListview)
				$aItems = StringSplit($sItems, "|")
				If $iListposition = 1 Then
					$iListposition = $aItems[0]
				Else
					$iListposition -= 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
		EndSelect
	Until $msg = -3


	MsgBox(0, "Wieder Beispiel 1", "Erneut wechseln beide Buttons einfach hin und her. Egal ob man wiederholt den einen drückt, oder abwechselt." & @CRLF & @CRLF & "Bitte beachten, hier muss erneut kein Handle geholt werden!")


	Do
		$msg = GUIGetMsg()
		Select
			Case $msg = $forward
				If $iListposition = 1 Then
					$iListposition = 2
					_GUICtrlListView_EnsureVisible($idListview, 180)
				Else
					$iListposition = 1
					_GUICtrlListView_EnsureVisible($idListview, 10)
				EndIf
			Case $msg = $backward
				If $iListposition = 1 Then
					$iListposition = 2
					_GUICtrlListView_EnsureVisible($idListview, 180)
				Else
					$iListposition = 1
					_GUICtrlListView_EnsureVisible($idListview, 10)
				EndIf
		EndSelect
	Until $msg = -3


	GUIDelete()


EndFunc   ;==>Example

Alles anzeigen

Dort wo ich das Handling der Listview ermitteln muss, nutze ich einen String, in dem die Positionen stehen, splitte ihn, gebe einer Variable einen neuen Wert und versuche dann an die richtige Position zu springen, die im entsprechenden Element des Array steht.
Das sind für einen Buttonclick schon ein paar Aufgaben. Aber warum geht ausgerechnet das Listview-Handle verloren?

**Oscar**

Es gibt in der Listview-UDF einige Funktionen, die nur mit dem Handle (richtig) funktionieren.
Wenn Du dort die Control-ID (Rückgabe von GUICtrlCreateListView) übergibst, funktioniert es nicht oder nur fehlerhaft.
Ich habe mir deshalb angewöhnt, beim benutzen von Funktionen aus der Listview-UDF diese immer mit dem Handle "GUICtrlGetHandle($idListview)" aufzurufen.

Deshalb funktioniert auch Dein Beispiel mit dem Handle:

AutoIt

#include <GuiListView.au3>
Example()


Func Example()
	Local $idListview


	GUICreate("ListView Ensure Visible", 400, 400)
	$idListview = GUICtrlCreateListView("Items", 2, 2, 394, 268)
	$hListview = GUICtrlGetHandle($idListview)


	$forward = GUICtrlCreateButton("Vorwärts", 10, 320, 100, 40)
	$backward = GUICtrlCreateButton("Rückwärts", 120, 320, 100, 40)
	_GUICtrlListView_SetColumnWidth($hListview, 0, 100)
	_GUICtrlListView_SetExtendedListViewStyle($hListview, BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT))
	GUISetState(@SW_SHOW)


	_GUICtrlListView_BeginUpdate($hListview)
	For $i = 1 To 200
		GUICtrlCreateListViewItem("Item " & $i, $idListview)
	Next
	_GUICtrlListView_EndUpdate($hListview)


	Local $sItems = "1|29|70|108|186" ; Die Items zu denen ich springen möchte


	Local $iListposition = 1


	Do
		$msg = GUIGetMsg()
		Select
			Case $msg = $forward
				$aItems = StringSplit($sItems, "|") ; $aItems[0] beeinhaltet die Anzahl der gefundenen Strings.
				If $iListposition = $aItems[0] Then
					$iListposition = 1
				Else
					$iListposition += 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
			Case $msg = $backward
				$aItems = StringSplit($sItems, "|")
				If $iListposition = 1 Then
					$iListposition = $aItems[0]
				Else
					$iListposition -= 1
				EndIf
				ConsoleWrite($aItems[$iListposition] & @CRLF)
				_GUICtrlListView_EnsureVisible($hListview, $aItems[$iListposition])
		EndSelect
	Until $msg = -3
EndFunc   ;==>Example

Alles anzeigen

**autoiter**

Danke dir Oskar.
Ich werde das vielleicht nicht immer machen, aber auf jeden Fall im Hinterkopf behalten.

Nur warum klappt es genau in dem Bsp.2 nicht wo ich noch die anderen Sachen mache, ohne das Handle zu ermitteln.

Vorher und nachher (Bsp.1 und 4) funktioniert der Befehl _GUICtrlListView_EnsureVisible ja auch ohne diese Operation

Zeitriss

Hi,

Hier mal kurz meine Schlussfolgerung:

Dein Beispiel 2 funktioniert wenn man den richtigen Datentyp nimmt:

AutoIt

_GUICtrlListView_EnsureVisible($idListview, Int($aItems[$iListposition]))

Dass es bei Beispiel 3 funktioniert liegt vermutlich daran dass bei einem Hwnd die Funktion _SendMessage() benützt wird:

AutoIt

Func _SendMessage($hWnd, $iMsg, $wParam = 0, $lParam = 0, $iReturn = 0, $wParamType = "wparam", $lParamType = "lparam", $sReturnType = "lresult")
	Local $aResult = DllCall("user32.dll", $sReturnType, "SendMessageW", "hwnd", $hWnd, "uint", $iMsg, $wParamType, $wParam, $lParamType, $lParam)
	If @error Then Return SetError(@error, @extended, "")
	If $iReturn >= 0 And $iReturn <= 4 Then Return $aResult[$iReturn]
	Return $aResult
EndFunc   ;==>_SendMessage

Dort wird dann beim DllCall der richtige Datentyp mitgegeben, deshalb klappt das.
Wenn du die Id mitgibst wird stattdessen GUICtrlSendMsg() benützt, welche dann einen String mitgibt, damit kann dann das Control nichts anfangen.

mfg
Zeitriss

**autoiter**

Hey @Zeitriss

Tatsache, das funktioniert auch in meinem echten Skript. Ich danke dir für die Erklärung dazu! In AutoIt muss man sich so selten um den Datentyp kümmern, dass ich auf diese Lösung sicher nicht gekommen wäre. Ich bin eben auf einem anderen Niveau unterwegs, als die Leute, die sich darüber unterhalten, ob und wie sie besser, als der Compiler programmieren können

Danke @Zeitriss, @Oscar