Standartgerät erkennen und setzten (Wiedergabegeräte / Audioeinstellung)

Michi91

Guten Morgen,

ich hab folgendes Problem und konnte dazu bei google bisher zu wenig finden.

Ich schau mir gerne mal Filme die am PC laufen am Fernseher an, dazu hab ich mir
einen kleinen Switcher zugelegt. Ich brauch also nur auf den Knopf drücken, dann wird das Signal von der
Graka auf den TV umgeleitet.

Soweit ne tolle Sache, jedoch spielen da die Audioeinstellungen manchmal nicht so ganz mit.
Soll heißen, das Standartgerät wird nicht immer auf das entsprechnd gerade angesteuerte Gerät,
also den Fernseher oder das Headset (PC) gesetzt.

Jetzt wollte ich mal ein kleinen Script machen, dass erkennt ob gerade der Monitor oder der Fernseher angeschlossen ist
und das Standartgerät entsprechend automatisch setzt, sofern dies nicht von selbst geschieht, so als Backup eben.

Dazu fehlen mir folgende Funktionen für AutoIt...
- Erkennen welcher Monitor gerade angeschlossen ist (über den Switch)
- Erkennen welches Gerät als Standartgerät gesetzt ist
- Standartgerät setzen

Wäre super, wenn mir da jemand weiter helfen könnte.
Derweil durchforste ich mal weiter Onkel Google

**Kanashius**

Hiermit kannst du herausfinden, welche Monitore gerade angeschlossen sind. Weiß aber nicht, ob das auch mit Switch funktioniert:

AutoIt

#include <WinAPIGdi.au3>
#include <WinAPISys.au3>
#include <Array.au3>
_ArrayDisplay(_getMaxMonitorInfo())


;Returns 2D-Array with all Monitors: Name, isPrimary, SizeX,SizeY,WorkareaX,WorkareaY,StartSizeX,StartSizeY,StartWorkareaX,StartWorkareaY
Func _getMaxMonitorInfo($max=10)
	local $arDevices[$max][10],$count=0
	for $i=0 to 10 step 1
		Local $aData = _WinAPI_GetMonitorInfo($i)
		If IsArray($aData) Then
			$arDevices[$count][0]=$aData[3]
			$arDevices[$count][1]=$aData[2]
			$arDevices[$count][2]=DllStructGetData($aData[0], 3)-DllStructGetData($aData[0], 1)
			$arDevices[$count][3]=DllStructGetData($aData[0], 4)-DllStructGetData($aData[0], 2)
			$arDevices[$count][4]=DllStructGetData($aData[1], 3)-DllStructGetData($aData[1], 1)
			$arDevices[$count][5]=DllStructGetData($aData[1], 4)-DllStructGetData($aData[1], 2)
			$arDevices[$count][6]=DllStructGetData($aData[0], 1)
			$arDevices[$count][7]=DllStructGetData($aData[0], 2)
			$arDevices[$count][8]=DllStructGetData($aData[1], 1)
			$arDevices[$count][9]=DllStructGetData($aData[1], 2)
			$count+=1
		EndIf
	next
	ReDim $arDevices[$count][10]
	return $arDevices
EndFunc

Alles anzeigen

