FF.au3 Tablink kopieren

M0rtis

Hi,

ich hätte eine kurze Frage.
Habe seid kurzem angefangen ein bisschen mit der FF.au3 rum zuspielen. Doch mir stelle sich folgende Frage: Kann man irgendwie den Link vom Tab kopieren lassen?

Danke im Voraus!

Mit freundlichen Grüßen

M0rtis

**Bitnugger**

Zitat von M0rtis

Kann man irgendwie den Link vom Tab kopieren lassen?

Die Frage ist sehr ungenau formuliert... ich vermute mal, ...

AutoIt

;-- TIME_STAMP   2016-10-29 22:05:28


#Include <FF.au3>


 _FFConnect()


If _FFIsConnected() Then
	; href of the current page
	$sHref = _FFCmd(".location.href")
	If @error Then
		_FFTabAdd("https://autoit.de/index.php/Thread/84695-FF-au3-Tablink-kopieren/?postID=677601#post677601")
	Else
		MsgBox(64,"Current href:",$sHref)
	EndIf


	_FFTabDuplicate()
	Sleep(3000)


	; title of the current page
	$sTitle = _FFCmd( ".title")
	If Not @error Then MsgBox(64,"Title of the current page:",$sTitle)


Else
	MsgBox(64,"Error:","Can't conncect to FireFox")
EndIf

Alles anzeigen

M0rtis

Sorry,
Also genauer Formuliert meine ich, du lässt z.B. auf Youtube.com navigieren und klickst ein Video an, dann ändert sich der Link ja oben in der Navigationsleiste und der soll dann in die Zwischenablage kopiert werden.

MfG

M0rtis

**Bitnugger**

Als Navigationsleiste würde ich die komplette Zeile bezeichnen, in der der sich u. A. auch die "Address Bar" befindet, die du sicher meinst.

Sobald sich die Adresse des aktuellen Tabs ändert, kopiert dieses Script sie in die Zwischenablage und gibt zusätzlich eine Meldung via MsgBox aus.

FF_HREF_TO_CLIPBOARD

AutoIt

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Change2CUI=y
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****


;-- TIME_STAMP   2016-10-30 13:14:14


#Include <FF.au3>
$_FF_COM_TRACE = False	; Nur die wichtigsten Zustände und Fehlermeldungen ausgeben.


_Main()


Func _Main()
	_FFConnect()


	If _FFIsConnected() Then
		Local $sHref, $sHrefOld, $iTabIndex


		While 1
			; href of the current page
			$sHref = _FFCmd(".location.href")
			If @error Then Exit MsgBox(64,"Error:","Can't get .location.href from FireFox") +2


			If $sHrefOld <> $sHref Then
				$sHrefOld = $sHref
				$iTabIndex = _FFTabGetSelected()
				ClipPut($sHref)
				MsgBox(0, @ScriptName, _
					'$iTabIndex = ' & $iTabIndex & @CRLF & @CRLF & _
					'$sHref = ' & @CRLF & @CRLF & $sHref & @CRLF & @CRLF & @CRLF & _
					'The link is now in the clipboard.')
			EndIf
			Sleep(500)
		WEnd


	Else
		Exit MsgBox(64,"Error:","Can't conncect to FireFox") +1
	EndIf
EndFunc

Alles anzeigen

M0rtis

Ah Interessant. Danke jedenfalls