Keywort Script für Thumbsplus

Nasic

Hallo,

ich suche einen script, der im Program ThumbsPlus im Slide Show modus per Mausklick Keyworte einfügen kann.

Manuell geht das mit Strg-K (Keywort) Enter Space

Es müsste also eine GUI drübergelegt werden, wo man diese Sequenz auswählen kann.

Hat jemand einen solchen Sript oder einen den man umschreiben kann?

Für mich als Anfänger ist zu schwierig; ich habe es noch nicht einmal geschafft eine GUI drüber zu legen.

AutoIt kann das ganz sicher!

Vielen Dank für eure Hilfe.

Nasic

**Bitnugger**

So in etwa...

SendThumbsPlus

AutoIt

;-- TIME_STAMP   2016-12-02 22:20:22


; SendThumbsPlus


#include <GUIConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>


_Main()


Func _Main()
#region - GUI Create
; Größe und Position der eigenen GUI nach Belieben anpassen
Local $hGUI = GUICreate('SendThumbsPlus', 625, 35, -1, -1, -1, $WS_EX_TOPMOST)
$idButton_Send0 = GUICtrlCreateButton('Send Keywort xyz',   5, 5, 150, 25)
$idButton_Send1 = GUICtrlCreateButton('Send Keywort abc', 160, 5, 150, 25)
$idButton_Send2 = GUICtrlCreateButton('Send Keywort fgh', 315, 5, 150, 25)
$idButton_Exit  = GUICtrlCreateButton('Exit', 470,5, 150, 25)
GUISetState()
#endregion


#region - GUI SelectLoop
While 1
	$msg = GUIGetMsg()
	Select
		Case $msg = $GUI_EVENT_CLOSE Or $msg = $idButton_Exit
			Exit
		Case $msg = $idButton_Send0
			_SendKey(0)
		Case $msg = $idButton_Send1
			_SendKey(1)
		Case $msg = $idButton_Send2
			_SendKey(2)
		;Case $msg =
	EndSelect
WEnd
#endregion
EndFunc


Func _SendKey($iKeywortID)
	; Keyworts hier nach Belieben anpassen
	Local Static $aKeyworts = ['Keywort_00', 'Keywort_01', 'Keywort_02']
	If $iKeywortID < 0 Or $iKeywortID > UBound($aKeyworts) Then Return SetError(1)


	; Hier die korrekten Werte mit Au3Info holen...
	Local $hWnd = WinGetHandle('[TITLE:ThumbsPlus; CLASS:ThumbsPlus; INSTANCE:1]')
	If IsHWnd($hWnd) = 0 Then Exit MsgBox(0, @ScriptName, 'WinGetHandle() konnte das Window von ThumbsPlus nicht finden!') +1


	; Das ThumbsPlus-Window aktivieren, bevor wir diesem Keystrokes senden
	WinActivate($hWnd)
	; wenn es mit Send() 'hakt', nach jedem Send() noch ein Sleep(500) oder höher einbauen
	Send('^k')
	;Sleep(500)
	Send($aKeyworts[$iKeywortID])
	Send('{ENTER}')
	Send('{SPACE}')
EndFunc

Alles anzeigen