Audio wechseln hab ich auch mal probiert... von Windows her ist da leider nichts möglich, also muss man das Fenster öffnen und dort klicken... wobei sich das Fenster auch weigert versteckt geöffnet zu werden -> es ist kurz sichtbar. Das ganze klappt auch irgendwie nur bei jedem 2ten aufruf... keine ahnung, wieso... Hab deshalb nen paar überprüfungen drin. (Wenn das Sound Fenster schon offen ist, ist es danach weg...

AutoIt

#include <array.au3>
#include <GuiListView.au3>


$arSoundDevices=_getSoundDevices()
_ArrayDisplay($arSoundDevices)
_changeDefaultSoundDevice($arSoundDevices[0][0],$arSoundDevices[0][1])


;Gibt 1 zurück bei Erfolg, sonst 0
Func _changeDefaultSoundDevice($deviceName,$deviceDescription="",$deep=0)
	If $deep=5 Then return 0
	$winHandle=_openSound()
	$existed=@extended
	$LVHandle=ControlGetHandle($winHandle,"","[CLASS:SysListView32; INSTANCE:1]")
	$bool=1
	If _GUICtrlListView_GetItemCount($LVHandle)=0 Then
		WinClose($winHandle)
		$bool=_changeDefaultSoundDevice($deviceName,$deviceDescription,$deep+1)
		$existed=@extended
	Else
		for $i=0 to _GUICtrlListView_GetItemCount($LVHandle)-1 step 1
			If _GUICtrlListView_GetItemText($LVHandle,$i,0)=$deviceName Then
				if $deviceDescription="" or _GUICtrlListView_GetItemText($LVHandle,$i,1)=$deviceDescription Then
					_GUICtrlListView_SetItemSelected($LVHandle,$i,true)
					ControlClick($winHandle,"","[CLASS:Button; INSTANCE:2]")
				endif
			EndIf
		next
	EndIf
	If NOT $existed Then WinClose($winHandle)
	SetExtended($existed)
	return $bool
EndFunc


Func _getSoundDevices($deep=0)
	$winHandle=_openSound()
	$existed=@extended
	$LVHandle=ControlGetHandle($winHandle,"","[CLASS:SysListView32; INSTANCE:1]")
	local $arSoundDevices[_GUICtrlListView_GetItemCount($LVHandle)][3]
	If _GUICtrlListView_GetItemCount($LVHandle)=0 Then
		WinClose($winHandle)
		$arSoundDevices=_getSoundDevices($deep+1)
		$existed=@extended
	Else
		for $i=0 to _GUICtrlListView_GetItemCount($LVHandle)-1 step 1
			$arSoundDevices[$i][0]=_GUICtrlListView_GetItemText($LVHandle,$i,0)
			$arSoundDevices[$i][1]=_GUICtrlListView_GetItemText($LVHandle,$i,1)
			$arSoundDevices[$i][2]=_GUICtrlListView_GetItemText($LVHandle,$i,2)
		next
	EndIf
	If NOT $existed Then WinClose($winHandle)
	SetExtended($existed)
	return $arSoundDevices
EndFunc


Func _openSound()
	SetExtended(false)
	$arHandles=_getHandles("Sound")
	for $i=0 to UBound($arHandles)-1 step 1
		$handle=ControlGetHandle($arHandles[$i],"","[CLASS:SysTabControl32; INSTANCE:1]")
		If not @error Then
			SetExtended(true)
			WinClose($arHandles[$i])
		endif
	next
	$pid=ShellExecute("mmsys.cpl","","","",@SW_HIDE)
	$timer=TimerInit()
	do
		$arWins=_getWinHandlesByProcess($pid,"Sound")
		If TimerDiff($timer)>2000 Then ExitLoop
	Until UBound($arWins)>0
	If UBound($arWins)>1 Then
		SetError(1)
		return -1
	Endif
	return $arWins[0]
EndFunc


Func _getHandles($title)
	local $arWin=WinList()
	local $arWins[UBound($arWin)],$count=0
	for $i=1 to UBound($arWin)-1 step 1
		If StringInStr($arWin[$i][0],$title) Then
			$arWins[$count]=$arWin[$i][1]
			$count+=1
		EndIf
	next
	ReDim $arWins[$count]
	return $arWins
EndFunc


Func _getWinHandlesByProcess($pid,$title=-1)
	local $proc=ProcessList("rundll32.exe")
	if UBound($proc)>1 Then $proc=$proc[1][1]
	local $arWin=WinList()
	local $arProcWins[UBound($arWin)],$count=0
	for $i=1 to UBound($arWin)-1 step 1
		If $pid=WinGetProcess($arWin[$i][1]) or $proc=WinGetProcess($arWin[$i][1]) AND ($title=-1 or StringInStr($arWin[$i][0],$title)) Then
			$arProcWins[$count]=$arWin[$i][1]
			$count+=1
		EndIf
	next
	ReDim $arProcWins[$count]
	return $arProcWins
EndFunc

Alles anzeigen

MfG Kanashius

**Bitnugger**