Und mein Script startet ein weiteres Dos fenster ?!

mauric

Hallo Zusammen
Ich habe hier ein Script, dass einfach nur CSV Files Zippen sollte und dieses Zip file anschliessend korrekt beschriftet mit Name+Datum.
Habe zwischenzeitlich mal etwas versucht zu "Coden/Schreiben" , aber es hat noch ein Fehler in der RunWait Zeile die ich aber momentan nicht mehr versteh

Ich bitte um Hilfe!

Spoiler anzeigen

C

#include <MsgBoxConstants.au3>
#include <WinAPIFiles.au3>


zippen()
Func zippen()


FileDelete(".\input.csv")


	Local $destin, $source, $a, $DateName


	$destin = "c:\temp\stocks\Stocks.zip"
	$source = "c:\temp\stocks\*.csv"
	$wert = "a"


	RunWait(@ComSpec & " /c " & "& @SystemDir &" "'\7za.exe'" "'& $wert &'" "'& $destin &'" "'& $source &'"", @SW_SHOW)


$DateName = @MDAY & "_" & @MON &"_" & @YEAR & "-StocksCVSBackup.zip"


FileMove("'& $destin &'", $DateName)


FileCopy("'& $destin &'",".\Archiv")
FileDelete("'& $source &'")


EndFunc

Alles anzeigen

**Bitnugger**

Das erste Fenster geht auf, weil du RunWait() mit dem Makro @ComSpec startest.
Das zweite Fenster geht auf, weil du RunWait() mit dem Makro @SW_SHOW startest.

Beides ist übrigens unnötig!

Dein RunWait() hätte so aussehen müssen...

AutoIt

RunWait(@ComSpec & ' /c "' & @SystemDir & "\7za.exe" & '" a "' & $destin & '" "' & $source & '"', '', @SW_SHOW)

Mit StringFormat wird diese Zeile aber leichter zu händeln und auch übersichtlicher...

AutoIt

RunWait(StringFormat('"%s" /c "%s" a "%s" "%s"', @ComSpec, @SystemDir & "\7za.exe", $destin, $source), '', @SW_SHOW)

@ComSpec brauchst du nur, wenn du einen Befehl ausführen willst, der nicht als eigenständige Exe vorhanden ist, sondern in der CMD enthalten ist - z. B. Set, Copy oder Echo. Deshalb kann man das so viel kürzer machen...

AutoIt

RunWait(StringFormat('"%s" a "%s" "%s"', @SystemDir & "\7za.exe", $destin, $source), '', @SW_SHOW)

Schau einfach hier, wie ich es gemacht habe...

7za

AutoIt

;-- TIME_STAMP   2017-04-22 06:34:34


Example()


Func Example()
	Local $sArchiv, $sSource
	$sSource = "f:\Progdir\CrystalDiskInfo\Smart\HGST HTS541010A9E680JA100A1F30URKM\*.csv"
	$sArchiv = 'm:\temp\' & @MDAY & "_" & @MON & "_" & @YEAR & "-StocksCVSBackup.zip"


	_7za($sArchiv, $sSource)
EndFunc   ;==>Example


Func _7za($sArchiv, $sSource)
	Local $iErr
	Local Static $aSevenZa = ['f:\Progdir\7-Zip-Extra\7za.exe', 'f:\Progdir\7-Zip-Extra\x64\7za.exe'], $sSevenZa = (@OSArch = 'X86') ? $aSevenZa[0] : $aSevenZa[1]


	; ---------------
	; Archiv erzeugen
	; ---------------
	; Usage: 7za <command> [<switches>...] <archive_name> [<file_names>...]
	$iErr = RunWait(StringFormat('"%s" a "%s" "%s"', $sSevenZa, $sArchiv, $sSource), '', @SW_HIDE)
	; --> m:\Temp\22_04_2017-StocksCVSBackup.zip	5,7 k	22.04.2017 05:58	-a--
	If @error Then
		MsgBox(262192, @ScriptName, 'Error: 7za wurde mit folgendem Fehlercode beendet: ' & $iErr)
	Else
		; ---------------
		; Quelldateien löschen, wenn das Archiv erstellt werden konnte
		; ---------------
;~ 		FileDelete($sSource)
	EndIf
EndFunc   ;==>_7za

Alles anzeigen

mauric

Hallo Bittnugger!

Wollte mich bedanken für die schnelle Hilfe die ich bekommen durfte!
Mauri