Datei einlesen nach Wert suchen und ergänzen

donpascal

Ich hab noch ein Problem, und nachdem ich gesehen habe es geht hier echt super mit Lösungen.
Vielleicht kann mir jemand helfen.
Ich möchte eine Datei in einen Array lesen, dann nach einem Wert suchen und die Datei (falls nicht vorhanden) um den Wert ergänzen.
Sollte die Datei nicht vorhanden sein, sollte sie erstellt werden.
Aber ich steh da voll auf dem Schlauch.
danke

C

#include <GUIConstants.au3>
#include <file.au3>
#include <Date.au3>
#include <array.au3>
#include <Process.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <UpdownConstants.au3>
#include <EditConstants.au3>
#include <ListboxConstants.au3>
#include <WindowsConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>
#include <GuiListView.au3>
#include <Misc.au3>


$APPDATA=EnvGet("APPDATA")
$SystemDrive=EnvGet("SystemDrive")
$Systemroot= EnvGet("SYSTEMROOT")
$USERNAME=EnvGet("USERNAME")
$ProgramData= EnvGet("ProgramData")
$temp=EnvGet("TEMP")
$USERPROFILE=EnvGet("USERPROFILE")
Local $arraydbfile
Break(0) ; 0 = Break is disabled (user cannot quit)
$arraydbfile="0"
$returncode="0"




$dbfile=$USERPROFILE & "\AppData\LocalLow\Sun\Java\Deployment\security\exception.sites"


$x=0


$url="Beispieltext"
If Not FileExists($dbfile) Then
Local $hFileOpen = FileOpen($dbfile, 10)
FileWriteLine($dbfile,@LF)
FileClose($dbfile)
EndIf


Local $rep_zertmodelArray
$i=0
	_FileReadToArray($dbfile, $rep_zertmodelArray)
 		For $i = 0 To $rep_zertmodelArray[0]
 				if $test1 = 0 Then
 					$x=$x+1
 				EndIf
		Next


 	if $x=0 Then
 		;MsgBox(0,"x", $x)
 		_ArrayDelete($rep_zertmodelArray,0)
 		_ArrayInsert($rep_zertmodelArray,0,$url)
		Local $hFileOpen = FileOpen($dbfile, 10)
 		_FileWriteFromArray($dbfile, $rep_zertmodelArray)
 		FileClose($dbfile)
 	EndIf
$y=0
_FileReadToArray($dbfile, $rep_zertmodelArray)
	For $y = 0 To $rep_zertmodelArray[0]
		If $rep_zertmodelArray[$i] = "" Then
			_ArrayDelete($rep_zertmodelArray, $y)
		EndIf
	Next


Exit

Alles anzeigen

smurf

Hallo,

hast du mal _ArraySearch versucht? Damit kannst du das Array durchsuchen und bekommst als Rückgabewert den Platz in deinem Array oder -1 wenns nicht im Array gefunden wurde.
Mit _ArrayAdd kannst du dann den fehlenden Eintrag dem Array hinzufügen.
Mit _FileWriteFromArray kannst du das Array in eine Datei schreiben. Dabei wird die vorhandene Datei überschrieben oder wenn du einen neuen Dateinamen angibst eine neue Datei erstellt.

Gruß
Smurf

**Bitnugger**

Ich würde das so angegen...

Spoiler anzeigen

AutoIt

;-- TIME_STAMP   2016-12-20 20:00:02


#include <file.au3>
;#include <array.au3>


Opt('MustDeclareVars', 1)


_Example1()
_Example2()


; Einen Eintrag suchen und hinzufügen
Func _Example1()
	Local $hFile, $sFile = @LocalAppDataDir & "Low\Sun\Java\Deployment\security\exception.sites"
	Local $sURL = 'autoit.de', $aCertmodelArray


	If FileExists($sFile) = 0 Then
		; Datei existiert nicht... erzeugen und URL hinzufügen...
		$hFile = FileOpen($sFile, BitOR($FO_OVERWRITE, $FO_CREATEPATH))
		FileWrite($hFile, $sURL)
	Else
		$hFile = FileOpen($sFile, $FO_APPEND)
		_FileReadToArray($hFile, $aCertmodelArray)
		If @error = 0 Then
			_ArraySearch($aCertmodelArray, $sURL)
			If @error Then
				; Eintrag nicht vorhanden... URL hinzufügen...
				FileWrite($hFile, $sURL)
			EndIf
		Else
			; Datei ist vorhanden, aber leer... URL hinzufügen...
			FileWrite($hFile, $sURL)
		EndIf
	EndIf


	FileClose($hFile)
EndFunc  ;==>_Example1


; Mehrere Einträge suchen und hinzufügen
Func _Example2()
	Local $hFile, $sFile = @LocalAppDataDir & "Low\Sun\Java\Deployment\security\exception.sites"
	Local $aURLs = ['autoit.de', 'www.autoitscript.com', 'chocolatey.org'], $aCertmodelArray, $aAppendURLs[0]


	If FileExists($sFile) = 0 Then
		; Datei existiert nicht... erzeugen und URLs hinzufügen...
		$hFile = FileOpen($sFile, BitOR($FO_OVERWRITE, $FO_CREATEPATH))
		_FileWriteFromArray($hFile, $aURLs)
	Else
		$hFile = FileOpen($sFile, $FO_APPEND)
		_FileReadToArray($hFile, $aCertmodelArray)
		If @error = 0 Then
			For $i = 0 To UBound($aURLs) -1 Step 1
				_ArraySearch($aCertmodelArray, $aURLs[$i])
				If @error Then
					; Eintrag nicht vorhanden... URL hinzufügen...
					_ArrayAdd($aAppendURLs, $aURLs[$i])
				EndIf
			Next
			If UBound($aURLs) > 0 Then _FileWriteFromArray($hFile, $aAppendURLs)
		Else
			; Datei ist vorhanden, aber leer... URLs hinzufügen...
			_FileWriteFromArray($hFile, $aURLs)
		EndIf
	EndIf


	FileClose($hFile)
EndFunc  ;==>_Example2

Alles anzeigen