Observer Pattern

#include <Array.au3>


Func Array()
   local $arr = []
   _ArrayDelete($arr, 0)
   return $arr
EndFunc


Func Dict()
   local $dict = ObjCreate("Scripting.Dictionary")
   $dict.CompareMode = 1
   return $dict
EndFunc




Global $Subscribers = Dict()


Func Subscribe($fFunction, $sChannel = "any")
   If Not $Subscribers.Exists($sChannel) Then
	  $Subscribers.Add($sChannel, Array())
   EndIf
   local $arr = ($Subscribers.Item($sChannel))
   _arrayAdd($arr, $fFunction)
   $Subscribers.Item($sChannel) = $arr
EndFunc


Func Publish($sMsg, $sChannel = "any")
   For $fn in ($Subscribers.Item($sChannel))
	  ConsoleWrite("Calling function " & FuncName($fn) & " on channel " & $sChannel & @CRLF)
	  Call($fn, $sMsg)
   Next
EndFunc




Func me1($data)
   ConsoleWrite("[me1] Got message: " & $data & @CRLF)
EndFunc
Func me2($data)
   ConsoleWrite("[me2] Got message: " & $data & @CRLF)
EndFunc




Subscribe(me1)
Subscribe(me2, "events")




; Array Inhalt nur "lesbar" wenn die Function als String subscribed wird
; Subscribe("me1")
_ArrayDisplay( ($Subscribers.Item("any"))    )
_ArrayDisplay( ($Subscribers.Item("events")) )


Publish("Hello, World!")
Publish("Let's get started!", "events")

#include <Array.au3>


Func Array()
   local $aArray[0]
   return $aArray
EndFunc
Func Dict($iCompareMode = 1)
   local $dict = ObjCreate("Scripting.Dictionary")
   $dict.CompareMode = $iCompareMode
   return $dict
EndFunc




Global $Subscribers = Dict()


Func Attach($fFunction, $sChannel = "any")
   If Not $Subscribers.Exists($sChannel) Then
	  $Subscribers.Add($sChannel, Array())
   EndIf
   local $arr = ($Subscribers.Item($sChannel))
   _arrayAdd($arr, $fFunction)
   $Subscribers.Item($sChannel) = $arr
EndFunc


Func Detach($fFunction, $sChannel = "any")
   Local $arr = ($Subscribers.Item($sChannel))
   $iIndex = _arraySearch($arr, $fFunction)


   If @error Or $iIndex = -1 Then
	  ConsoleWrite("Subscriber " & (IsString($fFunction) ? $fFunction : FuncName($fFunction)) & _
		 " not found in channel " & $sChannel & @CRLF)
	  Return SetError(1)
   Else
	  ConsoleWrite("Removing subscriber " & (IsString($fFunction) ? $fFunction : FuncName($fFunction)) & _
		 " from channel " & $sChannel & @CRLF)
	  _ArrayDelete($arr, $iIndex)
	  $Subscribers.Item($sChannel) = $arr
   EndIf
EndFunc


Func Publish($sMsg, $sChannel = "any")
   For $fn in ($Subscribers.Item($sChannel))
	  ConsoleWrite("Calling function " & IsString($fn) ? $fn : FuncName($fn) & " on channel " & $sChannel & @CRLF)
	  Call($fn, $sMsg)
   Next
EndFunc




Func me1($data)
   ConsoleWrite("[me1] Got message: " & $data & @CRLF)
EndFunc
Func me2($data)
   ConsoleWrite("[me2] Got message: " & $data & @CRLF)
EndFunc




Attach("me1")
Attach("me2", "events")


Detach(me2)




; Array Inhalt nur "lesbar" wenn die Function als String subscribed wird
; Subscribe("me1")
_ArrayDisplay( ($Subscribers.Item("any"))    )
_ArrayDisplay( ($Subscribers.Item("events")) )




Publish("Hello, World!")
Publish("Let's get started!", "events")